From 3da86ebdba38387cc3e760efeef4c603865c4244 Mon Sep 17 00:00:00 2001
From: David Roman <davidroman96@gmail.com>
Date: Tue, 6 Aug 2024 11:24:53 +0200
Subject: media-sound/lms: add missing RDEPEND

Closes: https://bugs.gentoo.org/937443
Signed-off-by: David Roman <davidroman96@gmail.com>
---
 media-sound/lms/lms-3.56.0-r1.ebuild | 72 ++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 media-sound/lms/lms-3.56.0-r1.ebuild

(limited to 'media-sound')

diff --git a/media-sound/lms/lms-3.56.0-r1.ebuild b/media-sound/lms/lms-3.56.0-r1.ebuild
new file mode 100644
index 000000000..d271ce719
--- /dev/null
+++ b/media-sound/lms/lms-3.56.0-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake pam systemd
+
+DESCRIPTION="Lightweight Music Server."
+HOMEPAGE="https://lms-demo.poupon.dev/ https://github.com/epoupon/lms"
+SRC_URI="https://github.com/epoupon/lms/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test stb"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/libarchive
+	acct-user/lms
+	dev-cpp/wt
+	dev-libs/boost
+	dev-libs/libconfig[cxx]
+	media-libs/taglib
+	media-video/ffmpeg[mp3,opus]
+	sys-libs/pam
+
+	!stb? ( media-gfx/graphicsmagick )
+
+"
+
+DEPEND="
+	${RDEPEND}
+
+	stb? ( dev-libs/stb )
+"
+
+BDEPEND="
+	test? ( dev-cpp/gtest )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-respect-ldflags.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DLMS_IMAGE_BACKEND=$(usex stb stb graphicsmagick)
+		-DENABLE_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	systemd_newunit conf/systemd/default.service lms.service
+	newinitd "${FILESDIR}/lms.init" lms
+	dopamd conf/pam/lms
+	mv "${ED}/usr/share/lms/lms.conf" "${ED}/etc/lms.conf" || die
+
+	# Already installed in the proper directory
+	rm "${ED}/usr/share/lms/default.service" || die
+	rm "${ED}/usr/share/lms/lms" || die
+
+	keepdir /var/log/lms
+	fowners -R lms:lms /var/log/lms
+
+	keepdir /var/lms
+	fowners lms:lms /var/lms
+}
-- 
cgit v1.2.3-65-gdbad