From 9994316821c7cbf81f05f86f59fb159b202bad00 Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Mon, 6 Nov 2023 19:14:51 +0100
Subject: app-doc/devmanual: add 0_pre20231106
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Update PYTHON_COMPAT.

Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 app-doc/devmanual/Manifest                       |  1 +
 app-doc/devmanual/devmanual-0_pre20231106.ebuild | 60 ++++++++++++++++++++++++
 app-doc/devmanual/devmanual-9999.ebuild          |  2 +-
 3 files changed, 62 insertions(+), 1 deletion(-)
 create mode 100644 app-doc/devmanual/devmanual-0_pre20231106.ebuild

(limited to 'app-doc')

diff --git a/app-doc/devmanual/Manifest b/app-doc/devmanual/Manifest
index b7c9b231462d..3203fa07ba8e 100644
--- a/app-doc/devmanual/Manifest
+++ b/app-doc/devmanual/Manifest
@@ -1 +1,2 @@
 DIST devmanual-0_pre20230121.tar.xz 185536 BLAKE2B e099b3644ee84148f6ab7630934beb80420501aae76774949ec16529d64716c09bfc26a0e7a3641c5cc2809adbf00e5560b04182840799e229b30182e4920dd6 SHA512 370cb49d5b257f8efc872bc5c85a53aabb3a01fc0fc8d1f65144e27a5ff578286a25987e62fc9874dfdda7bf4864e7921d31e97f43db12e75bd59b429314d369
+DIST devmanual-0_pre20231106.tar.xz 187040 BLAKE2B 20992be79db2b581234a813740bd59c697af624d6edc86e29375078b63cdc13bed3eae116e21d2b82d568703983860cae7be00649f24eb90f2a6f6b7837525d7 SHA512 0434e0155876dff01105ac014528d8abaa19631c5b260d2c8c995c417053403ae652d4e082d0a08549994e3238024ed2592b145c6b0435ed84f87397fb7aeacc
diff --git a/app-doc/devmanual/devmanual-0_pre20231106.ebuild b/app-doc/devmanual/devmanual-0_pre20231106.ebuild
new file mode 100644
index 000000000000..13af86d6e06c
--- /dev/null
+++ b/app-doc/devmanual/devmanual-0_pre20231106.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12} )
+PYTHON_REQ_USE="xml(+)"
+inherit python-any-r1 readme.gentoo-r1
+
+DESCRIPTION="The Gentoo Development Guide"
+HOMEPAGE="https://devmanual.gentoo.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/devmanual.git"
+else
+	# "make dist" in devmanual repo
+	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+fi
+
+LICENSE="CC-BY-SA-4.0"
+SLOT="0"
+IUSE="+offline test"
+RESTRICT="!test? ( test )"
+
+BDEPEND=">=dev-libs/libxml2-2.9.12
+	dev-libs/libxslt
+	gnome-base/librsvg
+	media-fonts/open-sans
+	${PYTHON_DEPS}
+	test? ( >=app-text/htmltidy-5.8.0 )"
+
+PATCHES=( "${FILESDIR}"/${PN}-eclasses.patch )
+
+src_compile() {
+	emake OFFLINE=$(usex offline 1 0)
+}
+
+src_install() {
+	emake OFFLINE=$(usex offline 1 0) \
+		DESTDIR="${D}" \
+		htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	local DOC_CONTENTS="In order to browse the Gentoo Development Guide in
+		offline mode, point your browser to the following url:
+		file://${EPREFIX}/usr/share/doc/${PF}/html/index.html"
+	if ! has_version app-doc/eclass-manpages; then
+		DOC_CONTENTS+="\\n\\nThe offline version of the devmanual does not
+			include the documentation for the eclasses. If you need it,
+			then emerge app-doc/eclass-manpages."
+	fi
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
diff --git a/app-doc/devmanual/devmanual-9999.ebuild b/app-doc/devmanual/devmanual-9999.ebuild
index f48fa93aeb42..13af86d6e06c 100644
--- a/app-doc/devmanual/devmanual-9999.ebuild
+++ b/app-doc/devmanual/devmanual-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9,10,11} )
+PYTHON_COMPAT=( python3_{9,10,11,12} )
 PYTHON_REQ_USE="xml(+)"
 inherit python-any-r1 readme.gentoo-r1
 
-- 
cgit v1.2.3-65-gdbad