From b8392461748b972a4d5c054d8f7986a9f678c2be Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sat, 8 Jun 2024 14:01:32 +0200
Subject: dev-cpp/gstreamermm: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 dev-cpp/gstreamermm/gstreamermm-1.10.0-r1.ebuild | 68 -----------------------
 dev-cpp/gstreamermm/gstreamermm-1.10.0-r2.ebuild | 69 ++++++++++++++++++++++++
 2 files changed, 69 insertions(+), 68 deletions(-)
 delete mode 100644 dev-cpp/gstreamermm/gstreamermm-1.10.0-r1.ebuild
 create mode 100644 dev-cpp/gstreamermm/gstreamermm-1.10.0-r2.ebuild

(limited to 'dev-cpp')

diff --git a/dev-cpp/gstreamermm/gstreamermm-1.10.0-r1.ebuild b/dev-cpp/gstreamermm/gstreamermm-1.10.0-r1.ebuild
deleted file mode 100644
index a950c1971927..000000000000
--- a/dev-cpp/gstreamermm/gstreamermm-1.10.0-r1.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit gnome2 virtualx
-
-DESCRIPTION="C++ interface for GStreamer"
-HOMEPAGE="https://gstreamer.freedesktop.org/bindings/cplusplus.html"
-
-LICENSE="LGPL-2.1"
-SLOT="1.0/1"
-KEYWORDS="amd64 ~ppc x86"
-IUSE="doc examples test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=media-libs/gstreamer-${PV}:1.0
-	>=media-libs/gst-plugins-base-${PV}:1.0
-	>=dev-cpp/glibmm-2.47.6:2
-	>=dev-cpp/libxmlpp-2.14:2.6
-	>=dev-libs/libsigc++-2:2
-"
-DEPEND="${RDEPEND}
-	dev-cpp/mm-common
-	virtual/pkgconfig
-	doc? (
-		app-text/doxygen
-		dev-libs/libxslt
-		media-gfx/graphviz )
-	test? (
-		dev-cpp/gtest
-		>=media-libs/gst-plugins-base-${PV}:1.0[X,ogg,theora,vorbis]
-		>=media-libs/gst-plugins-good-${PV}:1.0
-		>=media-plugins/gst-plugins-jpeg-${PV}:1.0 )
-"
-# eautoreconf:
-#	dev-cpp/mm-common
-
-# Installs reference docs into /usr/share/doc/gstreamermm-1.0/
-# but that's okay, because the rest of dev-cpp/*mm stuff does the same
-
-PATCHES=(
-	"${FILESDIR}"/${P}-no-volatile.patch
-)
-
-src_prepare() {
-	if ! use examples; then
-		# don't waste time building examples
-		sed -e 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' \
-			-i Makefile.am Makefile.in || die
-	fi
-
-	sed -e 's/ -Werror/ /' -i tests/Makefile.am tests/Makefile.in || die
-
-	gnome2_src_prepare
-}
-
-src_configure() {
-	gnome2_src_configure \
-		$(use_enable doc documentation) \
-		$(use_enable test unittests)
-}
-
-src_test() {
-	# running tests in parallel fails
-	virtx emake -j1 check
-}
diff --git a/dev-cpp/gstreamermm/gstreamermm-1.10.0-r2.ebuild b/dev-cpp/gstreamermm/gstreamermm-1.10.0-r2.ebuild
new file mode 100644
index 000000000000..e9ba634485f7
--- /dev/null
+++ b/dev-cpp/gstreamermm/gstreamermm-1.10.0-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 virtualx
+
+DESCRIPTION="C++ interface for GStreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/bindings/cplusplus.html"
+
+LICENSE="LGPL-2.1"
+SLOT="1.0/1"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=media-libs/gstreamer-${PV}:1.0
+	>=media-libs/gst-plugins-base-${PV}:1.0
+	>=dev-cpp/glibmm-2.47.6:2
+	>=dev-cpp/libxmlpp-2.14:2.6
+	>=dev-libs/libsigc++-2:2"
+DEPEND="${RDEPEND}
+	test? (
+		dev-cpp/gtest
+		>=media-libs/gst-plugins-base-${PV}:1.0[X,ogg,theora,vorbis]
+		>=media-libs/gst-plugins-good-${PV}:1.0
+		>=media-plugins/gst-plugins-jpeg-${PV}:1.0
+	)"
+BDEPEND="
+	dev-cpp/mm-common
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-libs/libxslt
+		media-gfx/graphviz
+	)"
+# eautoreconf:
+#	dev-cpp/mm-common
+
+# Installs reference docs into /usr/share/doc/gstreamermm-1.0/
+# but that's okay, because the rest of dev-cpp/*mm stuff does the same
+
+PATCHES=(
+	"${FILESDIR}"/${P}-no-volatile.patch
+)
+
+src_prepare() {
+	if ! use examples; then
+		# don't waste time building examples
+		sed -e 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' \
+			-i Makefile.am Makefile.in || die
+	fi
+
+	sed -e 's/ -Werror/ /' -i tests/Makefile.am tests/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable doc documentation) \
+		$(use_enable test unittests)
+}
+
+src_test() {
+	# running tests in parallel fails
+	virtx emake -j1 check
+}
-- 
cgit v1.2.3-65-gdbad