dev-libs/raft: add 0.14.0

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 56 insertions, 0 deletions

diff --git a/dev-libs/raft/Manifest b/dev-libs/raft/Manifest
index f767de429eed..789773ecc640 100644
--- a/dev-libs/raft/Manifest
+++ b/dev-libs/raft/Manifest
@@ -1 +1,2 @@
 DIST raft-0.13.0.tar.gz 332490 BLAKE2B 8d14e07b12d4f5a7eadb626b72a90b4defffaee26804a982f257ef80f75ff47ccf434a7dc6b62f36177120cd12ce8c772a6f293e9ad48c61df277b10c0df1854 SHA512 1d65f21ac85deb36a6f8681bd506656a34994164ba51f7c23aa523673024dacf5616bbb3f706c0da4df38c0cc1a00b330459209c80d404545686525da2916afa
+DIST raft-0.14.0.tar.gz 336032 BLAKE2B 22f03a54ba99cbfd5564f5b730d42dc7ad786071daaad4928b331d0d740c9289fd4a3226a08a67b8e40b62319613173d9d8b0df5b40577a68f876f6015a53f16 SHA512 c8b6b6428d65a7d97e74cea2b41ce443d90741afe71c3c173f2ea3c84782a892f20158f6635a8eafda6d4a729ba001ea991640d43ff6cfafdacb1b607104de3c
diff --git a/dev-libs/raft/raft-0.14.0.ebuild b/dev-libs/raft/raft-0.14.0.ebuild
new file mode 100644
index 000000000000..dfebdcca2626
--- /dev/null
+++ b/dev-libs/raft/raft-0.14.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="C implementation of the Raft consensus protocol"
+HOMEPAGE="https://github.com/canonical/raft"
+SRC_URI="https://github.com/canonical/raft/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="lz4 test zfs"
+RESTRICT="!test? ( test )"
+
+DEPEND="dev-libs/libuv:=
+	lz4? ( app-arch/lz4:= )"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/raft-0.10.0-toggle-zfs.patch
+	"${FILESDIR}"/raft-0.11.3-disable-automagic-check-for-lz4.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-uv
+
+		--disable-benchmark
+		--disable-debug
+		--disable-example
+		--disable-sanitize
+		--disable-static
+
+		$(use_enable lz4)
+		$(use_enable test fixture)
+
+		$(use_with zfs)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}