# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
##
## Created by Wolfram Schlich <wschlich@gentoo.org>
##
## TODO
## - ?
##

inherit eutils pax-utils

DESCRIPTION="AVIRA AntiVir Update Manager"
MY_P="avira_update_manager_unix-${PV%.*}-${PV##*.}"
SRC_URI="http://dl1.pro.antivir.de/package/ium/unix/en/avira_update_manager_unix_en.tar.gz"
HOMEPAGE="http://www.avira.com/"
LICENSE="AVIRA-AntiVir"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""
DEPEND=""
RDEPEND=">=app-antivirus/antivir-savapi-3"
S="${WORKDIR}/${MY_P}"
# prevent installation functions from stripping binaries
# otherwise the antivir selfcheck fails. also don't try
# to fetch the distribution tarball from a mirror.
RESTRICT="strip mirror"

#
# Settings overridable by user supplied environment variables
#

AVHOMEDIR="${AVHOMEDIR:-/usr/lib/AntiVir}"
AVCONFDIR="${AVCONFDIR:-/etc/avira}"
AVIUMHTTPDIR="${AVIUMHTTPDIR:-/var/avira/ium/HttpRoot}"
AVIUMLOGDIR="${AVIUMLOGDIR:-/var/log/ium}"
AVUSER="${AVUSER:-avgate}"
AVUID="${AVUID:-220}"
AVSH="${AVSH:--1}"
AVGROUP="${AVGROUP:-antivir}"
AVGID="${AVGID:-220}"
AVHOSTNAME="${AVHOSTNAME:-$(hostname -f)}"

pkg_setup() {

	#
	# Add USER + GROUP
	#

	enewgroup "${AVGROUP}" "${AVGID}"
	enewuser "${AVUSER}" "${AVUID}" "${AVSH}" -1 "${AVGROUP}" -c AntiVir

}

src_install() {

	#
	# Executables, libraries and misc components
	#

	exeinto "${AVHOMEDIR}/ium"
	insinto "${AVHOMEDIR}/ium"
	exeopts -oroot -g"${AVGROUP}" -m2750
	insopts -oroot -g"${AVGROUP}" -m0640
	doexe bin/linux_glibc22/ium
	doins bin/linux_glibc22/ium_msg.avr
	doins bin/linux_glibc22/libcommon.so
	doins bin/linux_glibc22/common_msg.avr
	doins etc/iumproducts.xml

	local libupdate_ver=0.1.0.33
	doins bin/linux_glibc22/libupdate.so.${libupdate_ver}
	dosym "libupdate.so.${libupdate_ver}" "${AVHOMEDIR}/ium/libupdate.so.0"
	dosym "libupdate.so.${libupdate_ver}" "${AVHOMEDIR}/ium/libupdate.so"

	diropts ""
	dodir "${DESTTREE}/sbin"
	dosym "${AVHOMEDIR}/ium/ium" "${DESTTREE}/sbin/avium"

	newexe script/avira_start.sh.template avium
	doexe script/avium_start.sh
	doexe script/avium_restart.sh
	doexe script/avium_stop.sh

	insinto "${AVHOMEDIR}/ium/ssl"
	doins cert/cacert.pem
	doins cert/server.pem

	#
	# Init script
	#

	exeopts -oroot -groot -m0755
	exeinto /etc/init.d
	newexe "${FILESDIR}/${PV}/antivir-ium.init.d" antivir-ium

	#
	# Config
	#

	insopts -oroot -g"${AVGROUP}" -m0640
	insinto "${AVCONFDIR}"
	doins "${FILESDIR}"/${PV}/ium.conf
	dosed "s:%AVIUMHTTPDIR%:${AVIUMHTTPDIR}:g" "${AVCONFDIR}/ium.conf"
	doins "${FILESDIR}"/${PV}/mirrorconfig.xml

	#
	# IUM log directory
	#

	diropts -o"${AVUSER}" -g"${AVGROUP}" -m0750
	dodir "${AVIUMLOGDIR}"
	dodir "${AVIUMHTTPDIR}"

	#
	# Documents
	#

	dodoc \
		LICENSE \
		LICENSE.DE \
		README \
		doc/MANUAL

	#
	# Templates
	#

	insinto "${AVHOMEDIR}/ium"
	insopts -m0644
	doins templates/*.htm
	doins doc/mail_template_iumstatus.txt

}

pkg_postinst() {

	#
	# Manual invocation
	#

	elog
	elog "Manually adding products to get updates for"
	elog "==========================================="
	elog
	elog "  ${AVHOMEDIR}/ium/ium --add_products"
	elog
	elog "Manually getting updates for products"
	elog "====================================="
	elog
	elog "  ${AVHOMEDIR}/ium/ium --get_updates"
	elog

	echo

	#
	# Automatic updates for products
	#

	rand="$(date +%N 2>/dev/null)"
	min="$[ (${rand:-${RANDOM}} % 59) + 1 ]"
	elog
	elog "Automatically getting updates for products"
	elog "=========================================="
	elog
	elog "Add the following line to your /etc/crontab or a new file"
	elog "in /etc/cron.d/ to make AntiVir check for updates"
	elog "${min} minutes after every full hour:"
	elog
	elog "  ${min} * * * * root exec ${AVHOMEDIR}/ium/ium --get_updates >/dev/null"
	elog

	echo

	#
	# Automatic updates for IUM
	#

	rand="$(date +%N 2>/dev/null)"
	min="$[ (${rand:-${RANDOM}} % 59) + 1 ]"
	elog
	elog "Automatically getting updates for IUM itself"
	elog "==========================================="
	elog
	elog "Add the following line to your /etc/crontab or a new file"
	elog "in /etc/cron.d/ to make AntiVir check for updates"
	elog "${min} minutes after every full hour:"
	elog
	elog "  ${min} * * * * root exec ${AVHOMEDIR}/avupdate --product=IUM >/dev/null"
	elog

	echo

	#
	# Client configuration info
	#

	elog
	elog "Configuring clients"
	elog "==================="
	elog
	elog "Windows clients"
	elog "---------------"
	elog
	elog "Options -> General -> Update -> Webserver -> Download Server:"
	elog "  http://iumserver:7080/upd"
	elog
	elog "Linux clients"
	elog "-------------"
	elog
	elog "For SAVAPI2 products add these two options in /etc/avupdater.conf:"
	elog "  HTTPUpdateServer 'iumserver':7080"
	elog "  IgnoreRemoteServerSpec yes"
	elog
	elog "For SAVAPI3 products adjust /etc/avupdate.conf as follows:"
	elog "  internet-srvs=http://iumserver:7080/upd"
	elog

	echo

	#
	# Templates
	#

	elog
	elog "Using the HTML templates"
	elog "========================"
	elog
	elog "The templates were installed into"
	elog
	elog "\t${AVHOMEDIR}/ium"
	elog

}