sci-libs/libpdb/libpdb-991112-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/libpdb/libpdb-991112-r1.ebuild,v 1.1 2012/10/18 16:56:01 jlec Exp $

EAPI=4

inherit eutils toolchain-funcs

DESCRIPTION="PDB Record I/O Libraries -- c version"
HOMEPAGE="http://www.cgl.ucsf.edu/Overview/software.html"
SRC_URI="mirror://gentoo/${P}.shar"

SLOT="0"
LICENSE="BSD"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="static-libs"

RDEPEND=""
DEPEND="${RDEPEND}
	app-arch/sharutils"

S="${WORKDIR}"

src_unpack() {
	"${EPREFIX}/usr/bin/unshar" "${DISTDIR}"/${A} || die
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-dynlib+flags.patch
	tc-export CC RANLIB AR
}

src_compile() {
	emake ${PN}.so
	use static-libs && emake ${PN}.a
}

src_install() {
	dolib.so ${PN}.so*
	use static-libs && dolib.a ${PN}.a

	insinto /usr/include/${PN}
	doins *.h
}