From d5e9a7a2be7a349797185aded9d605bd7eff7b1e Mon Sep 17 00:00:00 2001
From: "Matthew S. Turnbull" <sparky@bluefang-logic.com>
Date: Fri, 18 Nov 2022 01:02:24 -0500
Subject: gnome-extra/cinnamon-settings-daemon: add 5.6.0

Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>
---
 gnome-extra/cinnamon-settings-daemon/Manifest      |  1 +
 .../cinnamon-settings-daemon-5.6.0.ebuild          | 91 ++++++++++++++++++++++
 2 files changed, 92 insertions(+)
 create mode 100644 gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.6.0.ebuild

(limited to 'gnome-extra/cinnamon-settings-daemon')

diff --git a/gnome-extra/cinnamon-settings-daemon/Manifest b/gnome-extra/cinnamon-settings-daemon/Manifest
index 55a9ef2f2d77..a14707ff5d51 100644
--- a/gnome-extra/cinnamon-settings-daemon/Manifest
+++ b/gnome-extra/cinnamon-settings-daemon/Manifest
@@ -1,2 +1,3 @@
 DIST cinnamon-settings-daemon-5.2.0.tar.gz 662588 BLAKE2B aca6aac0a7b85fa9fb60f1101e0027d5faf3f6d95f7d306ae0ad9dd2e19bb1b48ab4333bbcdff5405b52c306f67eb34bfce895b37529d3ce015182aac41dcf07 SHA512 ae076956715bc7b47746868df0f1cb4034a8ce26b2d64878c74654f08a4498155063f16bf7972316fa138f72e10a82e8589fdb607f8072bbcd92e106bedbe98e
 DIST cinnamon-settings-daemon-5.4.5.tar.gz 573247 BLAKE2B a2075d74c7e05f9deda385577725d41b6d184a7de7b2c519c7c4167af99bd13d2882402b245ada5ff2e049189cce4a3b0f6e1a2c88ccad8c296fab9da8dd6b66 SHA512 7a3629361fac9d48b3ee64f4595e393b601553d8941762ccdb98bc362edc17ca27e1f8077e7b81b3c262445c4335f7740b8800745146237006547bdcf17a40d1
+DIST cinnamon-settings-daemon-5.6.0.tar.gz 572607 BLAKE2B d8b9a4ff4574251fc142840e81070eebd66ed322b64eadca97efcf2f6bc302bfef18e933d3e7d9bdfe236cc9fb30b24b4b98cbb539ed50c53767d1d2fd7a4a26 SHA512 69aff73deb5ae0278642b8d630b7e460daf4c84f4745f8809c73d2a74effc0642f404589651939fd5132cfe99010259155a9809cb4b074e34d52bb89f1266fd6
diff --git a/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.6.0.ebuild b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.6.0.ebuild
new file mode 100644
index 000000000000..344c6de57399
--- /dev/null
+++ b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-5.6.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit meson gnome2-utils python-any-r1 xdg
+
+DESCRIPTION="Cinnamon's settings daemon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-settings-daemon"
+SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1 LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+colord cups input_devices_wacom smartcard systemd"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[dbus]
+	dev-libs/libgudev:=
+	>=gnome-base/libgnomekbd-3.6
+	>=gnome-extra/cinnamon-desktop-5.6:0=
+	media-libs/fontconfig
+	>=media-libs/lcms-2.2:2
+	media-libs/libcanberra:0=[gtk3,pulseaudio]
+	>=media-sound/pulseaudio-0.9.16[glib]
+	>=sys-auth/polkit-0.97
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.14.0:3
+	>=x11-libs/libnotify-0.7.3:0=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	>=x11-libs/libxklavier-5.0
+	>=x11-libs/pango-1.20.0
+	>=sys-power/upower-0.9.11
+
+	colord? ( >=x11-misc/colord-0.1.27:= )
+	cups? (
+		>=net-print/cups-1.4[dbus]
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7:=
+		>=gnome-base/librsvg-2.36.2 )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	systemd? ( sys-apps/systemd:0= )
+	!systemd? ( sys-auth/elogind:0= )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/libxml2:2
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang install-scripts
+}
+
+src_configure() {
+	# gudev not optional on Linux platforms
+	local emesonargs=(
+		-Duse_gudev=enabled
+		-Duse_polkit=enabled
+		-Duse_logind=enabled
+		$(meson_feature colord use_color)
+		$(meson_feature cups use_cups)
+		$(meson_feature smartcard use_smartcard)
+		$(meson_feature input_devices_wacom use_wacom)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-65-gdbad