Prefix related changes to side step some of the things that can't be done on Prefix.

Package-Manager: portage-2.1.9.42/cvs/Linux i686

6 files changed, 1309 insertions, 5 deletions

diff --git a/dev-db/postgresql-server/ChangeLog b/dev-db/postgresql-server/ChangeLog
index d52d37c49f30..d44fc5a09663 100644
--- a/dev-db/postgresql-server/ChangeLog
+++ b/dev-db/postgresql-server/ChangeLog
@@ -1,6 +1,17 @@
 # ChangeLog for dev-db/postgresql-server
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-server/ChangeLog,v 1.118 2011/03/31 03:17:04 titanofold Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-server/ChangeLog,v 1.119 2011/04/12 00:11:12 titanofold Exp $
+
+*postgresql-server-9.0.3-r4 (12 Apr 2011)
+*postgresql-server-8.4.7-r3 (12 Apr 2011)
+*postgresql-server-8.3.14-r3 (12 Apr 2011)
+*postgresql-server-8.2.20-r3 (12 Apr 2011)
+
+  12 Apr 2011; Aaron W. Swenson <titanofold@gentoo.org>
+  +postgresql-server-8.2.20-r3.ebuild, +postgresql-server-8.3.14-r3.ebuild,
+  +postgresql-server-8.4.7-r3.ebuild, +postgresql-server-9.0.3-r4.ebuild:
+  Prefix related changes to side step some of the things that can't be done
+  on Prefix.
 
 *postgresql-server-9.1_alpha5 (31 Mar 2011)
 
diff --git a/dev-db/postgresql-server/Manifest b/dev-db/postgresql-server/Manifest
index 286ff9550fee..8c50ca58a36b 100644
--- a/dev-db/postgresql-server/Manifest
+++ b/dev-db/postgresql-server/Manifest
@@ -58,31 +58,35 @@ EBUILD postgresql-server-8.2.18.ebuild 10146 RMD160 866f7f61fb2980b7a8f19de51857
 EBUILD postgresql-server-8.2.19.ebuild 10156 RMD160 3b6c3ec4ff02999ca6d2e59f4966efe8120e4f3e SHA1 eda937fbafcf0772740e448051478249092635d1 SHA256 6f6032f54bca4dc1dc942ea89d1ff3d0f9f4487b09722fb734b80730a00eae87
 EBUILD postgresql-server-8.2.20-r1.ebuild 10659 RMD160 1781c0a8eadef9aab618530fd43ea563aafdf4f9 SHA1 2a5f0515dfd5d9c6b1e3da048d61535e1c59e934 SHA256 6991151d46f5106385a1eaa8eb4b87d5fd22131ac96832346e065f85e3c670f6
 EBUILD postgresql-server-8.2.20-r2.ebuild 10633 RMD160 d579f1565f407ced64da67428fcb8e8c4c1fae9d SHA1 0dd6950c6fe610acac1000e72219df79ecade062 SHA256 8b2e6a2d4f1265ae545488c335feedba055b40b54464daaff3d6aecf3500690c
+EBUILD postgresql-server-8.2.20-r3.ebuild 11304 RMD160 3db97dc9716d47ff2d35931facd81404c3e0f135 SHA1 3dd7f4817946cab81f10dac9c5e4986156f7aae6 SHA256 7e9ded6f955fc7ed59f02415d1ac64f2ae85291de3847cd84ce932373a190232
 EBUILD postgresql-server-8.2.20.ebuild 10152 RMD160 64af69ec0d89c71008265269638821c3e54e1122 SHA1 cd1caaa0c20baf2e30823af7cd743cb63db87d6b SHA256 2d5c9890103f09175384473dc0eb91703a13e81e90172692402135671b202b02
 EBUILD postgresql-server-8.3.12.ebuild 10277 RMD160 9a64318061f46f7224bd95402ba66aeb287e556b SHA1 317d19a7e1e4f0d1c1e7732baa89a30fd7a18a99 SHA256 8fe151f6c53b3526d213a7faa815076b8abf8520a62dd18ce8215aeeb8e381a7
 EBUILD postgresql-server-8.3.13.ebuild 10285 RMD160 cfc154be1839100fa41a4fdaeb6f56f2d5a23bcd SHA1 da92d99f604308b8328dd586acd9d6063be52f8a SHA256 c7d245e9b15b351413a4befe44f325fd462bcc66383a554910859e7d15a34496
 EBUILD postgresql-server-8.3.14-r1.ebuild 10865 RMD160 8cb38540b144059ccc7bc305f4b79499143ff1f2 SHA1 d917ce5fe0700ec59d7fc874c8d22fd929808558 SHA256 259bfedc620e2583deca05061d2f3dcea69b22017c1a775b977e19f9ded08974
 EBUILD postgresql-server-8.3.14-r2.ebuild 10837 RMD160 5f41c565533f495afa4876b80e40954836effcf8 SHA1 49cc46d0c1f909b82258e38355af176b32dc9a3f SHA256 44d6f39a0083df466dc3bb97600f306de647c034acc3c2ca2d713ac7c1db24dd
+EBUILD postgresql-server-8.3.14-r3.ebuild 11509 RMD160 3373a8c8f6574dbbc8cf493352fae04a20dd1b58 SHA1 3c73769e5260ca4b21c86d39ec0197e703f4622c SHA256 ec8052008ed0466931171a63a7d0130142e59c25e9736e1817b41ee5bbe454f6
 EBUILD postgresql-server-8.3.14.ebuild 10280 RMD160 67b6c48ae80f1ab036c6f8955bf12903ff570dcb SHA1 ff74fb2785f185d647bfb1789324b19aebce5fcf SHA256 43ce1ca39d6dfe4fb2c0b68a5f6cce35fea1875d47f2032b1c9c3d54e9cdaef2
 EBUILD postgresql-server-8.4.5.ebuild 10345 RMD160 e8c6fe25773e62509dd66f5da2f1d42378e875c6 SHA1 681e2c2984fe586a9a6e4cbaac701f8695362e4a SHA256 8500bb5bfd40b931c6f6e25b1a08abf524677702c5fa2e2f9c941edca2beebb2
 EBUILD postgresql-server-8.4.6.ebuild 10353 RMD160 2780cca97d3a96e3b84367e097305a10f99872d6 SHA1 cab66166abc783a2ef97bf37b84b6153a38915b8 SHA256 ccd687b7b100bb03f0ae9f8b2952253b21ffaae4e1cc934cb0707bba6a5df1ff
 EBUILD postgresql-server-8.4.7-r1.ebuild 10936 RMD160 c39c13793b10530531053e53224e9191d12e03ab SHA1 b3550366ff54ca035f4e1218aa8b0304846494e2 SHA256 347e2ae0055324a5325c3c4e1b7640736be86501ce1479c4b124094cfcaa958c
 EBUILD postgresql-server-8.4.7-r2.ebuild 10936 RMD160 97a712801ecbc840c37cf340d8df03e9d198837e SHA1 47dd63e6f7ab30b8e5db5ece287a163b710b9284 SHA256 da8caf93b4ed66109c702b559702ad6e69eac04f9b56793b58b406ad9b32fabd
+EBUILD postgresql-server-8.4.7-r3.ebuild 11603 RMD160 4e38a731c5d289a2ebc7a620c0a4102c05d4aef2 SHA1 b0dd9df922134a8c404fc7196f3e2b78cf1cf114 SHA256 413f91348894e86cb3a12b3eaa9a55ba0b9a7a27876fe40cc5ec5e6c9b68a244
 EBUILD postgresql-server-8.4.7.ebuild 10348 RMD160 178c71ad91031dcb725d811a0b432e4a55402685 SHA1 d1068ee1c19825bcead76d4a20978242f8204c40 SHA256 fc693f1a2bac35baca98285769195e0c07185845e8fac0f9afaad0398c1bd274
 EBUILD postgresql-server-9.0.1.ebuild 10183 RMD160 ea6fd12a8f09c7699aa778d5c98bbcd335c630e1 SHA1 c14311df967c46ffba9b2a255d29e8f301b403b8 SHA256 e84ba8420cbed78b27af8694682cf8ffed521c483e8f99275e22624d4444561f
 EBUILD postgresql-server-9.0.2.ebuild 10183 RMD160 a689f44bb8d4e14a43605b6774775d86b8fcc254 SHA1 2006f9f68db8b39dd7e4969e7a021cc4713eb8dd SHA256 415f2ca5433850e7a8d9e0c35b5f8991ba78981cc7fc6699e4736e1a20681ecc
 EBUILD postgresql-server-9.0.3-r2.ebuild 10530 RMD160 8dc31becc37884734e56eb1e2e77f5b2a2207370 SHA1 1df9adfeb704eb5f55a2015238bdb0795cabb92a SHA256 ead8e90d77b2fe9721582de4f9f769a8d7109e10a7060ab559f8b697e3b08eb4
 EBUILD postgresql-server-9.0.3-r3.ebuild 10502 RMD160 1299bdd675ee30f5b4300fd36b539fa72febf616 SHA1 100f89b581710dc90da64d289799dce622643a82 SHA256 297990616ece1ceeb5a071a4c997fece7ea55ed36580fc4d105837d3e406f66e
+EBUILD postgresql-server-9.0.3-r4.ebuild 11179 RMD160 1e52d10cc6cda7d59fda1e85eadaca26b0762990 SHA1 0c0b56a1f1bdede2e0bba33f6bb2afbcaf753eff SHA256 f87b8d48690a0d3af4418a89b37735c04381abe05d83a9f5ff1a41b92cd8a27a
 EBUILD postgresql-server-9.0.3.ebuild 10178 RMD160 65da0866e062f1254e5e082aa3d6e5460035c972 SHA1 629aba6be85464b7e32548e05accc1cb86eeada9 SHA256 5f931b0c7a5ba5265cc1e3386243e18bba02fa1ff415b79d9f78ecbb5d3734de
 EBUILD postgresql-server-9.1_alpha4-r1.ebuild 10312 RMD160 8bd10acf58d0c370156d630be4d0b0d21fdfdf3e SHA1 798e8cec3f462db93c7427dccb561b31e1f4e298 SHA256 227d1db1609dfdf9ccf75ecd7648b1916bd18ef37fa08843568f3879706650c2
 EBUILD postgresql-server-9.1_alpha4.ebuild 10337 RMD160 bd2fdab0f859120ca077594ebbda4c3c428f9509 SHA1 f18528e8a27f21004f464b0139c05c71d9767cdb SHA256 230a1f29d8965a32e5557ef235ea2fd53c085ef383d935a50195f575f8d08f4a
 EBUILD postgresql-server-9.1_alpha5.ebuild 10852 RMD160 0f8d03a524ea30389137fb1e31436484476e5058 SHA1 9ed72b70b8b26e51767ff3984e483ebd8c190b50 SHA256 06b24f6f64b950ac4811cbc42836ffe84d8ef7488319a76f7a421e4c0684d4cc
-MISC ChangeLog 37865 RMD160 215d1c3230e748dae99c632b089c63a6f6f7f00c SHA1 696139dae062994a0b138a5adbb601ac1696d59d SHA256 a6dcc3f113f6a5013a9db18bebbb0ec6cebebe3b028aca86037307bde5aabf51
+MISC ChangeLog 38332 RMD160 dfa04fbac060c4d048744d7fc873e68ec98bd6b7 SHA1 abf33493c29841e071e67e2203430021152d47cb SHA256 c8cdf3d37e1a20a9be79227ab78aa7e7561db88f85e6bb32ba51e40052c0599d
 MISC metadata.xml 420 RMD160 789f5a0ce45d05125098fd7e74a816cf08f4c39b SHA1 d308d7434a37f12cd320f74ed85e1d3ca7dabc75 SHA256 ac37a5084450a782d02510149d030bd0d4a63164f2ffb7bdda3ddf344606ca62
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iF4EAREIAAYFAk2T8jcACgkQCOhwUhu5AEnaNgD/WwjMf6rm9j+da81Y6Za5szL5
-xHk9fBEqxB9xliXPfUIBAIoKSnbgOAQu3NKieJRQwW/Lskke6Jyy5VY+uV+i/b57
-=YQdl
+iF4EAREIAAYFAk2jmLQACgkQCOhwUhu5AEk0AgD+Pmy7W1PwDlpSWFGYoJGEUnCJ
+HbdgLnCYUFswqDrkhiEA/R8oEYODp2yDY+cuIT13xsczIdec/PpereKACREZiHZq
+=Ym+1
 -----END PGP SIGNATURE-----
diff --git a/dev-db/postgresql-server/postgresql-server-8.2.20-r3.ebuild b/dev-db/postgresql-server/postgresql-server-8.2.20-r3.ebuild
new file mode 100644
index 000000000000..f4e9ce1c0388
--- /dev/null
+++ b/dev-db/postgresql-server/postgresql-server-8.2.20-r3.ebuild
@@ -0,0 +1,319 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-server/postgresql-server-8.2.20-r3.ebuild,v 1.1 2011/04/12 00:11:12 titanofold Exp $
+
+EAPI="3"
+
+WANT_AUTOMAKE="none"
+inherit autotools eutils multilib pam prefix versionator
+
+SLOT="$(get_version_component_range 1-2)"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~s390 ~sh ~sparc ~x86"
+
+DESCRIPTION="PostgreSQL server"
+HOMEPAGE="http://www.postgresql.org/"
+SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
+		 http://dev.gentoo.org/~titanofold/postgresql-patches-${SLOT}.tbz2
+		 http://dev.gentoo.org/~titanofold/postgresql-initscript-1.0.1.tbz2"
+LICENSE="POSTGRESQL"
+
+S=${WORKDIR}/postgresql-${PV}
+
+LINGUAS="af cs de es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
+IUSE="doc kernel_linux nls pam perl python selinux tcl xml"
+
+for lingua in ${LINGUAS} ; do
+	IUSE+=" linguas_${lingua}"
+done
+
+wanted_languages() {
+	local enable_langs
+
+	for lingua in ${LINGUAS} ; do
+		use linguas_${lingua} && enable_langs+="${lingua} "
+	done
+
+	echo -n ${enable_langs}
+}
+
+RDEPEND="~dev-db/postgresql-base-${PV}:${SLOT}[pam?,nls=]
+	perl? ( >=dev-lang/perl-5.8 )
+	python? ( >=dev-lang/python-2.2 dev-python/egenix-mx-base )
+	selinux? ( sec-policy/selinux-postgresql )
+	tcl? ( >=dev-lang/tcl-8 )
+	xml? ( dev-libs/libxml2 dev-libs/libxslt )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	xml? ( dev-util/pkgconfig )"
+PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
+
+pkg_setup() {
+	enewgroup postgres 70
+	enewuser postgres 70 /bin/bash ${EROOT%/}/var/lib/postgresql postgres
+}
+
+src_prepare() {
+	epatch "${WORKDIR}/autoconf.patch" \
+		"${WORKDIR}/server.patch" \
+		"${WORKDIR}/darwin.patch" \
+		"${WORKDIR}/SuperH.patch"
+
+	eprefixify src/include/pg_config_manual.h
+
+	if use test ; then
+		epatch "${WORKDIR}/regress.patch"
+		sed -e "s|@SOCKETDIR@|${T}|g" -i src/test/regress/pg_regress.c
+		sed -e "s|/no/such/location|${S}/src/test/regress/tmp_check/no/such/location|g" -i src/test/regress/{input,output}/tablespace.source
+	else
+		echo "all install:" > "${S}/src/test/regress/GNUmakefile"
+	fi
+
+	eautoconf
+}
+
+src_configure() {
+	# eval is needed to get along with pg_config quotation of space-rich entities.
+	eval econf "$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --configure)" \
+		$(use_with perl) \
+		$(use_with python) \
+		$(use_with tcl) \
+		--with-includes="${EROOT%/}/usr/include/postgresql-${SLOT}/" \
+		"$(has_version ~dev-db/postgresql-base-${PV}[nls] && use_enable nls nls "$(wanted_languages)")" \
+		|| die "configure failed"
+}
+
+src_compile() {
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2); do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake -C $bd -j1 \
+				PGXS=$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --pgxs) \
+				PGXS_IN_SERVER=1 PGXS_WITH_SERVER="${S}/src/backend/postgres" \
+				NO_PGXS=0 USE_PGXS=1 docdir=${EROOT%/}/usr/share/doc/${PF} || die "emake in $bd failed"
+	done
+}
+
+src_install() {
+	if use perl ; then
+		mv -f "${S}/src/pl/plperl/GNUmakefile" "${S}/src/pl/plperl/GNUmakefile_orig"
+		sed -e "s:\$(DESTDIR)\$(plperl_installdir):\$(plperl_installdir):" \
+			"${S}/src/pl/plperl/GNUmakefile_orig" > "${S}/src/pl/plperl/GNUmakefile"
+	fi
+
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2) ; do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake install -C $bd -j1 DESTDIR="${D}" \
+			PGXS_IN_SERVER=1 PGXS_WITH_SERVER="${S}/src/backend/postgres" \
+			PGXS=$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --pgxs) \
+			NO_PGXS=0 USE_PGXS=1 docdir=${EROOT%/}/usr/share/doc/${PF} || die "emake install in $bd failed"
+	done
+
+	rm -r "${ED}/usr/share/postgresql-${SLOT}/man/man7/" "${ED}/usr/share/doc/${PF}/html"
+	rm "${ED}"/usr/share/postgresql-${SLOT}/man/man1/{clusterdb,create{db,lang,user},drop{db,lang,user},ecpg,pg_{config,dump,dumpall,restore},psql,reindexdb,vacuumdb}.1
+
+	dodoc README HISTORY doc/{README.*,TODO,bug.template}
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+	cat >"${ED}/etc/eselect/postgresql/slots/${SLOT}/service" <<-__EOF__
+		postgres_ebuilds="\${postgres_ebuilds} ${PF}"
+		postgres_service="postgresql-${SLOT}"
+	__EOF__
+
+	newconfd "${WORKDIR}/postgresql.confd" postgresql-${SLOT} || die "Inserting conf.d file failed"
+	newinitd "${WORKDIR}/postgresql.init" postgresql-${SLOT} || die "Inserting init.d file failed"
+
+	use pam && pamd_mimic system-auth postgresql auth account session
+
+	keepdir /var/run/postgresql
+	fperms 0770 /var/run/postgresql
+	use prefix || fowners postgres:postgres /var/run/postgresql
+}
+
+pkg_postinst() {
+	eselect postgresql update
+	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
+	[[ "$(eselect postgresql show-service)" = "(none)" ]] && eselect postgresql set-service ${SLOT}
+
+	elog "The Unix-domain socket is located in:"
+	elog "    ${EROOT%/}/var/run/postgresql/"
+	elog
+	elog "If you have users and/or services that you would like to utilize the socket,"
+	elog "you must add them to the 'postgres' system group:"
+	elog "    usermod -a -G postgres <user>"
+	elog
+	elog "Before initializing the database, you may want to edit PG_INITDB_OPTS so that"
+	elog "it contains your preferred locale in:"
+	elog "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	elog
+	elog "Then, execute the following command to setup the initial database"
+	elog "environment:"
+	elog "    emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_postrm() {
+	eselect postgresql update
+}
+
+pkg_config() {
+	[[ -f ${EROOT%/}/etc/conf.d/postgresql-${SLOT} ]] && source ${EROOT%/}/etc/conf.d/postgresql-${SLOT}
+	[[ -z "${PGDATA}" ]] && PGDATA="${EROOT%/}/etc/postgresql-${SLOT}/"
+	[[ -z "${DATA_DIR}" ]] && DATA_DIR="${EROOT%/}/var/lib/postgresql/${SLOT}/data"
+
+	# environment.bz2 may not contain the same locale as the current system
+	# locale. Unset and source from the current system locale.
+	if [ -f ${EROOT%/}/etc/env.d/02locale ]; then
+		unset LANG
+		unset LC_CTYPE
+		unset LC_NUMERIC
+		unset LC_TIME
+		unset LC_COLLATE
+		unset LC_MONETARY
+		unset LC_MESSAGES
+		unset LC_ALL
+		source ${EROOT%/}/etc/env.d/02locale
+		[ -n "${LANG}" ] && export LANG
+		[ -n "${LC_CTYPE}" ] && export LC_CTYPE
+		[ -n "${LC_NUMERIC}" ] && export LC_NUMERIC
+		[ -n "${LC_TIME}" ] && export LC_TIME
+		[ -n "${LC_COLLATE}" ] && export LC_COLLATE
+		[ -n "${LC_MONETARY}" ] && export LC_MONETARY
+		[ -n "${LC_MESSAGES}" ] && export LC_MESSAGES
+		[ -n "${LC_ALL}" ] && export LC_ALL
+	fi
+
+	einfo "You can modify the paths and options passed to initdb by editing:"
+	einfo "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	einfo
+	einfo "Information on options that can be passed to initdb are found at:"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/creating-cluster.html"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/app-initdb.html"
+	einfo
+	einfo "PG_INITDB_OPTS is currently set to:"
+	if [[ -z "${PG_INITDB_OPTS}" ]] ; then
+		einfo "    (none)"
+	else
+		einfo "    ${PG_INITDB_OPTS}"
+	fi
+	einfo
+	einfo "Configuration files will be installed to:"
+	einfo "    ${PGDATA}"
+	einfo
+	einfo "The database cluster will be created in:"
+	einfo "    ${DATA_DIR}"
+	einfo
+	while [ "$correct" != "true" ] ; do
+		einfo "Are you ready to continue? (y/n)"
+		read answer
+		if [[ "$answer" =~ ^[Yy]([Ee][Ss])?$ ]] ; then
+			correct="true"
+		elif [[ "$answer" =~ ^[Nn]([Oo])?$ ]] ; then
+			die "Aborting initialization."
+		else
+			echo "Answer not recognized"
+		fi
+	done
+
+	if [ -n "$(ls -A ${DATA_DIR} 2> /dev/null)" ] ; then
+		eerror "The given directory, '${DATA_DIR}', is not empty."
+		eerror "Modify DATA_DIR to point to an empty directory."
+		die "${DATA_DIR} is not empty."
+	fi
+
+	[ -z "${PG_MAX_CONNECTIONS}" ] && PG_MAX_CONNECTIONS="128"
+	einfo "Checking system parameters..."
+
+	if ! use kernel_linux ; then
+		einfo "Skipped."
+		einfo "Tests not supported on this OS (yet)"
+	else
+		if [ -z ${SKIP_SYSTEM_TESTS} ; then
+			einfo "Checking whether your system supports at least ${PG_MAX_CONNECTIONS} connections..."
+
+			local SEMMSL=$(sysctl -n kernel.sem | cut -f1)
+			local SEMMNS=$(sysctl -n kernel.sem | cut -f2)
+			local SEMMNI=$(sysctl -n kernel.sem | cut -f4)
+			local SHMMAX=$(sysctl -n kernel.shmmax)
+
+			local SEMMSL_MIN=17
+			local SEMMNS_MIN=$(( ( ${PG_MAX_CONNECTIONS}/16 ) * 17 ))
+			local SEMMNI_MIN=$(( ( ${PG_MAX_CONNECTIONS}+15 ) / 16 ))
+			local SHMMAX_MIN=$(( 500000 + ( 30600 * ${PG_MAX_CONNECTIONS} ) ))
+
+			for p in SEMMSL SEMMNS SEMMNI SHMMAX ; do
+				if [ $(eval echo \$$p) -lt $(eval echo \$${p}_MIN) ] ; then
+					eerror "The value for ${p} $(eval echo \$$p) is below the recommended value $(eval echo \$${p}_MIN)"
+					eerror "You have now several options:"
+					eerror "  - Change the mentioned system parameter"
+					eerror "  - Lower the number of max.connections by setting PG_MAX_CONNECTIONS to a"
+					eerror "    value lower than ${PG_MAX_CONNECTIONS}"
+					eerror "  - Set SKIP_SYSTEM_TESTS in case you want to ignore this test completely"
+					eerror "More information can be found here:"
+					eerror "  http://www.postgresql.org/docs/${SLOT}/static/kernel-resources.html"
+					die "System test failed."
+				fi
+			done
+			einfo "Passed."
+		else
+			ewarn "SKIP_SYSTEM_TESTS set, so skipping."
+		fi
+	fi
+
+	if [[ ${EUID} == 0 ]] ; then
+		einfo "Creating the data directory ..."
+		mkdir -p "${DATA_DIR}"
+		chown -Rf postgres:postgres "${DATA_DIR}"
+		chmod 0700 "${DATA_DIR}"
+	fi
+
+	einfo "Initializing the database ..."
+	if [[ ${EUID} == 0 ]] ; then
+		su postgres -c "${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -D \"${DATA_DIR}\" ${PG_INITDB_OPTS}"
+	else
+		"${EROOT%/}"/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -U postgres -D "${DATA_DIR}" ${PG_INITDB_OPTS}
+	fi
+	mv "${DATA_DIR%/}"/*.conf "${PGDATA}"
+
+	einfo "The autovacuum function, which was in contrib, has been moved to the main"
+	einfo "PostgreSQL functions starting with 8.1."
+	einfo "You can enable it in the cluster's:"
+	einfo "    ${PGDATA%/}/postgresql.conf"
+	einfo
+	einfo "The PostgreSQL server, by default, will log events to:"
+	einfo "    ${DATA_DIR%/}/postmaster.log"
+	einfo
+	if use prefix ; then
+		einfo "The location of the configuration files have moved to:"
+		einfo "    ${PGDATA}"
+		einfo
+		einfo "To start the server:"
+		einfo "    pg_ctl start -D ${DATA_DIR} -o '-D ${PGDATA} --data-directory=${DATA_DIR}'"
+		einfo
+		einfo "To stop:"
+		einfo "    pg_ctl stop -D ${DATA_DIR}"
+		einfo
+		einfo "Or move the configuration files back:"
+		einfo "    mv ${PGDATA}*.conf ${DATA_DIR}"
+	else
+		einfo "You should use the '${EROOT%/}/etc/init.d/postgresql-${SLOT}' script to run PostgreSQL"
+		einfo "instead of 'pg_ctl'."
+	fi
+}
+
+src_test() {
+	einfo ">>> Test phase [check]: ${CATEGORY}/${PF}"
+
+	if [ ${UID} -ne 0 ] ; then
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/:${PATH}" \
+			emake -j1 check \
+			PGXS=$("${EROOT%/}"/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --pgxs) \
+			NO_PGXS=0 USE_PGXS=1 SLOT=${SLOT} || die 'Make check failed. See above for details.'
+
+		einfo "If you think other tests besides the regression tests are necessary, please"
+		einfo "submit a bug including a patch for this ebuild to enable them."
+	else
+		ewarn "Tests cannot be run as root. Skipping."
+		ewarn "HINT: FEATURES=\"userpriv\""
+	fi
+}
diff --git a/dev-db/postgresql-server/postgresql-server-8.3.14-r3.ebuild b/dev-db/postgresql-server/postgresql-server-8.3.14-r3.ebuild
new file mode 100644
index 000000000000..f28f0e79c1dc
--- /dev/null
+++ b/dev-db/postgresql-server/postgresql-server-8.3.14-r3.ebuild
@@ -0,0 +1,322 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-server/postgresql-server-8.3.14-r3.ebuild,v 1.1 2011/04/12 00:11:12 titanofold Exp $
+
+EAPI="3"
+
+WANT_AUTOMAKE="none"
+inherit autotools eutils multilib pam prefix versionator
+
+SLOT="$(get_version_component_range 1-2)"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+
+DESCRIPTION="PostgreSQL server"
+HOMEPAGE="http://www.postgresql.org/"
+SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
+		 http://dev.gentoo.org/~titanofold/postgresql-patches-${SLOT}.tbz2
+		 http://dev.gentoo.org/~titanofold/postgresql-initscript-1.2.tbz2"
+LICENSE="POSTGRESQL"
+
+S=${WORKDIR}/postgresql-${PV}
+
+LINGUAS="af cs de es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
+IUSE="doc kernel_linux nls pam perl python selinux tcl uuid xml"
+
+for lingua in ${LINGUAS} ; do
+	IUSE+=" linguas_${lingua}"
+done
+
+wanted_languages() {
+	local enable_langs
+
+	for lingua in ${LINGUAS} ; do
+		use linguas_${lingua} && enable_langs+="${lingua} "
+	done
+
+	echo -n ${enable_langs}
+}
+
+RDEPEND="~dev-db/postgresql-base-${PV}:${SLOT}[pam?,nls=]
+	perl? ( >=dev-lang/perl-5.8 )
+	python? ( >=dev-lang/python-2.2 dev-python/egenix-mx-base )
+	selinux? ( sec-policy/selinux-postgresql )
+	tcl? ( >=dev-lang/tcl-8 )
+	uuid? ( dev-libs/ossp-uuid )
+	xml? ( dev-libs/libxml2 dev-libs/libxslt )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	xml? ( dev-util/pkgconfig )"
+PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
+
+pkg_setup() {
+	enewgroup postgres 70
+	enewuser postgres 70 /bin/bash ${EROOT%/}/var/lib/postgresql postgres
+}
+
+src_prepare() {
+	epatch "${WORKDIR}/autoconf.patch" \
+		"${WORKDIR}/server.patch" \
+		"${WORKDIR}/SuperH.patch" \
+		"${WORKDIR}/darwin.patch"
+
+	eprefixify src/include/pg_config_manual.h
+
+	if use test ; then
+		epatch "${WORKDIR}/regress.patch"
+		sed -e "s|@SOCKETDIR@|${T}|g" -i src/test/regress/pg_regress{,_main}.c
+		sed -e "s|/no/such/location|${S}/src/test/regress/tmp_check/no/such/location|g" -i src/test/regress/{input,output}/tablespace.source
+	else
+		echo "all install:" > "${S}/src/test/regress/GNUmakefile"
+	fi
+
+	eautoconf
+}
+
+src_configure() {
+	# eval is needed to get along with pg_config quotation of space-rich entities.
+	eval econf "$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --configure)" \
+		$(use_with perl) \
+		$(use_with python) \
+		$(use_with tcl) \
+		$(use_with xml libxml) \
+		$(use_with xml libxslt) \
+		$(use_with uuid ossp-uuid) \
+		--with-system-tzdata="${EROOT%/}/usr/share/zoneinfo" \
+		--with-includes="${EROOT%/}/usr/include/postgresql-${SLOT}/" \
+		"$(has_version ~dev-db/postgresql-base-${PV}[nls] && use_enable nls nls "$(wanted_languages)")" \
+		|| die "configure failed"
+}
+
+src_compile() {
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2); do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake -C $bd -j1 \
+				PGXS=$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --pgxs) \
+				PGXS_IN_SERVER=1 PGXS_WITH_SERVER="${S}/src/backend/postgres" \
+				NO_PGXS=0 USE_PGXS=1 docdir=${EROOT%/}/usr/share/doc/${PF} || die "emake in $bd failed"
+	done
+}
+
+src_install() {
+	if use perl ; then
+		mv -f "${S}/src/pl/plperl/GNUmakefile" "${S}/src/pl/plperl/GNUmakefile_orig"
+		sed -e "s:\$(DESTDIR)\$(plperl_installdir):\$(plperl_installdir):" \
+			"${S}/src/pl/plperl/GNUmakefile_orig" > "${S}/src/pl/plperl/GNUmakefile"
+	fi
+
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2) ; do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake install -C $bd -j1 DESTDIR="${D}" \
+				PGXS_IN_SERVER=1 PGXS_WITH_SERVER="${S}/src/backend/postgres" \
+				PGXS=$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --pgxs) \
+				NO_PGXS=0 USE_PGXS=1 docdir=${EROOT%/}/usr/share/doc/${PF} || die "emake install in $bd failed"
+	done
+
+	rm -r "${ED}/usr/share/postgresql-${SLOT}/man/man7/" "${ED}/usr/share/doc/${PF}/html" || die
+	rm "${ED}"/usr/share/postgresql-${SLOT}/man/man1/{clusterdb,create{db,lang,user},drop{db,lang,user},ecpg,pg_{config,dump,dumpall,restore},psql,reindexdb,vacuumdb}.1 || die
+
+	dodoc README HISTORY doc/{README.*,TODO,bug.template}
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+	cat >"${ED}/etc/eselect/postgresql/slots/${SLOT}/service" <<-__EOF__
+		postgres_ebuilds="\${postgres_ebuilds} ${PF}"
+		postgres_service="postgresql-${SLOT}"
+	__EOF__
+
+	sed -e "s/@SLOT@/${SLOT}/g" -i "${WORKDIR}"/postgresql.confd
+	newconfd "${WORKDIR}/postgresql.confd" postgresql-${SLOT} || die "Inserting conf.d file failed"
+	sed -e "s/@SLOT@/${SLOT}/g" -i "${WORKDIR}"/postgresql.init
+	newinitd "${WORKDIR}/postgresql.init" postgresql-${SLOT} || die "Inserting init.d file failed"
+
+	use pam && pamd_mimic system-auth postgresql auth account session
+
+	keepdir /var/run/postgresql
+	fperms 0770 /var/run/postgresql
+	use prefix || fowners postgres:postgres /var/run/postgresql
+}
+
+pkg_postinst() {
+	eselect postgresql update
+	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
+	[[ "$(eselect postgresql show-service)" = "(none)" ]] && eselect postgresql set-service ${SLOT}
+
+	elog "The Unix-domain socket is located in:"
+	elog "    ${EROOT%/}/var/run/postgresql/"
+	elog
+	elog "If you have users and/or services that you would like to utilize the socket,"
+	elog "you must add them to the 'postgres' system group:"
+	elog "    usermod -a -G postgres <user>"
+	elog
+	elog "Before initializing the database, you may want to edit PG_INITDB_OPTS so that"
+	elog "it contains your preferred locale in:"
+	elog "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	elog
+	elog "Execute the following command to setup the initial database"
+	elog "environment:"
+	elog "    emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_postrm() {
+	eselect postgresql update
+}
+
+pkg_config() {
+	[[ -f ${EROOT%/}/etc/conf.d/postgresql-${SLOT} ]] && source ${EROOT%/}/etc/conf.d/postgresql-${SLOT}
+	[[ -z "${PGDATA}" ]] && PGDATA="${EROOT%/}/etc/postgresql-${SLOT}/"
+	[[ -z "${DATA_DIR}" ]] && DATA_DIR="${EROOT%/}/var/lib/postgresql/${SLOT}/data"
+
+	# environment.bz2 may not contain the same locale as the current system
+	# locale. Unset and source from the current system locale.
+	if [ -f ${EROOT%/}/etc/env.d/02locale ]; then
+		unset LANG
+		unset LC_CTYPE
+		unset LC_NUMERIC
+		unset LC_TIME
+		unset LC_COLLATE
+		unset LC_MONETARY
+		unset LC_MESSAGES
+		unset LC_ALL
+		source ${EROOT%/}/etc/env.d/02locale
+		[ -n "${LANG}" ] && export LANG
+		[ -n "${LC_CTYPE}" ] && export LC_CTYPE
+		[ -n "${LC_NUMERIC}" ] && export LC_NUMERIC
+		[ -n "${LC_TIME}" ] && export LC_TIME
+		[ -n "${LC_COLLATE}" ] && export LC_COLLATE
+		[ -n "${LC_MONETARY}" ] && export LC_MONETARY
+		[ -n "${LC_MESSAGES}" ] && export LC_MESSAGES
+		[ -n "${LC_ALL}" ] && export LC_ALL
+	fi
+
+	einfo "You can modify the paths and options passed to initdb by editing:"
+	einfo "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	einfo
+	einfo "Information on options that can be passed to initdb are found at:"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/creating-cluster.html"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/app-initdb.html"
+	einfo
+	einfo "PG_INITDB_OPTS is currently set to:"
+	if [[ -z "${PG_INITDB_OPTS}" ]] ; then
+		einfo "    (none)"
+	else
+		einfo "    ${PG_INITDB_OPTS}"
+	fi
+	einfo
+	einfo "Configuration files will be installed to:"
+	einfo "    ${PGDATA}"
+	einfo
+	einfo "The database cluster will be created in:"
+	einfo "    ${DATA_DIR}"
+	einfo
+	while [ "$correct" != "true" ] ; do
+		einfo "Are you ready to continue? (y/n)"
+		read answer
+		if [[ $answer =~ ^[Yy]([Ee][Ss])?$ ]] ; then
+			correct="true"
+		elif [[ $answer =~ ^[Nn]([Oo])?$ ]] ; then
+			die "Aborting initialization."
+		else
+			echo "Answer not recognized."
+		fi
+	done
+
+	if [ -n "$(ls -A ${DATA_DIR} 2> /dev/null)" ] ; then
+		eerror "The given directory, '${DATA_DIR}', is not empty."
+		eerror "Modify DATA_DIR to point to an empty directory."
+		die "${DATA_DIR} is not empty."
+	fi
+
+	[ -z "${PG_MAX_CONNECTIONS}" ] && PG_MAX_CONNECTIONS="128"
+	einfo "Checking system parameters..."
+
+	if ! use kernel_linux ; then
+		einfo "Skipped."
+		einfo "Tests not supported on this OS (yet)."
+	else
+		if [ -z ${SKIP_SYSTEM_TESTS} ] ; then
+			einfo "Checking whether your system supports at least ${PG_MAX_CONNECTIONS} connections..."
+
+			local SEMMSL=$(sysctl -n kernel.sem | cut -f1)
+			local SEMMNS=$(sysctl -n kernel.sem | cut -f2)
+			local SEMMNI=$(sysctl -n kernel.sem | cut -f4)
+			local SHMMAX=$(sysctl -n kernel.shmmax)
+
+			local SEMMSL_MIN=17
+			local SEMMNS_MIN=$(( ( ${PG_MAX_CONNECTIONS}/16 ) * 17 ))
+			local SEMMNI_MIN=$(( ( ${PG_MAX_CONNECTIONS}+15 ) / 16 ))
+			local SHMMAX_MIN=$(( 500000 + ( 30600 * ${PG_MAX_CONNECTIONS} ) ))
+
+			for p in SEMMSL SEMMNS SEMMNI SHMMAX ; do
+				if [ $(eval echo \$$p) -lt $(eval echo \$${p}_MIN) ] ; then
+					eerror "The value for ${p} $(eval echo \$$p) is below the recommended value $(eval echo \$${p}_MIN)"
+					eerror "You have now several options:"
+					eerror "  - Change the mentioned system parameter"
+					eerror "  - Lower the number of max connections by setting PG_MAX_CONNECTIONS to a"
+					eerror "    value lower than ${PG_MAX_CONNECTIONS}"
+					eerror "  - Set SKIP_SYSTEM_TESTS in case you want to ignore this test completely"
+					eerror "More information can be found here:"
+					eerror "    http://www.postgresql.org/docs/${SLOT}/static/kernel-resources.html"
+					die "System test failed."
+				fi
+			done
+			einfo "Passed."
+		else
+			ewarn "SKIP_SYSTEM_TESTS is set, so skipping."
+		fi
+	fi
+
+	if [[ ${EUID} == 0 ]] ; then
+		einfo "Creating the data directory ..."
+		mkdir -p "${DATA_DIR}"
+		chown -Rf postgres:postgres "${DATA_DIR}"
+		chmod 0700 "${DATA_DIR}"
+	fi
+
+	einfo "Initializing the database ..."
+	if [[ ${EUID} == 0 ]] ; then
+		su postgres -c "${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -D \"${DATA_DIR}\" ${PG_INITDB_OPTS}"
+	else
+		"${EROOT%/}"/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -U postgres -D "${DATA_DIR}" ${PG_INITDB_OPTS}
+	fi
+	mv "${DATA_DIR%/}"/*.conf "${PGDATA}"
+
+	einfo "The autovacuum function, which was in contrib, has been moved to the main"
+	einfo "PostgreSQL functions starting with 8.1. You can enable it in the clusters"
+	einfo "postgresql.conf."
+	einfo
+	if use prefix ; then
+		einfo "The location of the configuration files have moved to:"
+		einfo "    ${PGDATA}"
+		einfo
+		einfo "To start the server:"
+		einfo "    pg_ctl start -D ${DATA_DIR} -o '-D ${PGDATA} --data-directory=${DATA_DIR}'"
+		einfo
+		einfo "To stop:"
+		einfo "    pg_ctl stop -D ${DATA_DIR}"
+		einfo
+		einfo "Or move the configuration files back:"
+		einfo "    mv ${PGDATA}*.conf ${DATA_DIR}"
+	else
+		einfo "You should use the '${EROOT%/}/etc/init.d/postgresql-${SLOT}' script to run PostgreSQL"
+		einfo "instead of 'pg_ctl'."
+	fi
+}
+
+src_test() {
+	einfo ">>> Test phase [check]: ${CATEGORY}/${PF}"
+
+	if [ ${UID} -ne 0 ] ; then
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/:${PATH}" \
+			emake -j1 check \
+			PGXS=$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --pgxs) \
+			NO_PGXS=0 USE_PGXS=1 SLOT=${SLOT} || die "Make check failed. See above for details."
+
+		einfo "If you think other tests besides the regression tests are necessary, please"
+		einfo "submit a bug including a patch for this ebuild to enable them."
+	else
+		ewarn "Tests cannot be run as root. Skipping."
+		ewarn "HINT: FEATURES=\"userpriv\""
+	fi
+}
diff --git a/dev-db/postgresql-server/postgresql-server-8.4.7-r3.ebuild b/dev-db/postgresql-server/postgresql-server-8.4.7-r3.ebuild
new file mode 100644
index 000000000000..0bbeffd6be6e
--- /dev/null
+++ b/dev-db/postgresql-server/postgresql-server-8.4.7-r3.ebuild
@@ -0,0 +1,326 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-server/postgresql-server-8.4.7-r3.ebuild,v 1.1 2011/04/12 00:11:12 titanofold Exp $
+
+EAPI="3"
+PYTHON_DEPEND="python? 2"
+
+WANT_AUTOMAKE="none"
+inherit autotools eutils multilib pam prefix python versionator
+
+SLOT="$(get_version_component_range 1-2)"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+
+DESCRIPTION="PostgreSQL server"
+HOMEPAGE="http://www.postgresql.org/"
+SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
+		 http://dev.gentoo.org/~titanofold/postgresql-patches-${SLOT}.tbz2
+		 http://dev.gentoo.org/~titanofold/postgresql-initscript-1.2.tbz2"
+LICENSE="POSTGRESQL"
+
+S=${WORKDIR}/postgresql-${PV}
+
+LINGUAS="af cs de es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
+IUSE="doc kernel_linux nls pam perl -pg_legacytimestamp python selinux tcl uuid xml"
+
+for lingua in ${LINGUAS} ; do
+	IUSE+=" linguas_${lingua}"
+done
+
+wanted_languages() {
+	local enable_langs
+
+	for lingua in ${LINGUAS} ; do
+		use linguas_${lingua} && enable_langs+="${lingua} "
+	done
+
+	echo -n ${enable_langs}
+}
+
+RDEPEND="~dev-db/postgresql-base-${PV}:${SLOT}[pam?,pg_legacytimestamp=,nls=]
+	perl? ( >=dev-lang/perl-5.8 )
+	python? ( dev-python/egenix-mx-base )
+	selinux? ( sec-policy/selinux-postgresql )
+	tcl? ( >=dev-lang/tcl-8 )
+	uuid? ( dev-libs/ossp-uuid )
+	xml? ( dev-libs/libxml2 dev-libs/libxslt )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	xml? ( dev-util/pkgconfig )"
+PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
+
+pkg_setup() {
+	enewgroup postgres 70
+	enewuser postgres 70 /bin/bash ${EROOT%/}/var/lib/postgresql postgres
+
+	use python && python_set_active_version 2
+}
+
+src_prepare() {
+	epatch "${WORKDIR}/autoconf.patch" \
+		"${WORKDIR}/server.patch" \
+		"${WORKDIR}/ldflags.patch" \
+		"${WORKDIR}/SuperH.patch" \
+		"${WORKDIR}/darwin.patch"
+
+	eprefixify src/include/pg_config_manual.h
+
+	if use test ; then
+		epatch "${WORKDIR}/regress.patch"
+		sed -e "s|@SOCKETDIR@|${T}|g" -i src/test/regress/pg_regress{,_main}.c
+		sed -e "s|/no/such/location|${S}/src/test/regress/tmp_check/no/such/location|g" -i src/test/regress/{input,output}/tablespace.source
+	else
+		echo "all install:" > "${S}/src/test/regress/GNUmakefile"
+	fi
+
+	eautoconf
+}
+
+src_configure() {
+	# eval is needed to get along with pg_config quotation of space-rich entities.
+	eval econf "$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --configure)" \
+		$(use_with perl) \
+		$(use_with python) \
+		$(use_with tcl) \
+		$(use_with xml libxml) \
+		$(use_with xml libxslt) \
+		$(use_with uuid ossp-uuid) \
+		--with-system-tzdata="${EROOT%/}/usr/share/zoneinfo" \
+		--with-includes="${EROOT%/}/usr/include/postgresql-${SLOT}/" \
+		--with-libraries="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/$(get_libdir)" \
+		"$(has_version ~dev-db/postgresql-base-${PV}[nls] && use_enable nls nls "$(wanted_languages)")"
+}
+
+src_compile() {
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2) ; do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake -C $bd -j1 || die "emake in $bd failed"
+	done
+}
+
+src_install() {
+	if use perl ; then
+		mv -f "${S}/src/pl/plperl/GNUmakefile" "${S}/src/pl/plperl/GNUmakefile_orig"
+		sed -e "s:\$(DESTDIR)\$(plperl_installdir):\$(plperl_installdir):" \
+			"${S}/src/pl/plperl/GNUmakefile_orig" > "${S}/src/pl/plperl/GNUmakefile"
+	fi
+
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2) ; do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake install -C $bd -j1 DESTDIR="${D}" || die "emake install in $bd failed"
+	done
+
+	rm -r "${ED}/usr/share/postgresql-${SLOT}/man/man7/" "${ED}/usr/share/doc/postgresql-${SLOT}/html" || die
+	rm "${ED}"/usr/share/postgresql-${SLOT}/man/man1/{clusterdb,create{db,lang,user},drop{db,lang,user},ecpg,pg_{config,dump,dumpall,restore},psql,reindexdb,vacuumdb}.1 || die
+
+	dodoc README HISTORY doc/{README.*,TODO,bug.template}
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+	cat >"${ED}/etc/eselect/postgresql/slots/${SLOT}/service" <<-__EOF__
+		postgres_ebuilds="\${postgres_ebuilds} ${PF}"
+		postgres_service="postgresql-${SLOT}"
+	__EOF__
+
+	sed -e "s/@SLOT@/${SLOT}/g" -i "${WORKDIR}"/postgresql.confd
+	newconfd "${WORKDIR}"/postgresql.confd postgresql-${SLOT} || die "Inserting conf.d file failed"
+	sed -e "s/@SLOT@/${SLOT}/g" -i "${WORKDIR}"/postgresql.init
+	newinitd "${WORKDIR}"/postgresql.init postgresql-${SLOT} || die "Inserting init.d file failed"
+
+	use pam && pamd_mimic system-auth postgresql auth account session
+
+	keepdir /var/run/postgresql
+	fperms 0770 /var/run/postgresql
+	use prefix || fowners postgres:postgres /var/run/postgresql
+}
+
+pkg_postinst() {
+	eselect postgresql update
+	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
+	[[ "$(eselect postgresql show-service)" = "(none)" ]] && eselect postgresql set-service ${SLOT}
+
+	elog "The time stamp format is 64 bit integers now. If you upgrade from older"
+	elog "databases, this may force you to either do a dump and reload of enable"
+	elog "pg_legacytimestamp until you find time to do so. If the database can't start"
+	elog "please try enabling pg_legacytimestamp and rebuild."
+	elog
+	elog "The Unix-domain socket is located in:"
+	elog "    ${EROOT%/}/var/run/postgresql/"
+	elog
+	elog "If you have users and/or services that you would like to utilize the socket,"
+	elog "you must add them to the 'postgres' system group:"
+	elog "    usermod -a -G postgres <user>"
+	elog
+	elog "Before initializing the database, you may want to edit PG_INITDB_OPTS so that"
+	elog "it contains your preferred locale and character encoding in:"
+	elog "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	elog
+	elog "Then, execute the following command to setup the initial database"
+	elog "environment:"
+	elog "    emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_postrm() {
+	eselect postgresql update
+}
+
+pkg_config() {
+	[[ -f ${EROOT%/}/etc/conf.d/postgresql-${SLOT} ]] && source ${EROOT%/}/etc/conf.d/postgresql-${SLOT}
+	[[ -z "${PGDATA}" ]] && PGDATA="${EROOT%/}/etc/postgresql-${SLOT}/"
+	[[ -z "${DATA_DIR}" ]] && DATA_DIR="${EROOT%/}/var/lib/postgresql/${SLOT}/data"
+
+	# environment.bz2 may not contain the same locale as the current system
+	# locale. Unset and source from the current system locale.
+	if [ -f ${EROOT%/}/etc/env.d/02locale ]; then
+		unset LANG
+		unset LC_CTYPE
+		unset LC_NUMERIC
+		unset LC_TIME
+		unset LC_COLLATE
+		unset LC_MONETARY
+		unset LC_MESSAGES
+		unset LC_ALL
+		source ${EROOT%/}/etc/env.d/02locale
+		[ -n "${LANG}" ] && export LANG
+		[ -n "${LC_CTYPE}" ] && export LC_CTYPE
+		[ -n "${LC_NUMERIC}" ] && export LC_NUMERIC
+		[ -n "${LC_TIME}" ] && export LC_TIME
+		[ -n "${LC_COLLATE}" ] && export LC_COLLATE
+		[ -n "${LC_MONETARY}" ] && export LC_MONETARY
+		[ -n "${LC_MESSAGES}" ] && export LC_MESSAGES
+		[ -n "${LC_ALL}" ] && export LC_ALL
+	fi
+
+	einfo "You can modify the paths and options passed to initdb by editing:"
+	einfo "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	einfo
+	einfo "Information on options that can be passed to initdb are found at:"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/creating-cluster.html"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/app-initdb.html"
+	einfo
+	einfo "PG_INITDB_OPTS is currently set to:"
+	if [[ -z "${PG_INITDB_OPTS}" ]] ; then
+		einfo "    (none)"
+	else
+		einfo "    ${PG_INITDB_OPTS}"
+	fi
+	einfo
+	einfo "Configuration files will be installed to:"
+	einfo "    ${PGDATA}"
+	einfo
+	einfo "The database cluster will be created in:"
+	einfo "    ${DATA_DIR}"
+	einfo
+	while [ "$correct" != "true" ] ; do
+		einfo "Are you ready to continue? (y/n)"
+		read answer
+		if [[ $answer =~ ^[Yy]([Ee][Ss])?$ ]] ; then
+			correct="true"
+		elif [[ $answer =~ ^[Nn]([Oo])?$ ]] ; then
+			die "Aborting initialization."
+		else
+			echo "Answer not recognized"
+		fi
+	done
+
+	if [ -n "$(ls -A ${DATA_DIR} 2> /dev/null)" ] ; then
+		eerror "The given directory, '${DATA_DIR}', is not empty."
+		eerror "Modify DATA_DIR to point to an empty directory."
+		die "${DATA_DIR} is not empty."
+	fi
+
+	[ -z "${PG_MAX_CONNECTIONS}" ] && PG_MAX_CONNECTIONS="128"
+	einfo "Checking system parameters..."
+
+	if ! use kernel_linux ; then
+		einfo "Skipped."
+		einfo "  Tests not supported on this OS (yet)"
+	else
+		if [ -z ${SKIP_SYSTEM_TESTS} ] ; then
+			einfo "Checking whether your system supports at least ${PG_MAX_CONNECTIONS} connections..."
+
+			local SEMMSL=$(sysctl -n kernel.sem | cut -f1)
+			local SEMMNS=$(sysctl -n kernel.sem | cut -f2)
+			local SEMMNI=$(sysctl -n kernel.sem | cut -f4)
+			local SHMMAX=$(sysctl -n kernel.shmmax)
+
+			local SEMMSL_MIN=17
+			local SEMMNS_MIN=$(( ( ${PG_MAX_CONNECTIONS}/16 ) * 17 ))
+			local SEMMNI_MIN=$(( ( ${PG_MAX_CONNECTIONS}+15 ) / 16 ))
+			local SHMMAX_MIN=$(( 500000 + ( 30600 * ${PG_MAX_CONNECTIONS} ) ))
+
+			for p in SEMMSL SEMMNS SEMMNI SHMMAX ; do
+				if [ $(eval echo \$$p) -lt $(eval echo \$${p}_MIN) ] ; then
+					eerror "The value for ${p} $(eval echo \$$p) is below the recommended value $(eval echo \$${p}_MIN)"
+					eerror "You have now several options:"
+					eerror "  - Change the mentioned system parameter"
+					eerror "  - Lower the number of max.connections by setting PG_MAX_CONNECTIONS to a"
+					eerror "    value lower than ${PG_MAX_CONNECTIONS}"
+					eerror "  - Set SKIP_SYSTEM_TESTS in case you want to ignore this test completely"
+					eerror "More information can be found here:"
+					eerror "    http://www.postgresql.org/docs/${SLOT}/static/kernel-resources.html"
+					die "System test failed."
+				fi
+			done
+			einfo "Passed."
+		else
+			ewarn "SKIP_SYSTEM_TESTS set, so skipping."
+		fi
+	fi
+
+	if [[ ${EUID} == 0 ]] ; then
+		einfo "Creating the data directory ..."
+		mkdir -p "${DATA_DIR}"
+		chown -Rf postgres:postgres "${DATA_DIR}"
+		chmod 0700 "${DATA_DIR}"
+	fi
+
+	einfo "Initializing the database ..."
+	if [[ ${EUID} == 0 ]] ; then
+		su postgres -c "${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -D \"${DATA_DIR}\" ${PG_INITDB_OPTS}"
+	else
+		"${EROOT%/}"/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -U postgres -D "${DATA_DIR}" ${PG_INITDB_OPTS}
+	fi
+	mv "${DATA_DIR%/}"/*.conf "${PGDATA}"
+
+	einfo "The autovacuum function, which was in contrib, has been moved to the main"
+	einfo "PostgreSQL functions starting with 8.1, and starting with 8.4 is now enabled by"
+	einfo "default. You can disable it in the cluster's:"
+	einfo "    ${PGDATA%/}/postgresql.conf"
+	einfo
+	einfo "The PostgreSQL server, by default, will log events to:"
+	einfo "    ${DATA_DIR%/}/postmaster.log"
+	einfo
+	if use prefix ; then
+		einfo "The location of the configuration files have moved to:"
+		einfo "    ${PGDATA}"
+		einfo
+		einfo "To start the server:"
+		einfo "    pg_ctl start -D ${DATA_DIR} -o '-D ${PGDATA} --data-directory=${DATA_DIR}'"
+		einfo
+		einfo "To stop:"
+		einfo "    pg_ctl stop -D ${DATA_DIR}"
+		einfo
+		einfo "Or move the configuration files back:"
+		einfo "    mv ${PGDATA}*.conf ${DATA_DIR}"
+	else
+		einfo "You should use the '${EROOT%/}/etc/init.d/postgresql-${SLOT}' script to run PostgreSQL"
+		einfo "instead of 'pg_ctl'."
+	fi
+}
+
+src_test() {
+	einfo ">>> Test phase [check]: ${CATEGORY}/${PF}"
+
+	if [ ${UID} -ne 0 ] ; then
+		emake -j1 check  || die "Make check failed. See above for details."
+
+		einfo "If you think other tests besides the regression tests are necessary, please"
+		einfo "submit a bug including a patch for this ebuild to enable them."
+	else
+		ewarn "Tests cannot be run as root. Skipping."
+		ewarn "HINT: FEATURES=\"userpriv\""
+	fi
+}
diff --git a/dev-db/postgresql-server/postgresql-server-9.0.3-r4.ebuild b/dev-db/postgresql-server/postgresql-server-9.0.3-r4.ebuild
new file mode 100644
index 000000000000..e69eff347742
--- /dev/null
+++ b/dev-db/postgresql-server/postgresql-server-9.0.3-r4.ebuild
@@ -0,0 +1,322 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-server/postgresql-server-9.0.3-r4.ebuild,v 1.1 2011/04/12 00:11:12 titanofold Exp $
+
+EAPI="3"
+PYTHON_DEPEND="python? 2"
+
+WANT_AUTOMAKE="none"
+inherit autotools eutils multilib pam prefix python versionator
+
+SLOT="$(get_version_component_range 1-2)"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+
+DESCRIPTION="PostgreSQL server"
+HOMEPAGE="http://www.postgresql.org/"
+SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
+		 http://dev.gentoo.org/~titanofold/postgresql-patches-${SLOT}-r1.tbz2
+		 http://dev.gentoo.org/~titanofold/postgresql-initscript-1.2.tbz2"
+LICENSE="POSTGRESQL"
+
+S=${WORKDIR}/postgresql-${PV}
+
+LINGUAS="af cs de es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
+IUSE="doc kernel_linux nls pam perl -pg_legacytimestamp python selinux tcl uuid xml"
+
+for lingua in ${LINGUAS}; do
+	IUSE+=" linguas_${lingua}"
+done
+
+wanted_languages() {
+	local enable_langs
+
+	for lingua in ${LINGUAS} ; do
+		use linguas_${lingua} && enable_langs+="${lingua} "
+	done
+
+	echo -n ${enable_langs}
+}
+
+RDEPEND="~dev-db/postgresql-base-${PV}:${SLOT}[pam?,pg_legacytimestamp=,nls=]
+	perl? ( >=dev-lang/perl-5.8 )
+	python? ( dev-python/egenix-mx-base )
+	selinux? ( sec-policy/selinux-postgresql )
+	tcl? ( >=dev-lang/tcl-8 )
+	uuid? ( dev-libs/ossp-uuid )
+	xml? ( dev-libs/libxml2 dev-libs/libxslt )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	xml? ( dev-util/pkgconfig )"
+PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
+
+pkg_setup() {
+	enewgroup postgres 70
+	enewuser postgres 70 /bin/bash ${EROOT%/}/var/lib/postgresql postgres
+
+	use python && python_set_active_version 2
+}
+
+src_prepare() {
+	epatch "${WORKDIR}/autoconf.patch" \
+		"${WORKDIR}/server.patch"
+
+	eprefixify src/include/pg_config_manual.h
+
+	if use test ; then
+		epatch "${WORKDIR}/regress.patch"
+		sed -e "s|@SOCKETDIR@|${T}|g" -i src/test/regress/pg_regress{,_main}.c
+		sed -e "s|/no/such/location|${S}/src/test/regress/tmp_check/no/such/location|g" -i src/test/regress/{input,output}/tablespace.source
+	else
+		echo "all install:" > "${S}/src/test/regress/GNUmakefile"
+	fi
+
+	eautoconf
+}
+
+src_configure() {
+	# eval is needed to get along with pg_config quotation of space-rich entities.
+	eval econf "$(${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/pg_config --configure)" \
+		$(use_with perl) \
+		$(use_with python) \
+		$(use_with tcl) \
+		$(use_with xml libxml) \
+		$(use_with xml libxslt) \
+		$(use_with uuid ossp-uuid) \
+		--with-system-tzdata="${EROOT%/}/usr/share/zoneinfo" \
+		--with-includes="${EROOT%/}/usr/include/postgresql-${SLOT}/" \
+		--with-libraries="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/$(get_libdir)" \
+		"$(use_enable nls nls "$(wanted_languages)")"
+}
+
+src_compile() {
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2); do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake -C $bd -j1 || die "emake in $bd failed"
+	done
+}
+
+src_install() {
+	if use perl ; then
+		mv -f "${S}/src/pl/plperl/GNUmakefile" "${S}/src/pl/plperl/GNUmakefile_orig"
+		sed -e "s:\$(DESTDIR)\$(plperl_installdir):\$(plperl_installdir):" \
+			"${S}/src/pl/plperl/GNUmakefile_orig" > "${S}/src/pl/plperl/GNUmakefile"
+	fi
+
+	local bd
+	for bd in . contrib $(use xml && echo contrib/xml2) ; do
+		PATH="${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin:${PATH}" \
+			emake install -C $bd -j1 DESTDIR="${D}" || die "emake install in $bd failed"
+	done
+
+	dodoc README HISTORY doc/{README.*,TODO,bug.template}
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+	cat > "${ED}/etc/eselect/postgresql/slots/${SLOT}/service" <<-__EOF__
+		postgres_ebuilds="\${postgres_ebuilds} ${PF}"
+		postgres_service="postgresql-${SLOT}"
+	__EOF__
+
+	sed -e "s/@SLOT@/${SLOT}/g" -i "${WORKDIR}/postgresql.confd"
+	newconfd "${WORKDIR}/postgresql.confd" postgresql-${SLOT} || die "Inserting conf.d file failed"
+	sed -e "s/@SLOT@/${SLOT}/g" -i "${WORKDIR}/postgresql.init"
+	newinitd "${WORKDIR}/postgresql.init" postgresql-${SLOT} || die "Inserting init.d file failed"
+
+	use pam && pamd_mimic system-auth postgresql auth account session
+
+	keepdir /var/run/postgresql
+	fperms 0770 /var/run/postgresql
+	use prefix || fowners postgres:postgres /var/run/postgresql
+}
+
+pkg_postinst() {
+	eselect postgresql update
+	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
+	[[ "$(eselect postgresql show-service)" = "(none)" ]] && eselect postgresql set-service ${SLOT}
+
+	elog "The time stamp format is 64 bit integers now. If you upgrade from older"
+	elog "databases, this may force you to either do a dump and reload or enable"
+	elog "pg_legacytimestamp until you find time to do so. If the database cannot start"
+	elog "please try enabling pg_legacytimestamp and rebuild."
+	elog
+	elog "The Unix-domain socket is located in:"
+	elog "    ${EROOT%/}/var/run/postgresql/"
+	elog
+	elog "If you have users and/or services that you would like to utilize the socket,"
+	elog "you must add them to the 'postgres' system group:"
+	elog "    usermod -a -G postgres <user>"
+	elog
+	elog "Before initializing the database, you may want to edit PG_INITDB_OPTS so that"
+	elog "it contains your preferred locale in:"
+	elog "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	elog
+	elog "Then, execute the following command to setup the initial database"
+	elog "environment:"
+	elog "    emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_postrm() {
+	eselect postgresql update
+}
+
+pkg_config() {
+	[[ -f "${EROOT%/}/etc/conf.d/postgresql-${SLOT}" ]] && source "${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	[[ -z "${PGDATA}" ]] && PGDATA="${EROOT%/}/etc/postgresql-${SLOT}/"
+	[[ -z "${DATA_DIR}" ]] && DATA_DIR="${EROOT%/}/var/lib/postgresql/${SLOT}/data"
+
+	# environment.bz2 may not contain the same locale as the current system
+	# locale. Unset and source from the current system locale.
+	if [ -f "${EROOT%/}/etc/env.d/02locale" ]; then
+		unset LANG
+		unset LC_CTYPE
+		unset LC_NUMERIC
+		unset LC_TIME
+		unset LC_COLLATE
+		unset LC_MONETARY
+		unset LC_MESSAGES
+		unset LC_ALL
+		source "${EROOT%/}/etc/env.d/02locale"
+		[ -n "${LANG}" ] && export LANG
+		[ -n "${LC_CTYPE}" ] && export LC_CTYPE
+		[ -n "${LC_NUMERIC}" ] && export LC_NUMERIC
+		[ -n "${LC_TIME}" ] && export LC_TIME
+		[ -n "${LC_COLLATE}" ] && export LC_COLLATE
+		[ -n "${LC_MONETARY}" ] && export LC_MONETARY
+		[ -n "${LC_MESSAGES}" ] && export LC_MESSAGES
+		[ -n "${LC_ALL}" ] && export LC_ALL
+	fi
+
+	einfo "You can modify the paths and options passed to initdb by editing:"
+	einfo "    ${EROOT%/}/etc/conf.d/postgresql-${SLOT}"
+	einfo
+	einfo "Information on options that can be passed to initdb are found at:"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/creating-cluster.html"
+	einfo "    http://www.postgresql.org/docs/${SLOT}/static/app-initdb.html"
+	einfo
+	einfo "PG_INITDB_OPTS is currently set to:"
+	if [[ -z "${PG_INITDB_OPTS}" ]] ; then
+		einfo "    (none)"
+	else
+		einfo "    ${PG_INITDB_OPTS}"
+	fi
+	einfo
+	einfo "Configuration files will be installed to:"
+	einfo "    ${PGDATA}"
+	einfo
+	einfo "The database cluster will be created in:"
+	einfo "    ${DATA_DIR}"
+	einfo
+	while [ "$correct" != "true" ] ; do
+		einfo "Are you ready to continue? (Y/n)"
+		read answer
+		if [[ $answer =~ ^[Yy]([Ee][Ss])?$ ]] ; then
+			correct="true"
+		elif [[ $answer =~ ^[Nn]([Oo])?$ ]] ; then
+			die "Aborting initialization."
+		else
+			echo "Answer not recognized"
+		fi
+	done
+
+	if [ -n "$(ls -A ${DATA_DIR} 2> /dev/null)" ] ; then
+		eerror "The given directory, '${DATA_DIR}', is not empty."
+		eerror "Modify DATA_DIR to point to an empty directory."
+		die "${DATA_DIR} is not empty."
+	fi
+
+	[ -z "${PG_MAX_CONNECTIONS}" ] && PG_MAX_CONNECTIONS="128"
+	einfo "Checking system parameters..."
+
+	if ! use kernel_linux ; then
+		einfo "Skipped."
+		einfo "  Tests not supported on this OS (yet)"
+	else
+		if [ -z ${SKIP_SYSTEM_TESTS} ] ; then
+			einfo "Checking whether your system supports at least ${PG_MAX_CONNECTIONS} connections..."
+
+			local SEMMSL=$(sysctl -n kernel.sem | cut -f1)
+			local SEMMNS=$(sysctl -n kernel.sem | cut -f2)
+			local SEMMNI=$(sysctl -n kernel.sem | cut -f4)
+			local SHMMAX=$(sysctl -n kernel.shmmax)
+
+			local SEMMSL_MIN=17
+			local SEMMNS_MIN=$(( ( ${PG_MAX_CONNECTIONS}/16 ) * 17 ))
+			local SEMMNI_MIN=$(( ( ${PG_MAX_CONNECTIONS}+15 ) / 16 ))
+			local SHMMAX_MIN=$(( 500000 + ( 30600 * ${PG_MAX_CONNECTIONS} ) ))
+
+			for p in SEMMSL SEMMNS SEMMNI SHMMAX ; do
+				if [ $(eval echo \$$p) -lt $(eval echo \$${p}_MIN) ] ; then
+					eerror "The value for ${p} $(eval echo \$$p) is below the recommended value $(eval echo \$${p}_MIN)"
+					eerror "You have now several options:"
+					eerror "    - Change the mentioned system parameter"
+					eerror "    - Lower the number of max connections by setting PG_MAX_CONNECTIONS to a"
+					eerror "      value lower than ${PG_MAX_CONNECTIONS}"
+					eerror "    - Set SKIP_SYSTEM_TESTS in case you want to ignore this test completely"
+					eerror "More information can be found here:"
+					eerror "    http://www.postgresql.org/docs/${SLOT}/static/kernel-resources.html"
+					die "System test failed."
+				fi
+			done
+			einfo "Passed."
+		else
+			ewarn "SKIP_SYSTEM_TESTS set, so skipping."
+		fi
+	fi
+
+	if [[ ${EUID} == 0 ]] ; then
+		einfo "Creating the data directory ..."
+		mkdir -p "${DATA_DIR}"
+		chown -Rf postgres:postgres "${DATA_DIR}"
+		chmod 0700 "${DATA_DIR}"
+	fi
+
+	einfo "Initializing the database ..."
+
+	if [[ ${EUID} == 0 ]] ; then
+		su postgres -c "${EROOT%/}/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -D \"${DATA_DIR}\" ${PG_INITDB_OPTS}"
+	else
+		"${EROOT%/}"/usr/$(get_libdir)/postgresql-${SLOT}/bin/initdb -U postgres -D "${DATA_DIR}" ${PG_INITDB_OPTS}
+	fi
+
+	mv "${DATA_DIR%/}"/*.conf "${PGDATA}"
+
+	einfo "The autovacuum function, which was in contrib, has been moved to the main"
+	einfo "PostgreSQL functions starting with 8.1, and starting with 8.4 is now enabled"
+	einfo "by default. You can disable it in the cluster's:"
+	einfo "    ${PGDATA%/}/postgresql.conf"
+	einfo
+	einfo "The PostgreSQL server, by default, will log events to:"
+	einfo "    ${DATA_DIR%/}/postmaster.log"
+	einfo
+	if use prefix ; then
+		einfo "The location of the configuration files have moved to:"
+		einfo "    ${PGDATA}"
+		einfo
+		einfo "To start the server:"
+		einfo "    pg_ctl start -D ${DATA_DIR} -o '-D ${PGDATA} --data-directory=${DATA_DIR}'"
+		einfo
+		einfo "To stop:"
+		einfo "    pg_ctl stop -D ${DATA_DIR}"
+		einfo
+		einfo "Or move the configuration files back:"
+		einfo "    mv ${PGDATA}*.conf ${DATA_DIR}"
+	else
+		einfo "You should use the '${EROOT%/}/etc/init.d/postgresql-${SLOT}' script to run PostgreSQL"
+		einfo "instead of 'pg_ctl'."
+	fi
+}
+
+src_test() {
+	einfo ">>> Test phase [check]: ${CATEGORY}/${PF}"
+
+	if [ ${UID} -ne 0 ] ; then
+		emake -j1 check  || die "Make check failed. See above for details."
+
+		einfo "If you think other tests besides the regression tests are necessary, please"
+		einfo "submit a bug including a patch for this ebuild to enable them."
+	else
+		ewarn "Tests cannot be run as root. Skipping."
+		ewarn "HINT: FEATURES=\"userpriv\""
+	fi
+}