media-sound/gmusicbrowser: rework to utilize USE flags fully

also update pkg_postinst message
Closes: https://github.com/gentoo/gentoo/pull/2661

Signed-off-by: David Seifert <soap@gentoo.org>

3 files changed, 85 insertions, 19 deletions

diff --git a/media-sound/gmusicbrowser/gmusicbrowser-1.1.15-r2.ebuild b/media-sound/gmusicbrowser/gmusicbrowser-1.1.15-r2.ebuild
new file mode 100644
index 000000000000..8f43b0479144
--- /dev/null
+++ b/media-sound/gmusicbrowser/gmusicbrowser-1.1.15-r2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit fdo-mime gnome2-utils
+
+DESCRIPTION="An open-source jukebox for large collections of mp3/ogg/flac files"
+HOMEPAGE="http://gmusicbrowser.org/"
+SRC_URI="http://${PN}.org/download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbus extras gstreamer libnotify mplayer"
+
+GSTREAMER_DEPEND="
+	dev-perl/GStreamer
+	dev-perl/GStreamer-Interfaces
+	media-plugins/gst-plugins-meta:0.10"
+MPLAYER_DEPEND="media-video/mplayer"
+MPV_DEPEND="media-video/mpv"
+OTHER_DEPEND="
+	media-sound/alsa-utils
+	media-sound/flac123
+	|| ( media-sound/mpg123 media-sound/mpg321 )
+	media-sound/vorbis-tools"
+
+RDEPEND="dev-lang/perl
+	dev-perl/gtk2-perl
+	virtual/perl-MIME-Base64
+	|| ( net-misc/wget dev-perl/AnyEvent-HTTP )
+	dbus? ( dev-perl/Net-DBus )
+	gstreamer? ( ${GSTREAMER_DEPEND} )
+	mplayer? ( || ( ${MPLAYER_DEPEND} ${MPV_DEPEND} ) )
+	!gstreamer? ( !mplayer? ( ${OTHER_DEPEND} ) )
+	extras? ( dev-perl/gnome2-wnck )
+	libnotify? ( dev-perl/Gtk2-Notify )"
+DEPEND="sys-devel/gettext"
+
+src_install() {
+	emake \
+		DOCS="AUTHORS NEWS README" \
+		DESTDIR="${D}" \
+		iconsdir="${D}/usr/share/icons/hicolor" \
+		install
+
+	dohtml layout_doc.html
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+
+	elog "Gmusicbrowser supports gstreamer, mplayer, mpv and mpg123/ogg123..."
+	elog "for audio playback. Needed dependencies:"
+	elog "  Gstreamer: ${GSTREAMER_DEPEND}"
+	elog "  mplayer: ${MPLAYER_DEPEND}"
+	elog "  mpv: ${MPV_DEPEND}"
+	elog "  mpg123/ogg123...: ${OTHER_DEPEND}"
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild b/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild
index 3ac52e635b65..d83ca18de9f9 100644
--- a/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild
+++ b/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild
@@ -13,7 +13,7 @@ EGIT_REPO_URI="git://github.com/squentin/${PN}.git"
 LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS=""
-IUSE="doc"
+IUSE="dbus doc extras gstreamer libnotify mplayer"
 
 GSTREAMER_DEPEND="
 	dev-perl/GStreamer
@@ -31,12 +31,12 @@ RDEPEND="dev-lang/perl
 	dev-perl/gtk2-perl
 	virtual/perl-MIME-Base64
 	|| ( net-misc/wget dev-perl/AnyEvent-HTTP )
-	|| (
-		( ${GSTREAMER_DEPEND} )
-		( ${MPLAYER_DEPEND} )
-		( ${MPV_DEPEND} )
-		( ${OTHER_DEPEND} )
-	)"
+	dbus? ( dev-perl/Net-DBus )
+	gstreamer? ( ${GSTREAMER_DEPEND} )
+	mplayer? ( || ( ${MPLAYER_DEPEND} ${MPV_DEPEND} ) )
+	!gstreamer? ( !mplayer? ( ${OTHER_DEPEND} ) )
+	extras? ( dev-perl/gnome2-wnck )
+	libnotify? ( dev-perl/Gtk2-Notify )"
 DEPEND="sys-devel/gettext
 	doc? ( dev-perl/Text-Markdown )"
 
@@ -64,18 +64,10 @@ pkg_postinst() {
 
 	elog "Gmusicbrowser supports gstreamer, mplayer, mpv and mpg123/ogg123..."
 	elog "for audio playback. Needed dependencies:"
-	elog "Gstreamer: ${GSTREAMER_DEPEND}"
-	elog "mplayer: ${MPLAYER_DEPEND}"
-	elog "mpv: ${MPV_DEPEND}"
-	elog "mpg123/ogg123...: ${OTHER_DEPEND}"
-	elog
-	elog "This ebuild just ensures at least one implementation is installed!"
-	elog
-	elog "other optional dependencies:"
-	elog "	dev-perl/Net-DBus (for dbus support and mpris1/2 plugins)"
-	elog "	dev-perl/Gtk2-WebKit (for Web context plugin)"
-	elog "	dev-perl/Gtk2-Notify (for Notify plugin)"
-	elog "	dev-perl/gnome2-wnck (for Titlebar plugin)"
+	elog "  Gstreamer: ${GSTREAMER_DEPEND}"
+	elog "  mplayer: ${MPLAYER_DEPEND}"
+	elog "  mpv: ${MPV_DEPEND}"
+	elog "  mpg123/ogg123...: ${OTHER_DEPEND}"
 }
 
 pkg_postrm() {
diff --git a/media-sound/gmusicbrowser/metadata.xml b/media-sound/gmusicbrowser/metadata.xml
index 99330a633e99..6c2c0dcaa759 100644
--- a/media-sound/gmusicbrowser/metadata.xml
+++ b/media-sound/gmusicbrowser/metadata.xml
@@ -10,4 +10,7 @@
 		<email>sound@gentoo.org</email>
 		<name>Gentoo Sound project</name>
 	</maintainer>
+	<use>
+		<flag name="extras">Install some extra deps for plugins (ex. Titlebar)</flag>
+	</use>
 </pkgmetadata>