dev-python/astroml: initial import

Package-Manager: portage-2.2.27

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/astroml/astroml-0.3.ebuild b/dev-python/astroml/astroml-0.3.ebuild
new file mode 100644
index 000000000000..5246df1ba9a6
--- /dev/null
+++ b/dev-python/astroml/astroml-0.3.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 virtualx
+
+MYPN=astroML
+MYP=${MYPN}-${PV}
+
+DESCRIPTION="Python Machine Learning library for astronomy"
+HOMEPAGE="http://www.astroml.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MYPN}/${MYP}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	sci-libs/scikits_learn[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MYP}"
+
+DOCS=( CHANGES.rst README.rst )
+
+python_test() {
+	virtx nosetests --verbose || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	insinto /usr/share/doc/${PF}
+	use examples && doins -r examples
+}