From aa7954f2eed1aa85f1266e31c0c483a4c774eb17 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sat, 31 Jul 2021 23:16:23 +0100
Subject: app-misc/abook: fix DEPEND, simplify ebuild

- Fix DEPEND to include RDEPEND
- Note that gettext is used as a header too, so DEPEND as well
- Simplify src_compile / use flag-o-matic
- Drop src_install

Thanks-to: David Seifert <soap@gentoo.org>
Signed-off-by: Sam James <sam@gentoo.org>
---
 app-misc/abook/abook-0.6.1-r3.ebuild | 58 ------------------------------------
 app-misc/abook/abook-0.6.1-r4.ebuild | 57 +++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+), 58 deletions(-)
 delete mode 100644 app-misc/abook/abook-0.6.1-r3.ebuild
 create mode 100644 app-misc/abook/abook-0.6.1-r4.ebuild

(limited to 'app-misc/abook')

diff --git a/app-misc/abook/abook-0.6.1-r3.ebuild b/app-misc/abook/abook-0.6.1-r3.ebuild
deleted file mode 100644
index d0229f26585a..000000000000
--- a/app-misc/abook/abook-0.6.1-r3.ebuild
+++ /dev/null
@@ -1,58 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools
-
-MY_P="${P/_/}"
-DESCRIPTION="Abook is a text-based addressbook program designed to use with mutt mail client"
-HOMEPAGE="http://abook.sourceforge.net/"
-SRC_URI="http://abook.sourceforge.net/devel/${MY_P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 ppc ppc64 sparc x86"
-IUSE="nls"
-
-RDEPEND="
-	sys-libs/ncurses:=
-	sys-libs/readline:=
-	dev-libs/libvformat
-	nls? ( virtual/libintl )"
-
-DEPEND="
-	sys-devel/autoconf-archive
-	virtual/pkgconfig
-	nls? ( sys-devel/gettext )
-"
-
-S="${WORKDIR}/${MY_P}"
-
-DOCS=( BUGS ChangeLog FAQ README TODO sample.abookrc )
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.6.1-use-PKG_CHECK_MODULES-for-ncurses.patch
-	"${FILESDIR}"/${PN}-0.6.1-use-newer-macro-for-readline.patch
-	"${FILESDIR}"/${PN}-0.6.1-vformat.patch
-)
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		--enable-vformat \
-		$(use_enable nls)
-}
-
-src_compile() {
-	# bug 570428
-	emake CFLAGS="${CFLAGS} -std=gnu89"
-}
-
-src_install() {
-	default
-}
diff --git a/app-misc/abook/abook-0.6.1-r4.ebuild b/app-misc/abook/abook-0.6.1-r4.ebuild
new file mode 100644
index 000000000000..f6e46075e42e
--- /dev/null
+++ b/app-misc/abook/abook-0.6.1-r4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+MY_P="${P/_/}"
+DESCRIPTION="Abook is a text-based addressbook program designed to use with mutt mail client"
+HOMEPAGE="http://abook.sourceforge.net/"
+SRC_URI="http://abook.sourceforge.net/devel/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ppc ppc64 sparc x86"
+IUSE="nls"
+
+RDEPEND="
+	sys-libs/ncurses:=
+	sys-libs/readline:=
+	dev-libs/libvformat
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+BDEPEND="
+	sys-devel/autoconf-archive
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( BUGS ChangeLog FAQ README TODO sample.abookrc )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.1-use-PKG_CHECK_MODULES-for-ncurses.patch
+	"${FILESDIR}"/${PN}-0.6.1-use-newer-macro-for-readline.patch
+	"${FILESDIR}"/${PN}-0.6.1-vformat.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-vformat \
+		$(use_enable nls)
+}
+
+src_compile() {
+	# bug #570428
+	append-cflags -std=gnu89
+
+	emake CFLAGS="${CFLAGS}"
+}
-- 
cgit v1.2.3-65-gdbad