From cbb7419abbb5c70634a9c94292c85aa348aca91a Mon Sep 17 00:00:00 2001
From: Dane Smith <c1pher@gentoo.org>
Date: Mon, 21 Mar 2011 13:43:05 +0000
Subject: Version bump for app-crypt/qca wrt bug 359717.

(Portage version: 2.1.9.42/cvs/Linux x86_64)
---
 app-crypt/qca/ChangeLog        |  9 +++--
 app-crypt/qca/qca-2.0.3.ebuild | 75 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+), 2 deletions(-)
 create mode 100644 app-crypt/qca/qca-2.0.3.ebuild

(limited to 'app-crypt/qca')

diff --git a/app-crypt/qca/ChangeLog b/app-crypt/qca/ChangeLog
index 160881f1db00..3842cdf512dd 100644
--- a/app-crypt/qca/ChangeLog
+++ b/app-crypt/qca/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-crypt/qca
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/qca/ChangeLog,v 1.82 2010/03/26 23:32:41 yngwin Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/qca/ChangeLog,v 1.83 2011/03/21 13:43:05 c1pher Exp $
+
+*qca-2.0.3 (21 Mar 2011)
+
+  21 Mar 2011; Dane Smith <c1pher@gentoo.org> +qca-2.0.3.ebuild:
+  Version bump wrt bug 359717. Moved to EAPI 3. Added a missing die.
 
   26 Mar 2010; Ben de Groot <yngwin@gentoo.org> qca-2.0.2-r2.ebuild:
   Use qt4-r2.eclass (bug #311481). Removed unneeded die messages.
diff --git a/app-crypt/qca/qca-2.0.3.ebuild b/app-crypt/qca/qca-2.0.3.ebuild
new file mode 100644
index 000000000000..d0c8eb6b61b0
--- /dev/null
+++ b/app-crypt/qca/qca-2.0.3.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/qca/qca-2.0.3.ebuild,v 1.1 2011/03/21 13:43:05 c1pher Exp $
+
+EAPI="3"
+inherit eutils multilib qt4-r2
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="http://delta.affinix.com/qca/"
+SRC_URI="http://delta.affinix.com/download/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="aqua debug doc examples"
+RESTRICT="test"
+
+DEPEND="x11-libs/qt-core:4[debug?]"
+RDEPEND="${DEPEND}
+	!<app-crypt/qca-1.0-r3:0"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.0.2-pcfilespath.patch
+
+	if use aqua; then
+		sed -i \
+		-e "s|QMAKE_LFLAGS_SONAME =.*|QMAKE_LFLAGS_SONAME = -Wl,-install_name,|g" \
+		src/src.pro || die "Sed failed."
+	fi
+}
+
+src_configure() {
+	_libdir=$(get_libdir)
+
+	# Ensure proper rpath
+	export EXTRA_QMAKE_RPATH="${EPREFIX}/usr/${_libdir}/qca2"
+
+	./configure \
+		--prefix="${EPREFIX}"/usr \
+		--qtdir="${EPREFIX}"/usr \
+		--includedir="${EPREFIX}"/usr/include/qca2 \
+		--libdir="${EPREFIX}"/usr/${_libdir}/qca2 \
+		--certstore-path="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
+		--no-separate-debug-info \
+		--disable-tests \
+		--$(use debug && echo debug || echo release) \
+		--no-framework \
+		|| die "configure failed"
+
+	eqmake4
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die
+	dodoc README TODO || die
+
+	cat <<-EOF > "${WORKDIR}"/44qca2
+	LDPATH="${EPREFIX}/usr/${_libdir}/qca2"
+	EOF
+	doenvd "${WORKDIR}"/44qca2 || die
+
+	if use doc; then
+		dohtml "${S}"/apidocs/html/* || die
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/
+		doins -r "${S}"/examples || die
+	fi
+
+	# add the proper rpath for packages that do CONFIG += crypto
+	echo "QMAKE_RPATHDIR += \"${EPREFIX}/usr/${_libdir}/qca2\"" >> \
+		"${D%/}${EPREFIX}/usr/share/qt4/mkspecs/features/crypto.prf" \
+		|| die "failed to add rpath to crypto.prf"
+}
-- 
cgit v1.2.3-65-gdbad