From 8abba274084920588c1cf4097cbbd605b311df5e Mon Sep 17 00:00:00 2001
From: Naohiro Aota <naota@gentoo.org>
Date: Sat, 4 Jun 2011 05:52:35 +0000
Subject: Support ruby19

(Portage version: 2.2.0_alpha37/cvs/Linux x86_64)
---
 dev-ruby/rcairo/ChangeLog               |  7 ++-
 dev-ruby/rcairo/rcairo-1.10.0-r4.ebuild | 84 +++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+), 1 deletion(-)
 create mode 100644 dev-ruby/rcairo/rcairo-1.10.0-r4.ebuild

(limited to 'dev-ruby/rcairo')

diff --git a/dev-ruby/rcairo/ChangeLog b/dev-ruby/rcairo/ChangeLog
index 47a9db97ce83..6bd8cf0003c8 100644
--- a/dev-ruby/rcairo/ChangeLog
+++ b/dev-ruby/rcairo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/rcairo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.62 2011/05/02 20:05:29 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.63 2011/06/04 05:52:35 naota Exp $
+
+*rcairo-1.10.0-r4 (04 Jun 2011)
+
+  04 Jun 2011; Naohiro Aota <naota@gentoo.org> +rcairo-1.10.0-r4.ebuild:
+  Support ruby19
 
   02 May 2011; Hans de Graaff <graaff@gentoo.org> +rcairo-1.8.1.ebuild:
   Add back rcairo 1.8.1 until newer versions go together with
diff --git a/dev-ruby/rcairo/rcairo-1.10.0-r4.ebuild b/dev-ruby/rcairo/rcairo-1.10.0-r4.ebuild
new file mode 100644
index 000000000000..bd9921f06fa2
--- /dev/null
+++ b/dev-ruby/rcairo/rcairo-1.10.0-r4.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.10.0-r4.ebuild,v 1.1 2011/06/04 05:52:35 naota Exp $
+
+EAPI=2
+
+# jruby → cannot work, it's a compiled extension
+USE_RUBY="ruby18 ruby19"
+
+RUBY_FAKEGEM_NAME="cairo"
+
+# Documentation depends on files that are not distributed.
+RUBY_FAKEGEM_TASK_DOC=""
+
+# Depends on test-unit-2 which is currently masked.
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Ruby bindings for cairo"
+HOMEPAGE="http://cairographics.org/rcairo/"
+
+IUSE=""
+
+SLOT="0"
+LICENSE="|| ( Ruby GPL-2 )"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
+
+RDEPEND="${RDEPEND}
+	>=x11-libs/cairo-1.2.0[svg]"
+DEPEND="${DEPEND}
+	>=x11-libs/cairo-1.2.0[svg]
+	dev-util/pkgconfig"
+
+ruby_add_bdepend "
+	dev-ruby/ruby-glib2
+	test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
+
+all_ruby_prepare() {
+	# Remove a failing test for the new recording surface. It's not
+	# clear if this is a test failure or not, but we need to move on
+	# with cairo 1.10.
+	rm test/test_recording_surface.rb || die
+
+	# We don't need pkg-config since we compile directly so remove
+	# metadata because otherwise rubygems or bundler may get confused.
+	rm ../metadata || die
+}
+
+each_ruby_configure() {
+	${RUBY} extconf.rb || die "extconf failed"
+}
+
+each_ruby_compile() {
+	emake || die "make failed"
+
+	# again, try to make it more standard, to install it more easily.
+	cp ext/cairo/cairo$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	# don't rely on the Rakefile because it's a mess to load with
+	# their hierarchy, do it manually.
+	${RUBY} -Ilib -r ./test/cairo-test-utils.rb \
+		-e 'gem "test-unit"; require "test/unit"; Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
+}
+
+each_ruby_install() {
+	each_fakegem_install
+
+	insinto $(ruby_get_hdrdir)
+	doins ext/cairo/rb_cairo.h || die "Cannot install header file."
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}/samples
+	doins -r samples/* || die "Cannot install sample files."
+}
-- 
cgit v1.2.3-65-gdbad