From af0b8dbf3d4474336ac33bd45c999620b54a827a Mon Sep 17 00:00:00 2001
From: Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
Date: Tue, 6 Nov 2012 04:24:38 +0000
Subject: Version bump.

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, unsigned Manifest commit)
---
 x11-libs/libdrm/ChangeLog            |  8 +++++-
 x11-libs/libdrm/libdrm-2.4.40.ebuild | 55 ++++++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+), 1 deletion(-)
 create mode 100644 x11-libs/libdrm/libdrm-2.4.40.ebuild

(limited to 'x11-libs/libdrm')

diff --git a/x11-libs/libdrm/ChangeLog b/x11-libs/libdrm/ChangeLog
index 0c348b824876..8163e31015ee 100644
--- a/x11-libs/libdrm/ChangeLog
+++ b/x11-libs/libdrm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/libdrm
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.203 2012/10/20 23:36:11 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.204 2012/11/06 04:24:38 chithanh Exp $
+
+*libdrm-2.4.40 (06 Nov 2012)
+
+  06 Nov 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +libdrm-2.4.40.ebuild:
+  Version bump.
 
   20 Oct 2012; Richard Yao <ryao@gentoo.org> libdrm-2.4.37.ebuild,
   libdrm-2.4.38.ebuild, libdrm-2.4.39.ebuild:
diff --git a/x11-libs/libdrm/libdrm-2.4.40.ebuild b/x11-libs/libdrm/libdrm-2.4.40.ebuild
new file mode 100644
index 000000000000..46ab2634b173
--- /dev/null
+++ b/x11-libs/libdrm/libdrm-2.4.40.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.40.ebuild,v 1.1 2012/11/06 04:24:38 chithanh Exp $
+
+EAPI=4
+inherit xorg-2
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="http://dri.freedesktop.org/"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
+fi
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+VIDEO_CARDS="exynos intel nouveau omap radeon vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} libkms"
+RESTRICT="test" # see bug #236845
+
+RDEPEND="dev-libs/libpthread-stubs
+	video_cards_intel? ( >=x11-libs/libpciaccess-0.10 )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.4.28-solaris.patch
+)
+
+src_prepare() {
+	if [[ ${PV} = 9999* ]]; then
+		# tests are restricted, no point in building them
+		sed -ie 's/tests //' "${S}"/Makefile.am
+	fi
+	xorg-2_src_prepare
+}
+
+src_configure() {
+	XORG_CONFIGURE_OPTIONS=(
+		--enable-udev
+		$(use_enable video_cards_exynos exynos-experimental-api)
+		$(use_enable video_cards_intel intel)
+		$(use_enable video_cards_nouveau nouveau)
+		$(use_enable video_cards_omap omap-experimental-api)
+		$(use_enable video_cards_radeon radeon)
+		$(use_enable video_cards_vmware vmwgfx)
+		$(use_enable libkms)
+	)
+	xorg-2_src_configure
+}
-- 
cgit v1.2.3-65-gdbad