bump; drop py2.6 add py3.4

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 71 insertions, 1 deletions

diff --git a/dev-python/pyfits/ChangeLog b/dev-python/pyfits/ChangeLog
index aba2969f21b5..1cd1c513bb97 100644
--- a/dev-python/pyfits/ChangeLog
+++ b/dev-python/pyfits/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyfits
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyfits/ChangeLog,v 1.50 2014/06/10 19:19:13 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyfits/ChangeLog,v 1.51 2014/07/22 14:10:55 idella4 Exp $
+
+*pyfits-3.3 (22 Jul 2014)
+
+  22 Jul 2014; Ian Delaney <idella4@gentoo.org> +pyfits-3.3.ebuild:
+  bump; drop py2.6 add py3.4
 
 *pyfits-3.2.4 (10 Jun 2014)
 
diff --git a/dev-python/pyfits/pyfits-3.3.ebuild b/dev-python/pyfits/pyfits-3.3.ebuild
new file mode 100644
index 000000000000..e41525ffefac
--- /dev/null
+++ b/dev-python/pyfits/pyfits-3.3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyfits/pyfits-3.3.ebuild,v 1.1 2014/07/22 14:10:55 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+inherit distutils-r1 eutils multilib
+
+DESCRIPTION="Provides an interface to FITS formatted files under python"
+HOMEPAGE="http://www.stsci.edu/resources/software_hardware/pyfits"
+SRC_URI="mirror://pypi/p/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	!<dev-python/astropy-0.3
+	sci-libs/cfitsio:0="
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/d2to1-0.2.5[${PYTHON_USEDEP}]
+	>=dev-python/stsci-distutils-0.3[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/numpydoc[${PYTHON_USEDEP}]' python2_7 'python{3_3,3_4}')
+		dev-python/sphinxcontrib-programoutput[${PYTHON_USEDEP}]
+		dev-python/stsci-sphinxext[${PYTHON_USEDEP}]
+		 )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.2.1-unbundle-cfitsio.patch )
+
+python_prepare_all() {
+	sed -i \
+		-e "s/\(hook_package_dir = \)lib/\1$(get_libdir)/g" \
+		"${S}"/setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib* || die
+	nosetests || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html )
+	distutils-r1_python_install_all
+	dodoc FAQ.txt CHANGES.txt
+	rename_binary() {
+		local binary
+		for binary in "${ED}"/usr/bin/* "${D}$(python_get_scriptdir)"/*
+		do
+			mv ${binary}{,-${PN}} || die "failed renaming"
+		done
+	}
+	python_foreach_impl rename_binary
+}