From 4bd831725ea4684b9ed59e7b18e0afc911866a43 Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Mon, 9 Jul 2012 09:10:48 +0000
Subject: Version bump.

(Portage version: 2.2.0_alpha116/cvs/Linux x86_64)
---
 sys-apps/usbutils/usbutils-006.ebuild | 62 +++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 sys-apps/usbutils/usbutils-006.ebuild

(limited to 'sys-apps/usbutils/usbutils-006.ebuild')

diff --git a/sys-apps/usbutils/usbutils-006.ebuild b/sys-apps/usbutils/usbutils-006.ebuild
new file mode 100644
index 000000000000..056484a622c5
--- /dev/null
+++ b/sys-apps/usbutils/usbutils-006.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/usbutils/usbutils-006.ebuild,v 1.1 2012/07/09 09:10:48 radhermit Exp $
+
+EAPI="4"
+
+PYTHON_DEPEND="python? 2:2.6"
+
+inherit python
+
+DESCRIPTION="USB enumeration utilities"
+HOMEPAGE="http://linux-usb.sourceforge.net/"
+SRC_URI="mirror://kernel/linux/utils/usb/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="python zlib"
+
+RDEPEND="virtual/libusb:1
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+RDEPEND="${RDEPEND}
+	sys-apps/hwids"
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	if use python; then
+		python_convert_shebangs 2 lsusb.py
+		sed -i -e '/^usbids/s:/usr/share:/usr/share/misc:' lsusb.py || die
+	fi
+}
+
+src_configure() {
+	econf \
+		--datarootdir="${EPREFIX}/usr/share" \
+		--datadir="${EPREFIX}/usr/share/misc" \
+		--disable-usbids \
+		$(use_enable zlib)
+}
+
+src_install() {
+	default
+	newdoc usbhid-dump/NEWS NEWS.usbhid-dump
+
+	use python || rm -f "${ED}"/usr/bin/lsusb.py
+
+	newbin "${FILESDIR}"/usbmodules.sh usbmodules
+}
+
+pkg_postinst() {
+	elog "The 'network-cron' USE flag is gone; if you want a more up-to-date"
+	elog "usb.ids file, you should use sys-apps/hwids-99999999 (live ebuild)."
+}
-- 
cgit v1.2.3-65-gdbad