1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/mako/mako-0.7.3.ebuild b/dev-python/mako/mako-0.7.3.ebuild
new file mode 100644
index 000000000000..c551fddef810
--- /dev/null
+++ b/dev-python/mako/mako-0.7.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/mako/mako-0.7.3.ebuild,v 1.1 2012/11/13 10:02:18 patrick Exp $
+
+EAPI="3"
+SUPPORT_PYTHON_ABIS="1"
+DISTUTILS_SRC_TEST="nosetests"
+
+inherit distutils eutils
+
+MY_P="Mako-${PV}"
+
+DESCRIPTION="A Python templating language"
+HOMEPAGE="http://www.makotemplates.org/ http://pypi.python.org/pypi/Mako"
+SRC_URI="http://www.makotemplates.org/downloads/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc"
+
+RDEPEND=">=dev-python/beaker-1.1
+	>=dev-python/markupsafe-0.9.2"
+DEPEND="${RDEPEND}
+	dev-python/setuptools"
+
+S="${WORKDIR}/${MY_P}"
+
+DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"
+
+src_prepare() {
+	distutils_src_prepare
+	epatch "${FILESDIR}/test-fix.patch"
+
+	2to3_conversion() {
+		[[ "${PYTHON_ABI}" == 2.* ]] && return
+		2to3-${PYTHON_ABI} -nw --no-diffs test
+	}
+	python_execute_function -s 2to3_conversion
+}
+
+src_test() {
+	distutils_src_test -P -w test
+}
+
+src_install() {
+	distutils_src_install
+
+	if use doc; then
+		pushd doc > /dev/null
+		rm -fr build
+		insinto /usr/share/doc/${PF}/html
+		doins -r [a-z]* _static || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+}