From 6e7f3ccdecefaa8716371009e5543e34b2cc8fe4 Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Sun, 12 Apr 2020 09:33:40 -0600
Subject: media-gfx/feh: version bump to 3.4

Signed-off-by: Tim Harder <radhermit@gentoo.org>
---
 media-gfx/feh/Manifest       |  1 +
 media-gfx/feh/feh-3.4.ebuild | 70 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 media-gfx/feh/feh-3.4.ebuild

(limited to 'media-gfx')

diff --git a/media-gfx/feh/Manifest b/media-gfx/feh/Manifest
index 0c77094a8f99..258fcce7edb9 100644
--- a/media-gfx/feh/Manifest
+++ b/media-gfx/feh/Manifest
@@ -1,2 +1,3 @@
 DIST feh-3.2.1.tar.bz2 2112281 BLAKE2B 2918d2714f0557e1b67284709bce22c5e14d8f7f545ca33c16ec7928273edf18c9be48a685c3e9a032170bf2b7e572a4b78664f37b2a16c5ae5829b3cc55ca76 SHA512 11a136990f7d02409501f10553659c64ad5d18d4bfaa4e5cfdeb7a2f53ffdb8bd9b8347796c65e75c49615ac4c12bc81bf3a58325f778cb5e0c1608181d7b53a
 DIST feh-3.3.tar.bz2 2112880 BLAKE2B 56042367c0acce966e115e77f3afa1acd3f942a956bc453de364bcd17d90393ad2868039a5793af64826cd50322e4ef5f9f2b9678f982c7c85b025ed208f8bb8 SHA512 0372115a8f2df77cdfc0fc1b24479e72d9be1f24127c787909ef671075b199b8d5f873200ce202f51705991cf3c5f5cc71ef8f47294fe520e3a9acc5cb7582a9
+DIST feh-3.4.tar.bz2 2114146 BLAKE2B 0bc65db77c67c42b693122b877417c3dc4db7a0551cdf62723b3f7c134e5f2bb73ee6d0aa5a0c81402cf5a5f723ceb29a45fb5e4aef1911dc643aeb82c3ef17d SHA512 50cb7fd33b583ee802cbbba8ed7a74e9eb72a141ffa28ab998a196f9f8d030a8192420fc084136f699cb33b1b8c4d8c2c111fa90695dd82a1366330a428383ce
diff --git a/media-gfx/feh/feh-3.4.ebuild b/media-gfx/feh/feh-3.4.ebuild
new file mode 100644
index 000000000000..cdfb177f990f
--- /dev/null
+++ b/media-gfx/feh/feh-3.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs xdg-utils
+
+DESCRIPTION="A fast, lightweight imageviewer using imlib2"
+HOMEPAGE="https://feh.finalrewind.org/"
+SRC_URI="https://feh.finalrewind.org/${P}.tar.bz2"
+
+LICENSE="feh"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="debug curl exif test xinerama"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="media-libs/imlib2[X]
+	>=media-libs/libpng-1.2:0=
+	x11-libs/libX11
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${COMMON_DEPEND}
+	virtual/jpeg:0"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+	x11-libs/libXt
+	test? (
+		>=dev-lang/perl-5.10
+		dev-perl/Test-Command
+		media-libs/imlib2[gif,jpeg,png]
+	)"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.2-debug-cflags.patch )
+
+pkg_setup() {
+	use_feh() { usex $1 1 0; }
+
+	fehopts=(
+		DESTDIR="${D}"
+		PREFIX="${EPREFIX}"/usr
+		doc_dir='${main_dir}'/share/doc/${PF}
+		example_dir='${main_dir}'/share/doc/${PF}/examples
+		curl=$(use_feh curl)
+		debug=$(use_feh debug)
+		xinerama=$(use_feh xinerama)
+		exif=$(use_feh exif)
+	)
+}
+
+src_compile() {
+	tc-export CC
+	emake "${fehopts[@]}"
+}
+
+src_install() {
+	emake "${fehopts[@]}" install
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad