1 files changed, 45 insertions, 0 deletions
diff --git a/kde-apps/analitza/analitza-16.12.0.ebuild b/kde-apps/analitza/analitza-16.12.0.ebuild
new file mode 100644
index 000000000000..6294dd9d9d2a
--- /dev/null
+++ b/kde-apps/analitza/analitza-16.12.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+KDE_TEST="forceoptional-recursive"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE library for mathematical features"
+KEYWORDS="~amd64 ~x86"
+IUSE="eigen opengl"
+
+DEPEND="
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtsvg)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	eigen? ( dev-cpp/eigen:3 )
+	opengl? (
+		$(add_qt_dep qtopengl)
+		virtual/opengl
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# Nothing is installed
+	sed -i \
+		-e "/add_subdirectory(examples)/ s/^/#DONT/" \
+		analitzaplot/CMakeLists.txt || die
+
+	kde5_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package eigen Eigen3)
+		$(cmake-utils_use_find_package opengl OpenGL)
+	)
+
+	kde5_src_configure
+}