From d216c3cff2e2d6eea14b9f2f8061946fe575445f Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Sun, 29 Nov 2020 15:24:02 +0100
Subject: sci-visualization/fityk: migrate to lua-single.eclass

Builds and tests fine against all three Lua versions upstream Autoconf
script accepts.

Closes: https://bugs.gentoo.org/752852
Signed-off-by: Marek Szuba <marecki@gentoo.org>
---
 sci-visualization/fityk/fityk-1.3.1-r100.ebuild | 50 +++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 sci-visualization/fityk/fityk-1.3.1-r100.ebuild

(limited to 'sci-visualization')

diff --git a/sci-visualization/fityk/fityk-1.3.1-r100.ebuild b/sci-visualization/fityk/fityk-1.3.1-r100.ebuild
new file mode 100644
index 000000000000..fd3cd4903399
--- /dev/null
+++ b/sci-visualization/fityk/fityk-1.3.1-r100.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} )
+WX_GTK_VER=3.0
+
+inherit lua-single wxwidgets xdg
+
+DESCRIPTION="General-purpose nonlinear curve fitting and data analysis"
+HOMEPAGE="http://fityk.nieto.pl/"
+SRC_URI="https://github.com/wojdyr/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="gnuplot nlopt readline wxwidgets"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+DEPEND="
+	${LUA_DEPS}
+	dev-libs/boost:=
+	>=sci-libs/xylib-1
+	nlopt? ( sci-libs/nlopt )
+	readline? ( sys-libs/readline:0= )
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER} )"
+RDEPEND="${DEPEND}
+	gnuplot? ( sci-visualization/gnuplot )"
+BDEPEND="dev-lang/swig"
+
+src_configure() {
+	use wxwidgets && setup-wxwidgets
+
+	econf \
+		--disable-python \
+		--disable-static \
+		$(use_enable nlopt) \
+		$(use_enable wxwidgets GUI) \
+		$(use_with readline) \
+		--with-wx-config="${WX_CONFIG}"
+}
+
+src_install() {
+	default
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad