From 6693c3cc856e6328d7054c2e8224a4c93bf1315f Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sat, 20 May 2023 05:56:43 +0100
Subject: dev-util/colm: don't inject CFLAGS to main.cc

Causes crashes with some combinations.

Closes: https://bugs.gentoo.org/883993
Bug: https://bugs.gentoo.org/766069
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-util/colm/colm-0.14.7-r3.ebuild | 69 +++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 dev-util/colm/colm-0.14.7-r3.ebuild

(limited to 'dev-util/colm')

diff --git a/dev-util/colm/colm-0.14.7-r3.ebuild b/dev-util/colm/colm-0.14.7-r3.ebuild
new file mode 100644
index 000000000000..19e1284d28ca
--- /dev/null
+++ b/dev-util/colm/colm-0.14.7-r3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="COmputer Language Manipulation"
+HOMEPAGE="https://www.colm.net/open-source/colm/"
+SRC_URI="https://www.colm.net/files/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		|| ( app-text/asciidoc dev-ruby/asciidoctor )
+		dev-python/pygments
+	)
+"
+# libfsm moved from ragel -> colm, bug #766108
+RDEPEND="!<dev-util/ragel-7.0.3"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14.7-drop-julia-check.patch
+	"${FILESDIR}"/${PN}-0.14.7-disable-static-lib.patch
+	"${FILESDIR}"/${PN}-0.14.7-solaris.patch
+)
+
+src_prepare() {
+	default
+
+	# bug #733426
+	sed -i -e 's/(\[ASCIIDOC\], \[asciidoc\], \[asciidoc\]/S([ASCIIDOC], [asciidoc asciidoctor]/' configure.ac || die
+
+	# Respect CC/CXX (bug #766069), we also omit CFLAGS here because
+	# it seems to crash with some combinations and the software is fragile
+	# (bug #883993).
+	sed -i -e "s|gcc|$(tc-getCC)|" src/main.cc || die
+	sed -i -e "s|gcc|$(tc-getCC)|" test/colm.d/gentests.sh || die
+	sed -i -e "s|g++|$(tc-getCXX)|" test/colm.d/gentests.sh || die
+
+	# fix linkage on Darwin from colm itself during build
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		sed -i -e 's/libcolm\.so/libcolm.dylib/' src/main.cc || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable doc manual)
+}
+
+src_test() {
+	# Build tests
+	default
+
+	# Run them
+	cd test || die
+	./runtests || die
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad