From 1053568a64c82405f01bddf79710f9397105d696 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Wed, 8 May 2024 09:47:17 +0200
Subject: dev-python/sympy: Bump to 1.12.1_rc1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/sympy/Manifest                |   1 +
 dev-python/sympy/sympy-1.12.1_rc1.ebuild | 104 +++++++++++++++++++++++++++++++
 2 files changed, 105 insertions(+)
 create mode 100644 dev-python/sympy/sympy-1.12.1_rc1.ebuild

(limited to 'dev-python/sympy')

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index f19c73e34f72..94b934578aef 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1 +1,2 @@
+DIST sympy-1.12.1rc1.gh.tar.gz 8009898 BLAKE2B 7afbcb0c17249509a1a780bdfbe72eee5aaa4b4548a587968bd2c454cbdbda9e81b47ee31c98a8aa2323d575a9cc8897f9b52aba0eec1ed831e3038b2fc15aff SHA512 575947bc1057d8bfb5e4d6f84243d0206449ef97d861e6029c11f0868c34b8d909159901054469738577edc8f941db14a61936402037a24153c1ca97af4758ad
 DIST sympy-1.12.gh.tar.gz 7212937 BLAKE2B 1d37a019e7a6700e69e16d6ca7fdc563711165fc226ac6ec745d20fa6dc689ee9ea01a92549d851aacff763230872c2d1d0cb5bde581c4f960f5de515ffb5f06 SHA512 96a89b88f6912d70c56f5bd1903dd3c518963118ff25d033cdcb7da2f260b8ee209d3ab4a4394dd2b5dc0b4585b71ccd55d55c8e5c6e28024cccbedf07ee4360
diff --git a/dev-python/sympy/sympy-1.12.1_rc1.ebuild b/dev-python/sympy/sympy-1.12.1_rc1.ebuild
new file mode 100644
index 000000000000..b5b261a645c7
--- /dev/null
+++ b/dev-python/sympy/sympy-1.12.1_rc1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="
+	https://www.sympy.org/
+	https://github.com/sympy/sympy/
+	https://pypi.org/project/sympy/
+"
+# pypi sdist misses some files, notably top-level conftest.py, as of 1.12.1_rc1
+SRC_URI="
+	https://github.com/sympy/sympy/archive/${PV/_/}.tar.gz
+		-> ${P/_/}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="aesara examples imaging ipython latex mathml opengl pdf png pyglet symengine texmacs"
+
+RDEPEND="
+	dev-python/mpmath[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	aesara? (
+		$(python_gen_cond_dep '
+			dev-python/aesara[${PYTHON_USEDEP}]
+		' python3_{10..11})
+	)
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? ( dev-python/ipython[${PYTHON_USEDEP}] )
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-python/lxml[${PYTHON_USEDEP}] )
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require old version of antlr4
+		sympy/parsing/tests/test_autolev.py
+		sympy/parsing/tests/test_latex.py
+		# crash due to assertions in sys-devel/llvm[debug]
+		sympy/parsing/tests/test_c_parser.py
+
+		# TODO: pytest?
+		sympy/solvers/ode/tests/test_systems.py::test_linear_3eq_order1_type4_long_check
+		sympy/solvers/ode/tests/test_systems.py::test_linear_3eq_order1_type4_long_dsolve_dotprodsimp
+
+		# either very slow or hanging
+		sympy/solvers/ode/tests/test_systems.py::test_linear_new_order1_type2_de_lorentz_slow_check
+		sympy/integrals/tests/test_failing_integrals.py::test_issue_15227
+		sympy/matrices/tests/test_matrices.py::test_pinv_rank_deficient_when_diagonalization_fails
+		sympy/solvers/ode/tests/test_systems.py::test_nonlinear_3eq_order1_type1
+		sympy/solvers/ode/tests/test_systems.py::test_nonlinear_3eq_order1_type3
+
+		# known broken
+		# https://github.com/sympy/sympy/issues/26321
+		sympy/solvers/tests/test_simplex.py::test_lp
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest --veryquickcheck ||
+		die -n "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}
-- 
cgit v1.2.3-65-gdbad