Use libopenjpeg:2 and workaround broken slotting

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0B08240A96F66571)

4 files changed, 139 insertions, 4 deletions

diff --git a/app-text/poppler/ChangeLog b/app-text/poppler/ChangeLog
index 6849ea7a934c..8d6e13357d9b 100644
--- a/app-text/poppler/ChangeLog
+++ b/app-text/poppler/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-text/poppler
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.458 2015/05/18 11:31:55 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.459 2015/05/24 18:45:23 dilfridge Exp $
+
+*poppler-0.33.0-r1 (24 May 2015)
+
+  24 May 2015; Andreas K. Huettel <dilfridge@gentoo.org>
+  +poppler-0.33.0-r1.ebuild, poppler-9999.ebuild,
+  +files/poppler-0.33.0-openjpeg2.patch:
+  Use libopenjpeg:2 and workaround broken slotting
 
 *poppler-0.33.0 (18 May 2015)
 
diff --git a/app-text/poppler/files/poppler-0.33.0-openjpeg2.patch b/app-text/poppler/files/poppler-0.33.0-openjpeg2.patch
new file mode 100644
index 000000000000..af1a72fe9aa8
--- /dev/null
+++ b/app-text/poppler/files/poppler-0.33.0-openjpeg2.patch
@@ -0,0 +1,15 @@
+Sadly the CMake side of openjpeg slotting in Gentoo is broken.
+To reliably find openjpeg:2 we need to use pkg-config.
+
+diff -ruN poppler-0.33.0.orig/CMakeLists.txt poppler-0.33.0/CMakeLists.txt
+--- poppler-0.33.0.orig/CMakeLists.txt	2015-05-14 20:22:31.000000000 +0200
++++ poppler-0.33.0/CMakeLists.txt	2015-05-24 20:39:30.163709257 +0200
+@@ -172,7 +172,7 @@
+   set(USE_OPENJPEG1 ${LIBOPENJPEG_FOUND})
+   set(WITH_OPENJPEG ${LIBOPENJPEG_FOUND})
+ elseif(ENABLE_LIBOPENJPEG STREQUAL "openjpeg2")
+-  find_package(LIBOPENJPEG2)
++  pkg_check_modules(LIBOPENJPEG2 libopenjp2)
+   set(USE_OPENJPEG2 ${LIBOPENJPEG2_FOUND})
+   set(WITH_OPENJPEG ${LIBOPENJPEG2_FOUND})
+ endif()
diff --git a/app-text/poppler/poppler-0.33.0-r1.ebuild b/app-text/poppler/poppler-0.33.0-r1.ebuild
new file mode 100644
index 000000000000..60edeaecbd5d
--- /dev/null
+++ b/app-text/poppler/poppler-0.33.0-r1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.33.0-r1.ebuild,v 1.1 2015/05/24 18:45:23 dilfridge Exp $
+
+EAPI=5
+
+inherit cmake-utils toolchain-funcs
+
+if [[ "${PV}" == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.freedesktop.org/git/${PN}/${PN}"
+	SLOT="0/9999"
+else
+	SRC_URI="http://poppler.freedesktop.org/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SLOT="0/52"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="http://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="cairo cjk curl cxx debug doc +introspection +jpeg jpeg2k +lcms png qt4 qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=media-libs/fontconfig-2.6.0
+	>=media-libs/freetype-2.3.9
+	sys-libs/zlib
+	cairo? (
+		dev-libs/glib:2
+		>=x11-libs/cairo-1.10.0
+		introspection? ( >=dev-libs/gobject-introspection-1.32.1 )
+	)
+	curl? ( net-misc/curl )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2 )
+	lcms? ( media-libs/lcms:2 )
+	png? ( media-libs/libpng:0= )
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:0 )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( >=app-text/poppler-data-0.4.4 )
+"
+
+DOCS=(AUTHORS NEWS README README-XPDF TODO)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.26.0-qt5-dependencies.patch"
+	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
+	"${FILESDIR}/${PN}-0.28.1-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.33.0-openjpeg2.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT4_TESTS=OFF
+		-DBUILD_QT5_TESTS=OFF
+		-DBUILD_CPP_TESTS=OFF
+		-DENABLE_SPLASH=ON
+		-DENABLE_ZLIB=ON
+		-DENABLE_XPDF_HEADERS=ON
+		$(cmake-utils_use_enable curl LIBCURL)
+		$(cmake-utils_use_enable cxx CPP)
+		$(cmake-utils_use_enable utils)
+		$(cmake-utils_use_with cairo)
+		$(cmake-utils_use_with introspection GObjectIntrospection)
+		$(cmake-utils_use_with jpeg)
+		$(cmake-utils_use_with png)
+		$(cmake-utils_use_with qt4)
+		$(cmake-utils_use_find_package qt5 Qt5Core)
+		$(cmake-utils_use_with tiff)
+	)
+	if use jpeg2k; then
+		mycmakeargs+=(-DENABLE_LIBOPENJPEG=openjpeg2)
+	else
+		mycmakeargs+=(-DENABLE_LIBOPENJPEG=)
+	fi
+	if use lcms; then
+		mycmakeargs+=(-DENABLE_CMS=lcms2)
+	else
+		mycmakeargs+=(-DENABLE_CMS=)
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use cairo && use doc; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		# nonfatal, because live version doesn't provide html documentation.
+		nonfatal doins -r "${S}"/glib/reference/html/*
+	fi
+}
diff --git a/app-text/poppler/poppler-9999.ebuild b/app-text/poppler/poppler-9999.ebuild
index 07b39e6bc66d..cb483b020aa4 100644
--- a/app-text/poppler/poppler-9999.ebuild
+++ b/app-text/poppler/poppler-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-9999.ebuild,v 1.6 2015/05/18 11:31:55 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-9999.ebuild,v 1.7 2015/05/24 18:45:23 dilfridge Exp $
 
 EAPI=5
 
@@ -36,7 +36,7 @@ COMMON_DEPEND="
 	)
 	curl? ( net-misc/curl )
 	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( media-libs/openjpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2 )
 	lcms? ( media-libs/lcms:2 )
 	png? ( media-libs/libpng:0= )
 	qt4? (
@@ -63,6 +63,7 @@ PATCHES=(
 	"${FILESDIR}/${PN}-0.26.0-qt5-dependencies.patch"
 	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
 	"${FILESDIR}/${PN}-0.28.1-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.33.0-openjpeg2.patch"
 )
 
 src_configure() {
@@ -86,7 +87,7 @@ src_configure() {
 		$(cmake-utils_use_with tiff)
 	)
 	if use jpeg2k; then
-		mycmakeargs+=(-DENABLE_LIBOPENJPEG=openjpeg1)
+		mycmakeargs+=(-DENABLE_LIBOPENJPEG=openjpeg2)
 	else
 		mycmakeargs+=(-DENABLE_LIBOPENJPEG=)
 	fi