From 1d51a40c528e1995361858eadfaa410b590fd4f7 Mon Sep 17 00:00:00 2001
From: Maxim Koltsov <maksbotan@gentoo.org>
Date: Sat, 3 Sep 2011 14:49:58 +0000
Subject: Bump to 1.1.1, add plugin to 9999

Package-Manager: portage-2.1.10.11/cvs/Linux x86_64
---
 net-im/vacuum/vacuum-1.1.1.ebuild | 69 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 net-im/vacuum/vacuum-1.1.1.ebuild

(limited to 'net-im/vacuum/vacuum-1.1.1.ebuild')

diff --git a/net-im/vacuum/vacuum-1.1.1.ebuild b/net-im/vacuum/vacuum-1.1.1.ebuild
new file mode 100644
index 000000000000..2f3a2534576c
--- /dev/null
+++ b/net-im/vacuum/vacuum-1.1.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/vacuum/vacuum-1.1.1.ebuild,v 1.1 2011/09/03 14:49:57 maksbotan Exp $
+
+EAPI="4"
+LANGS="de pl ru uk"
+
+inherit cmake-utils
+
+DESCRIPTION="Qt4 Crossplatform Jabber client."
+HOMEPAGE="http://code.google.com/p/vacuum-im"
+SRC_URI="http://vacuum-im.googlecode.com/files/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+PLUGINS=" adiummessagestyle annotations autostatus avatars bitsofbinary bookmarks captchaforms chatstates clientinfo commands compress console dataforms datastreamsmanager emoticons filestreamsmanager filetransfer gateways inbandstreams iqauth jabbersearch messagearchiver multiuserchat pepmanager privacylists privatestorage registration remotecontrol rostersearch servicediscovery sessionnegotiation socksstreams vcard xmppuriqueries"
+IUSE="${PLUGINS// / +}"
+for x in ${LANGS}; do
+	IUSE+=" linguas_${x}"
+done
+
+REQUIRED_USE="
+	annotations? ( privatestorage )
+	avatars? ( vcard )
+	bookmarks? ( privatestorage )
+	captchaforms? ( dataforms )
+	commands? ( dataforms )
+	datastreamsmanager? ( dataforms )
+	filestreamsmanager? ( datastreamsmanager )
+	filetransfer? ( filestreamsmanager datastreamsmanager )
+	pepmanager? ( servicediscovery )
+	registration? ( dataforms )
+	remotecontrol? ( commands dataforms )
+	sessionnegotiation? ( dataforms )
+"
+
+RDEPEND="
+	>=x11-libs/qt-core-4.5:4[ssl]
+	>=x11-libs/qt-gui-4.5:4
+	>=dev-libs/openssl-0.9.8k
+	adiummessagestyle? ( >=x11-libs/qt-webkit-4.5:4 )
+	net-dns/libidn
+	x11-libs/libXScrnSaver
+"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS CHANGELOG README TRANSLATORS"
+
+src_configure() {
+	# linguas
+	local langs="none;"
+	for x in ${LANGS}; do
+		use linguas_${x} && langs+="${x};"
+	done
+
+	local mycmakeargs=(
+		-DINSTALL_LIB_DIR="$(get_libdir)"
+		-DINSTALL_SDK=ON
+		-DLANGS="${langs}"
+		-DINSTALL_DOCS=OFF
+	)
+
+	for x in ${PLUGINS}; do
+		mycmakeargs+=( "$(cmake-utils_use ${x} PLUGIN_${x})" )
+	done
+
+	cmake-utils_src_configure
+}
-- 
cgit v1.2.3-65-gdbad