3 files changed, 285 insertions, 2 deletions
diff --git a/dev-util/git/ChangeLog b/dev-util/git/ChangeLog
index 3470b29f3e7d..9502f9f88b1c 100644
--- a/dev-util/git/ChangeLog
+++ b/dev-util/git/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/git
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/git/ChangeLog,v 1.268 2008/04/24 08:24:03 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/ChangeLog,v 1.269 2008/04/29 22:35:26 robbat2 Exp $
+
+*git-1.5.5.1-r1 (29 Apr 2008)
+
+  29 Apr 2008; Robin H. Johnson <robbat2@gentoo.org> +git-1.5.5.1-r1.ebuild:
+  The gitweb.cgi did not contain the build-time replacements. Ensure that it
+  does, and also make it executable by default so that portage does not
+  strip the executability on upgrade.
 
   24 Apr 2008; Robin H. Johnson <robbat2@gentoo.org>
   +files/20080322-git-1.5.4.4-noperl.patch,
diff --git a/dev-util/git/Manifest b/dev-util/git/Manifest
index 95a8183a3854..26689505da16 100644
--- a/dev-util/git/Manifest
+++ b/dev-util/git/Manifest
@@ -50,6 +50,7 @@ EBUILD git-1.5.4.4-r1.ebuild 7852 RMD160 de5e3c73e8f2e586e6ded00675a9208553247d8
 EBUILD git-1.5.4.4.ebuild 6565 RMD160 60bcf79bd993f95d038921fd8e83dc1289f5c958 SHA1 1197a2cbdce0658199407f07292c8b15689dbdb5 SHA256 b8d304b4c09311ea7fc2adc86fb352a69a7c37d83f98c573015fb8c979074817
 EBUILD git-1.5.4.5.ebuild 7849 RMD160 840b920043b4da7ad9cd596d33752711e6b4f2d3 SHA1 dd1a33ee468dbd098a893ab64754fff3482223c7 SHA256 8cde4b1501c8465103c043838f42faae26be7c38b99abe29b47c983084e7765b
 EBUILD git-1.5.4.ebuild 6565 RMD160 17d6172114dcbbc24d390b93fc9598318e0b4906 SHA1 3a7b86bacacb291fccdde45b7cd1832bc7cdda35 SHA256 8ba59eba4f2377e33302bf9830657c68f3c6fec3b600e234a5b1a4b36e0bee15
+EBUILD git-1.5.5.1-r1.ebuild 7955 RMD160 c9609450929f72489e5fa1042db0b184ef2ef697 SHA1 eba5bf212c6932b359999dde149e781be992189b SHA256 62c93b2d999c566d3b415a2033eb30cf99efd96fdf0fe053594b7891df1241a2
 EBUILD git-1.5.5.1.ebuild 7889 RMD160 8388e149d1a5ef9502e9ad2f653a544664f8e8c9 SHA1 0713f497e5ed9d210578bd51c8f04297aef57247 SHA256 9a4d3fa8cb2ba9ab10fe6a6932e4cced2deb6eeef9b60254efb1bd925b9aee18
-MISC ChangeLog 39744 RMD160 8d671cc92ec0ee2ad3e99a18183187d4b55afbe2 SHA1 9c8fa9808480f88225a50a69175108d95b551880 SHA256 e7945b3cf6b119bb9d2bd31d2550a393ae9c7b2388d8335a013ae1ed53334c8a
+MISC ChangeLog 40040 RMD160 aba15e4262a440812de9ff52203fc63b7b15b128 SHA1 54bcf003bdfb66a04a2d4f19fba51e663fb19f56 SHA256 aa586800445889c7ef826c308eaf742effa46a99eedf0bc0c57e44f93628227e
 MISC metadata.xml 1029 RMD160 f44ab0f6f9566b2cdb37f6cdd094e163c94e7d11 SHA1 88453257ccbedf4166357c262f49b0731cc45448 SHA256 2aa15da3001de8d8182ee9c8289cdefae84652b78ccc4cf35b2394f07edc352f
diff --git a/dev-util/git/git-1.5.5.1-r1.ebuild b/dev-util/git/git-1.5.5.1-r1.ebuild
new file mode 100644
index 000000000000..933213f3f471
--- /dev/null
+++ b/dev-util/git/git-1.5.5.1-r1.ebuild
@@ -0,0 +1,275 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/git-1.5.5.1-r1.ebuild,v 1.1 2008/04/29 22:35:26 robbat2 Exp $
+
+inherit toolchain-funcs eutils elisp-common perl-module bash-completion
+
+MY_PV="${PV/_rc/.rc}"
+MY_P="${PN}-${MY_PV}"
+
+DOC_VER=${MY_PV}
+
+DESCRIPTION="GIT - the stupid content tracker, the revision control system heavily used by the Linux kernel team"
+HOMEPAGE="http://git.or.cz/"
+SRC_URI="mirror://kernel/software/scm/git/${MY_P}.tar.bz2
+		mirror://kernel/software/scm/git/${PN}-manpages-${DOC_VER}.tar.bz2
+		doc? ( mirror://kernel/software/scm/git/${PN}-htmldocs-${DOC_VER}.tar.bz2 )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="curl cgi doc emacs gtk iconv mozsha1 perl ppcsha1 tk threads webdav xinetd cvs subversion"
+
+DEPEND="
+	!app-misc/git
+	dev-libs/openssl
+	sys-libs/zlib
+	app-arch/cpio
+	perl?	( dev-lang/perl )
+	tk?		( dev-lang/tk )
+	curl?	( net-misc/curl )
+	webdav? ( dev-libs/expat )
+	emacs?  ( virtual/emacs )"
+# dev-perl/{Authen-SASL,Net-SMTP-SSL} are used by git-send-email
+
+RDEPEND="${DEPEND}
+	perl? ( dev-perl/Error
+			dev-perl/Net-SMTP-SSL
+			dev-perl/Authen-SASL
+			cgi? ( virtual/perl-CGI )
+			cvs? ( >=dev-util/cvsps-2.1 dev-perl/DBI dev-perl/DBD-SQLite )
+			subversion? ( dev-util/subversion dev-perl/libwww-perl dev-perl/TermReadKey )
+			)
+	gtk?  ( >=dev-python/pygtk-2.8 )"
+
+SITEFILE=72${PN}-gentoo.el
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if ! use perl ; then
+		if use cgi || use cvs || use subversion ; then
+			eerror "You must built dev-util/git with USE=perl and the"
+			eerror "applicable USE flag to use any of the following:"
+			eerror "gitweb, git-cvs*, git-svn, git-archimport, git-quiltimport"
+			die "You need USE=perl to satisfy your other USE= requests!"
+		fi
+	fi
+}
+
+# This is needed because for some obscure reasons future calls to make don't
+# pick up these exports if we export them in src_unpack()
+exportmakeopts() {
+	local myopts
+
+	if use mozsha1 ; then
+		myopts="${myopts} MOZILLA_SHA1=YesPlease"
+	elif use ppcsha1 ; then
+		myopts="${myopts} PPC_SHA1=YesPlease"
+	fi
+
+	if use curl ; then
+		use webdav || myopts="${myopts} NO_EXPAT=YesPlease"
+	else
+		myopts="${myopts} NO_CURL=YesPlease"
+		use webdav && ewarn "USE=webdav only matters with USE=curl. Ignoring."
+	fi
+
+	use iconv || myopts="${myopts} NO_ICONV=YesPlease"
+	use tk || myopts="${myopts} NO_TCLTK=YesPlease"
+	use perl || myopts="${myopts} NO_PERL=YesPlease"
+	use threads && myopts="${myopts} THREADED_DELTA_SEARCH=YesPlease"
+	use subversion || myopts="${myopts} NO_SVN_TESTS=YesPlease"
+
+	export MY_MAKEOPTS="${myopts}"
+}
+
+src_unpack() {
+	unpack ${MY_P}.tar.bz2
+	cd "${S}"
+	unpack ${PN}-manpages-${DOC_VER}.tar.bz2
+	use doc && cd "${S}"/Documentation && unpack ${PN}-htmldocs-${DOC_VER}.tar.bz2
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-1.5.3-symlinks.patch
+	epatch "${FILESDIR}"/20080423-${PN}-1.5.5.1-noperl.patch
+
+	sed -i \
+		-e "s:^\(CFLAGS =\).*$:\1 ${CFLAGS} -Wall:" \
+		-e "s:^\(LDFLAGS =\).*$:\1 ${LDFLAGS}:" \
+		-e "s:^\(CC = \).*$:\1$(tc-getCC):" \
+		-e "s:^\(AR = \).*$:\1$(tc-getAR):" \
+		-e 's:ln :ln -s :g' \
+		Makefile || die "sed failed"
+
+	exportmakeopts
+}
+
+src_compile() {
+	emake ${MY_MAKEOPTS} DESTDIR="${D}" prefix=/usr || die "make failed"
+
+	if use emacs ; then
+		elisp-compile contrib/emacs/{,vc-}git.el || die "emacs modules failed"
+	fi
+	if use perl && use cgi ; then
+		emake ${MY_MAKEOPTS} \
+		DESTDIR="${D}" \
+		prefix=/usr \
+		gitweb/gitweb.cgi || die "make gitweb/gitweb.cgi failed"
+	fi
+}
+
+src_install() {
+	emake ${MY_MAKEOPTS} DESTDIR="${D}" prefix=/usr install || \
+		die "make install failed"
+
+	doman man?/*
+
+	dodoc README Documentation/{SubmittingPatches,CodingGuidelines}
+	use doc && dodir /usr/share/doc/${PF}/html
+	for d in / /howto/ /technical/ ; do
+		docinto ${d}
+		dodoc Documentation${d}*.txt
+		use doc && dohtml -p ${d} Documentation${d}*.html
+	done
+	docinto /
+
+	dobashcompletion contrib/completion/git-completion.bash ${PN}
+
+	if use emacs ; then
+		elisp-install ${PN} contrib/emacs/{,vc-}git.el* || \
+			die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+		# don't add automatically to the load-path, so the sitefile
+		# can do a conditional loading
+		touch "${D}"/"${SITELISP}"/${PN}/.nosearch
+	fi
+
+	if use gtk ; then
+		dobin "${S}"/contrib/gitview/gitview
+		dodoc "${S}"/contrib/gitview/gitview.txt
+	fi
+
+	dobin contrib/fast-import/git-p4
+	dodoc contrib/fast-import/git-p4.txt
+	newbin contrib/fast-import/import-tars.perl import-tars
+
+	dodir /usr/share/${PN}/contrib
+	# The following are excluded:
+	# svnimport - use git-svn
+	# p4import - excluded because fast-import has a better one
+	# examples - these are stuff that is not used in Git anymore actually
+	# patches - stuff the Git guys made to go upstream to other places
+	for i in continuous fast-import hg-to-git \
+		hooks remotes2config.sh vim stats \
+		workdir convert-objects blameview ; do
+		cp -rf \
+			"${S}"/contrib/${i} \
+			"${D}"/usr/share/${PN}/contrib \
+			|| die "Failed contrib ${i}"
+	done
+
+	if use perl && use cgi ; then
+		dodir /usr/share/${PN}/gitweb
+		insinto /usr/share/${PN}/gitweb
+		doins "${S}"/gitweb/gitweb.cgi
+		doins "${S}"/gitweb/gitweb.css
+		doins "${S}"/gitweb/git-{favicon,logo}.png
+
+		# Make sure it can run
+		fperms 0755 /usr/share/${PN}/gitweb/gitweb.cgi
+
+		# INSTALL discusses configuration issues, not just installation
+		docinto /
+		newdoc  "${S}"/gitweb/INSTALL INSTALL.gitweb
+		newdoc  "${S}"/gitweb/README README.gitweb
+	fi
+
+	if use xinetd ; then
+		insinto /etc/xinetd.d
+		newins "${FILESDIR}"/git-daemon.xinetd git-daemon
+	fi
+
+	newinitd "${FILESDIR}"/git-daemon.initd git-daemon
+	newconfd "${FILESDIR}"/git-daemon.confd git-daemon
+
+	fixlocalpod
+}
+
+src_test() {
+	local disabled=""
+	local tests_cvs="t9200-git-cvsexportcommit.sh \
+					t9400-git-cvsserver-server.sh \
+					t9600-cvsimport.sh"
+	local tests_perl="t5502-quickfetch.sh \
+					t5512-ls-remote.sh \
+					t5520-pull.sh"
+
+	# Unzip is used only for the testcase code, not by any normal parts of Git.
+	has_version app-arch/unzip || \
+		einfo "Disabling tar-tree tests" && \
+		disabled="${disabled} \
+					t5000-tar-tree.sh"
+
+	if ! has userpriv "${FEATURES}"; then
+		ewarn "Skipping CVS tests because CVS does not work as root!"
+		ewarn "You should retest with FEATURES=userpriv!"
+		disabled="${disabled} \
+					${tests_cvs}"
+	fi
+
+	use cvs && \
+		has_version dev-util/cvs && \
+		built_with_use dev-util/cvs server || \
+		einfo "Disabling CVS tests (needs dev-util/cvs[USE=server])" && \
+		disabled="${disabled} \
+					${tests_cvs}"
+
+	use perl || \
+		einfo "Disabling tests that need Perl" && \
+		disabled="${disabled} \
+					${tests_perl}"
+
+	# Reset all previously disabled tests
+	cd "${S}/t"
+	for i in *.sh.DISABLED ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i%.DISABLED}"
+	done
+	einfo "Disabled tests:"
+	for i in ${disabled} ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i}.DISABLED" && einfo "Disabled $i"
+	done
+	cd "${S}"
+	# Now run the tests
+	einfo "Start test run"
+	emake ${MY_MAKEOPTS} DESTDIR="${D}" prefix=/usr test || die "tests failed"
+}
+
+showpkgdeps() {
+	local pkg=$1
+	shift
+	elog "  $(printf "%-17s:" ${pkg}) ${@}"
+}
+
+pkg_postinst() {
+	if use emacs ; then
+		elisp-site-regen
+		elog "GNU Emacs has built-in Git support in versions greater 22.1."
+		elog "You can disable the emacs USE flag for dev-util/git"
+		elog "if you are using such a version."
+	fi
+	if use subversion && ! built_with_use dev-util/subversion perl ; then
+		ewarn "You must build dev-util/subversion with USE=perl"
+		ewarn "to get the full functionality of git-svn!"
+	fi
+	elog "These additional scripts need some dependencies:"
+	echo
+	showpkgdeps git-archimport "dev-util/tla"
+	showpkgdeps git-quiltimport "dev-util/quilt"
+	showpkgdeps git-instaweb \
+		"|| ( www-servers/lighttpd www-servers/apache )"
+	echo
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}