blob: 098fdbbe3336bece3e2d56d5fbd647370358ec71 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools desktop xdg
DESCRIPTION="A heavily multi-threaded pluggable audio player"
HOMEPAGE="http://www.alsaplayer.org/"
SRC_URI="http://www.alsaplayer.org/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~mips ~ppc ~riscv ~sparc x86"
IUSE="+alsa audiofile doc flac gtk id3tag jack mad mikmod nas nls ogg opengl oss vorbis xosd"
RDEPEND="
media-libs/libsndfile:=
sys-libs/zlib:=
alsa? ( media-libs/alsa-lib )
audiofile? ( media-libs/audiofile:= )
flac? ( media-libs/flac )
gtk? ( >=x11-libs/gtk+-2.10:2 )
id3tag? ( media-libs/libid3tag:= )
jack? ( virtual/jack )
mad? ( media-libs/libmad )
mikmod? ( media-libs/libmikmod:0 )
nas? ( media-libs/nas )
ogg? ( media-libs/libogg )
opengl? ( virtual/opengl )
vorbis? ( media-libs/libvorbis )
xosd? ( x11-libs/xosd )"
DEPEND="${RDEPEND}
virtual/pkgconfig
doc? ( app-doc/doxygen )
nls? ( sys-devel/gettext )
oss? ( virtual/os-headers )"
REQUIRED_USE="|| ( alsa jack nas oss )"
src_prepare() {
default
sed -i \
-e 's:AM_CFLAGS = $(AM_CXXFLAGS)::' \
output/jack/Makefile.am || die
sed -i \
-e 's:-O2 -funroll-loops -finline-functions -ffast-math::' \
configure.ac || die
sed -i \
-e "s:/usr/lib:/usr/$(get_libdir):" \
configure.ac config.rpath || die
eautoreconf
}
src_configure() {
export ac_cv_prog_HAVE_DOXYGEN=$(usex doc true false)
export ac_cv_lib_xosd_xosd_create=$(usex xosd)
econf \
--disable-esd \
$(use_enable nls) \
$(use_enable opengl) \
$(use_enable mikmod) \
$(use_enable vorbis oggvorbis) \
$(use_enable audiofile) \
$(use_enable flac) \
$(use_enable mad) \
$(use_enable id3tag) \
$(use_enable gtk systray) \
$(use_enable jack) \
$(use_enable alsa) \
$(use_enable oss) \
$(use_enable gtk gtk2) \
$(use_enable nas)
}
src_install() {
default
dodoc docs/*.txt
newicon interface/gtk2/pixmaps/logo.xpm ${PN}.xpm
find "${D}" -name '*.la' -delete || die
}
|
GitWeb