From fc54b772cf0d6ea0243921df05dc2ab3e1f4f486 Mon Sep 17 00:00:00 2001
From: Markos Chandras <hwoarang@gentoo.org>
Date: Sat, 18 Jun 2011 10:51:19 +0000
Subject: Revbump with patch to fix compatibility with LXDE

(Portage version: 2.2.0_alpha41/cvs/Linux x86_64)
---
 x11-misc/obconf/obconf-2.0.3_p20110314-r1.ebuild | 60 ++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 x11-misc/obconf/obconf-2.0.3_p20110314-r1.ebuild

(limited to 'x11-misc/obconf/obconf-2.0.3_p20110314-r1.ebuild')

diff --git a/x11-misc/obconf/obconf-2.0.3_p20110314-r1.ebuild b/x11-misc/obconf/obconf-2.0.3_p20110314-r1.ebuild
new file mode 100644
index 000000000000..4ca0a32fc993
--- /dev/null
+++ b/x11-misc/obconf/obconf-2.0.3_p20110314-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/obconf/obconf-2.0.3_p20110314-r1.ebuild,v 1.1 2011/06/18 10:51:19 hwoarang Exp $
+
+EAPI=2
+inherit autotools fdo-mime eutils
+
+DESCRIPTION="ObConf is a tool for configuring the Openbox window manager."
+HOMEPAGE="http://icculus.org/openbox/index.php/ObConf:About"
+SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="lxde nls"
+
+RDEPEND="gnome-base/libglade:2.0
+	x11-libs/gtk+:2
+	x11-libs/startup-notification
+	>=x11-wm/openbox-3.5.0_pre20110313"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+S=${WORKDIR}
+
+src_prepare() {
+	# need --config-file switch when used on LXDE environment
+	if use lxde; then
+		sed -i -e "/^Exec/s:obconf.*$:obconf-lxde:" ${PN}.desktop || die
+	fi
+	# Make sure the correct path is appended to the config file
+	epatch "${FILESDIR}"/${P}-config-path.patch
+	eautopoint
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	# add wrapper for lxde environment. Bug #369555
+	if use lxde; then
+		dobin "${FILESDIR}"/${PN}-lxde || die
+	fi
+	dodoc AUTHORS CHANGELOG README || die "dodoc failed"
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
-- 
cgit v1.2.3-65-gdbad