sci-libs/scikits_statsmodels/scikits_statsmodels-0.4.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_statsmodels/scikits_statsmodels-0.4.3.ebuild,v 1.2 2012/12/10 19:29:07 bicatali Exp $

EAPI=4

SUPPORT_PYTHON_ABIS="1"
DISTUTILS_SRC_TEST="nosetests"
VIRTUALX_REQUIRED=test
RESTRICT_PYTHON_ABIS="2.4 3.3 2.7-pypy-*"
PYTHON_MODNAME="statsmodels"

inherit distutils virtualx

MYPN="${PN/scikits_/}"
MYP="${MYPN}-${PV}"

DESCRIPTION="Statistical computations and models for use with SciPy"
HOMEPAGE="http://statsmodels.sourceforge.net/"
SRC_URI="mirror://pypi/${MYPN:0:1}/${MYPN}/${MYP}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples test"

RDEPEND="
	dev-python/pandas
	sci-libs/scikits
	sci-libs/scipy
	examples? ( dev-python/matplotlib )"
DEPEND="
	>=dev-python/cython-0.15.1
	dev-python/pandas
	dev-python/setuptools
	sci-libs/scipy
	doc? ( dev-python/matplotlib
		   dev-python/sphinx
		   >=dev-python/ipython-0.12 )
	test? ( dev-python/nose )"

S="${WORKDIR}/${MYP}"

src_compile() {
	distutils_src_compile
	if use doc; then
		"$(PYTHON -f)" setup.py build_sphinx || die
	fi
}

src_install() {
	find "${S}" -name \*LICENSE.txt -delete
	distutils_src_install
	remove_scikits() {
		rm "${ED}"$(python_get_sitedir)/scikits/__init__.py || die
	}
	python_execute_function -q remove_scikits
	use doc && dohtml -r build/sphinx/html/*
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}