9 files changed, 582 insertions, 0 deletions
diff --git a/Bugzilla/BugUrl/Bugzilla.pm b/Bugzilla/BugUrl/Bugzilla.pm
new file mode 100644
index 000000000..53f174556
--- /dev/null
+++ b/Bugzilla/BugUrl/Bugzilla.pm
@@ -0,0 +1,67 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Tiago Mello.
+# Portions created by Tiago Mello are Copyright (C) 2010
+# Tiago Mello. All Rights Reserved.
+#
+# Contributor(s): Tiago Mello <timello@linux.vnet.ibm.com>
+#                 Max Kanat-Alexander <mkanat@bugzilla.org>
+
+package Bugzilla::BugUrl::Bugzilla;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->path =~ /show_bug\.cgi$/) ? 1 : 0;
+}
+
+sub _check_value {
+    my ($class, $uri) = @_;
+
+    $uri = $class->SUPER::_check_value($uri);
+
+    my $bug_id = $uri->query_param('id');
+    # We don't currently allow aliases, because we can't check to see
+    # if somebody's putting both an alias link and a numeric ID link.
+    # When we start validating the URL by accessing the other Bugzilla,
+    # we can allow aliases.
+    detaint_natural($bug_id);
+    if (!$bug_id) {
+        my $value = $uri->as_string;
+        ThrowUserError('bug_url_invalid', { url => $value, reason => 'id' });
+    }
+
+    # Make sure that "id" is the only query parameter.
+    $uri->query("id=$bug_id");
+    # And remove any # part if there is one.
+    $uri->fragment(undef);
+
+    return $uri;
+}
+
+sub target_bug_id {
+    my ($self) = @_;
+    return new URI($self->name)->query_param('id');
+}
+
+1;
diff --git a/Bugzilla/BugUrl/Bugzilla/Local.pm b/Bugzilla/BugUrl/Bugzilla/Local.pm
new file mode 100644
index 000000000..99f944fa6
--- /dev/null
+++ b/Bugzilla/BugUrl/Bugzilla/Local.pm
@@ -0,0 +1,111 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Tiago Mello.
+# Portions created by Tiago Mello are Copyright (C) 2010
+# Tiago Mello. All Rights Reserved.
+#
+# Contributor(s): Tiago Mello <timello@linux.vnet.ibm.com>
+
+package Bugzilla::BugUrl::Bugzilla::Local;
+use strict;
+use base qw(Bugzilla::BugUrl::Bugzilla);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####    Initialization     ####
+###############################
+
+use constant VALIDATOR_DEPENDENCIES => {
+    value => ['bug_id'],
+};
+
+###############################
+####        Methods        ####
+###############################
+
+sub ref_bug_url {
+    my $self = shift;
+
+    if (!exists $self->{ref_bug_url}) {
+        my $ref_bug_id = new URI($self->name)->query_param('id');
+        my $ref_bug = Bugzilla::Bug->check($ref_bug_id);
+        my $ref_value = $self->local_uri($self->bug_id);
+        $self->{ref_bug_url} =
+            new Bugzilla::BugUrl::Bugzilla::Local({ bug_id => $ref_bug->id,
+                                                    value => $ref_value });
+    }
+    return $self->{ref_bug_url};
+}
+
+sub should_handle {
+    my ($class, $uri) = @_;
+
+    # Check if it is either a bug id number or an alias.
+    return 1 if $uri->as_string =~ m/^\w+$/;
+
+    # Check if it is a local Bugzilla uri and call
+    # Bugzilla::BugUrl::Bugzilla to check if it's a valid Bugzilla
+    # see also url.
+    my $canonical_local = URI->new($class->local_uri)->canonical;
+    if ($canonical_local->authority eq $uri->canonical->authority
+        and $canonical_local->path eq $uri->canonical->path)
+    {
+        return $class->SUPER::should_handle($uri);
+    }
+
+    return 0;
+}
+
+sub _check_value {
+    my ($class, $uri, undef, $params) = @_;
+
+    # At this point we are going to treat any word as a
+    # bug id/alias to the local Bugzilla.
+    my $value = $uri->as_string;
+    if ($value =~ m/^\w+$/) {
+        $uri = new URI($class->local_uri($value));
+    } else {
+        # It's not a word, then we have to check
+        # if it's a valid Bugzilla url.
+        $uri = $class->SUPER::_check_value($uri);
+    }
+
+    my $ref_bug_id  = $uri->query_param('id');
+    my $ref_bug     = Bugzilla::Bug->check($ref_bug_id);
+    my $self_bug_id = $params->{bug_id};
+    $params->{ref_bug} = $ref_bug;
+
+    if ($ref_bug->id == $self_bug_id) {
+        ThrowUserError('see_also_self_reference');
+    }
+ 
+    my $product = $ref_bug->product_obj;
+    if (!Bugzilla->user->can_edit_product($product->id)) {
+        ThrowUserError("product_edit_denied",
+                       { product => $product->name });
+    }
+
+    return $uri;
+}
+
+sub local_uri {
+    my ($self, $bug_id) = @_;
+    $bug_id ||= '';
+    return correct_urlbase() . "show_bug.cgi?id=$bug_id";
+}
+
+1;
diff --git a/Bugzilla/BugUrl/Debian.pm b/Bugzilla/BugUrl/Debian.pm
new file mode 100644
index 000000000..7f73feea7
--- /dev/null
+++ b/Bugzilla/BugUrl/Debian.pm
@@ -0,0 +1,63 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Tiago Mello.
+# Portions created by Tiago Mello are Copyright (C) 2010
+# Tiago Mello. All Rights Reserved.
+#
+# Contributor(s): Tiago Mello <timello@linux.vnet.ibm.com>
+#                 Reed Loden <reed@reedloden.com>
+
+package Bugzilla::BugUrl::Debian;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->authority =~ /^bugs.debian.org$/i) ? 1 : 0;
+}
+
+sub _check_value {
+    my $class = shift;
+
+    my $uri = $class->SUPER::_check_value(@_);
+
+    # Debian BTS URLs can look like various things:
+    #   http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=1234
+    #   http://bugs.debian.org/1234
+    my $bug_id;
+    if ($uri->path =~ m|^/(\d+)$|) {
+        $bug_id = $1;
+    }
+    elsif ($uri->path =~ /bugreport\.cgi$/) {
+        $bug_id = $uri->query_param('bug');
+        detaint_natural($bug_id);
+    }
+    if (!$bug_id) {
+        ThrowUserError('bug_url_invalid',
+                       { url => $uri->path, reason => 'id' });
+    }
+    # This is the shortest standard URL form for Debian BTS URLs,
+    # and so we reduce all URLs to this.
+    return new URI("http://bugs.debian.org/" . $bug_id);
+}
+
+1;
diff --git a/Bugzilla/BugUrl/Google.pm b/Bugzilla/BugUrl/Google.pm
new file mode 100644
index 000000000..792699e50
--- /dev/null
+++ b/Bugzilla/BugUrl/Google.pm
@@ -0,0 +1,65 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Tiago Mello.
+# Portions created by Tiago Mello are Copyright (C) 2010
+# Tiago Mello. All Rights Reserved.
+#
+# Contributor(s): Tiago Mello <timello@linux.vnet.ibm.com>
+#                 Reed Loden <reed@reedloden.com>
+
+package Bugzilla::BugUrl::Google;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->authority =~ /^code.google.com$/i) ? 1 : 0;
+}
+
+sub _check_value {
+    my ($class, $uri) = @_;
+    
+    $uri = $class->SUPER::_check_value($uri);
+
+    my $value = $uri->as_string;
+    # Google Code URLs only have one form:
+    #   http(s)://code.google.com/p/PROJECT_NAME/issues/detail?id=1234
+    my $project_name;
+    if ($uri->path =~ m|^/p/([^/]+)/issues/detail$|) {
+        $project_name = $1;
+    } else {
+        ThrowUserError('bug_url_invalid', { url => $value });
+    }
+    my $bug_id = $uri->query_param('id');
+    detaint_natural($bug_id);
+    if (!$bug_id) {
+        ThrowUserError('bug_url_invalid', { url => $value, reason => 'id' });
+    }
+    # While Google Code URLs can be either HTTP or HTTPS,
+    # always go with the HTTP scheme, as that's the default.
+    $value = "http://code.google.com/p/" . $project_name .
+             "/issues/detail?id=" . $bug_id;
+
+    return new URI($value);
+}
+
+1;
diff --git a/Bugzilla/BugUrl/JIRA.pm b/Bugzilla/BugUrl/JIRA.pm
new file mode 100644
index 000000000..d0adcfed8
--- /dev/null
+++ b/Bugzilla/BugUrl/JIRA.pm
@@ -0,0 +1,54 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Matt Selsky
+# Portions created by Matt Selsky are Copyright (C) 2010
+# Matt Selsky. All Rights Reserved.
+#
+# Contributor(s): Matt Selsky <selsky@columbia.edu>
+
+package Bugzilla::BugUrl::JIRA;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->path =~ m|/browse/[A-Z][A-Z]+-\d+$|) ? 1 : 0;
+}
+
+sub _check_value {
+    my $class = shift;
+
+    my $uri = $class->SUPER::_check_value(@_);
+
+    # JIRA URLs have only one basic form (but the jira is optional):
+    #   https://issues.apache.org/jira/browse/KEY-1234
+    #   http://issues.example.com/browse/KEY-1234
+
+    # Make sure there are no query parameters.
+    $uri->query(undef);
+    # And remove any # part if there is one.
+    $uri->fragment(undef);
+
+    return $uri;
+}
+
+1;
diff --git a/Bugzilla/BugUrl/Launchpad.pm b/Bugzilla/BugUrl/Launchpad.pm
new file mode 100644
index 000000000..a5457fda9
--- /dev/null
+++ b/Bugzilla/BugUrl/Launchpad.pm
@@ -0,0 +1,59 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Tiago Mello.
+# Portions created by Tiago Mello are Copyright (C) 2010
+# Tiago Mello. All Rights Reserved.
+#
+# Contributor(s): Tiago Mello <timello@linux.vnet.ibm.com>
+#                 Max Kanat-Alexander <mkanat@bugzilla.org>
+
+package Bugzilla::BugUrl::Launchpad;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->authority =~ /launchpad.net$/) ? 1 : 0;
+}
+
+sub _check_value {
+    my ($class, $uri) = @_;
+
+    $uri = $class->SUPER::_check_value($uri);
+
+    my $value = $uri->as_string;
+    # Launchpad bug URLs can look like various things:
+    #   https://bugs.launchpad.net/ubuntu/+bug/1234
+    #   https://launchpad.net/bugs/1234
+    # All variations end with either "/bugs/1234" or "/+bug/1234"
+    if ($uri->path =~ m|bugs?/(\d+)$|) {
+        # This is the shortest standard URL form for Launchpad bugs,
+        # and so we reduce all URLs to this.
+        $value = "https://launchpad.net/bugs/$1";
+    }
+    else {
+        ThrowUserError('bug_url_invalid', { url => $value, reason => 'id' });
+    }
+
+    return new URI($value);
+}
+
+1;
diff --git a/Bugzilla/BugUrl/MantisBT.pm b/Bugzilla/BugUrl/MantisBT.pm
new file mode 100644
index 000000000..c525b0b2f
--- /dev/null
+++ b/Bugzilla/BugUrl/MantisBT.pm
@@ -0,0 +1,51 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Reed Loden.
+# Portions created by Reed Loden are Copyright (C) 2010
+# Reed Loden. All Rights Reserved.
+#
+# Contributor(s): Reed Loden <reed@reedloden.com>
+
+package Bugzilla::BugUrl::MantisBT;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->path_query =~ m|view\.php\?id=\d+$|) ? 1 : 0;
+}
+
+sub _check_value {
+    my $class = shift;
+
+    my $uri = $class->SUPER::_check_value(@_);
+
+    # MantisBT URLs look like the following ('bugs' directory is optional):
+    #   http://www.mantisbt.org/bugs/view.php?id=1234
+
+    # Remove any # part if there is one.
+    $uri->fragment(undef);
+
+    return $uri;
+}
+
+1;
diff --git a/Bugzilla/BugUrl/SourceForge.pm b/Bugzilla/BugUrl/SourceForge.pm
new file mode 100644
index 000000000..fffa96d52
--- /dev/null
+++ b/Bugzilla/BugUrl/SourceForge.pm
@@ -0,0 +1,58 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Tiago Mello
+# Portions created by Tiago Mello are Copyright (C) 2011
+# Tiago Mello. All Rights Reserved.
+#
+# Contributor(s): Tiago Mello <timello@linux.vnet.ibm.com>
+
+package Bugzilla::BugUrl::SourceForge;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->authority =~ /^sourceforge.net$/i
+            and $uri->path =~ m|/tracker/|) ? 1 : 0;
+}
+
+sub _check_value {
+    my $class = shift;
+
+    my $uri = $class->SUPER::_check_value(@_);
+
+    # SourceForge tracker URLs have only one form:
+    #  http://sourceforge.net/tracker/?func=detail&aid=111&group_id=111&atid=111
+    if ($uri->query_param('func') eq 'detail' and $uri->query_param('aid')
+        and $uri->query_param('group_id') and $uri->query_param('atid'))
+    {
+        # Remove any # part if there is one.
+        $uri->fragment(undef);
+        return $uri;
+    }
+    else {
+        my $value = $uri->as_string;
+        ThrowUserError('bug_url_invalid', { url => $value });
+    }
+}
+
+1;
diff --git a/Bugzilla/BugUrl/Trac.pm b/Bugzilla/BugUrl/Trac.pm
new file mode 100644
index 000000000..638bd779e
--- /dev/null
+++ b/Bugzilla/BugUrl/Trac.pm
@@ -0,0 +1,54 @@
+# -*- Mode: perl; indent-tabs-mode: nil -*-
+#
+# The contents of this file are subject to the Mozilla Public
+# License Version 1.1 (the "License"); you may not use this file
+# except in compliance with the License. You may obtain a copy of
+# the License at http://www.mozilla.org/MPL/
+#
+# Software distributed under the License is distributed on an "AS
+# IS" basis, WITHOUT WARRANTY OF ANY KIND, either express or
+# implied. See the License for the specific language governing
+# rights and limitations under the License.
+#
+# The Original Code is the Bugzilla Bug Tracking System.
+#
+# The Initial Developer of the Original Code is Matt Selsky
+# Portions created by Matt Selsky are Copyright (C) 2010
+# Matt Selsky. All Rights Reserved.
+#
+# Contributor(s): Matt Selsky <selsky@columbia.edu>
+
+package Bugzilla::BugUrl::Trac;
+use strict;
+use base qw(Bugzilla::BugUrl);
+
+use Bugzilla::Error;
+use Bugzilla::Util;
+
+###############################
+####        Methods        ####
+###############################
+
+sub should_handle {
+    my ($class, $uri) = @_;
+    return ($uri->path =~ m|/ticket/\d+$|) ? 1 : 0;
+}
+
+sub _check_value {
+    my $class = shift;
+
+    my $uri = $class->SUPER::_check_value(@_);
+
+    # Trac URLs can look like various things:
+    #   http://dev.mutt.org/trac/ticket/1234
+    #   http://trac.roundcube.net/ticket/1484130
+
+    # Make sure there are no query parameters.
+    $uri->query(undef);
+    # And remove any # part if there is one.
+    $uri->fragment(undef);
+
+    return $uri;
+}
+
+1;