From 8fd5476fe392e3d6274a80a723a6065d7145ff68 Mon Sep 17 00:00:00 2001
From: "Matthew S. Turnbull" <sparky@bluefang-logic.com>
Date: Tue, 28 Dec 2021 01:26:16 -0500
Subject: x11-libs/xapp: 2.2.8 version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>
---
 x11-libs/xapp/Manifest          |  1 +
 x11-libs/xapp/xapp-2.2.8.ebuild | 91 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)
 create mode 100644 x11-libs/xapp/xapp-2.2.8.ebuild

(limited to 'x11-libs')

diff --git a/x11-libs/xapp/Manifest b/x11-libs/xapp/Manifest
index 7bdeab61e644..86a384f507fa 100644
--- a/x11-libs/xapp/Manifest
+++ b/x11-libs/xapp/Manifest
@@ -1 +1,2 @@
 DIST xapp-2.2.4.tar.gz 242171 BLAKE2B a2e53123776f3f0739778673d08f165d268f5d632ce57d722ac443a7201c22c14c1c88e08247f6c16dd708a01b2dd566d4bd9d55289d70eb50ba29b8f2a0987d SHA512 428fd4dc1911905d6f940c6e38fc8b572d55bcb2691d45ac807276ef554b781c9f6c57bbd6d0a95bf52ca1703a38d260f36a61b88a94bc2dc0812b575839a983
+DIST xapp-2.2.8.tar.gz 245519 BLAKE2B cea0999a544143b8bfdd77cfb19ac794806cf7f20ce85a16d682227c164633fdcd4aacddf0235ade19732007cccc62e789f420081b0094f890b41e703ec96ff1 SHA512 eb8da7bd0b5bcdef46ebc5caf7f688eaa3e4a11f4e54dd0f37f006c2f52356bd38d361b35ae7d670cb3e34bb6e9fed8b132d998750e9cd64c110d230437d5636
diff --git a/x11-libs/xapp/xapp-2.2.8.ebuild b/x11-libs/xapp/xapp-2.2.8.ebuild
new file mode 100644
index 000000000000..48803592d1e1
--- /dev/null
+++ b/x11-libs/xapp/xapp-2.2.8.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2-utils vala meson python-r1 xdg-utils
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapp/"
+LICENSE="GPL-3"
+
+SRC_URI="https://github.com/linuxmint/xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+SLOT="0"
+IUSE="gtk-doc introspection static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.44.0:2
+	dev-libs/gobject-introspection:0=
+	dev-libs/libdbusmenu[gtk3]
+	gnome-base/libgnomekbd
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.16.0:3[introspection?]
+	x11-libs/libxkbfile
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	sys-devel/gettext
+
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	vala_src_prepare
+	default
+
+	# don't install distro specific tools
+	sed -i "/subdir('scripts')/d" meson.build || die
+
+	# Fix meson helpers
+	python_setup
+	python_fix_shebang meson-scripts
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dpy-overrides-dir="/pygobject"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# copy pygobject files to each active python target
+	# work-around for "py-overrides-dir" only supporting a single target
+	install_pygobject_override() {
+		PYTHON_GI_OVERRIDESDIR=$("${EPYTHON}" -c 'import gi;print(gi._overridesdir)' || die)
+		einfo "gobject overrides directory: ${PYTHON_GI_OVERRIDESDIR}"
+		mkdir -p "${D}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		cp -r "${D}"/pygobject/* "${D}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		python_optimize "${D}/${PYTHON_GI_OVERRIDESDIR}/"
+	}
+	python_foreach_impl install_pygobject_override
+	rm -r "${D}/pygobject" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-65-gdbad