dev-python/jupyter_core: Drop py3.6 in new rev due to ipython

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 37 insertions, 0 deletions

diff --git a/dev-python/jupyter_core/jupyter_core-4.6.3-r1.ebuild b/dev-python/jupyter_core/jupyter_core-4.6.3-r1.ebuild
new file mode 100644
index 000000000000..b5e369ae4bba
--- /dev/null
+++ b/dev-python/jupyter_core/jupyter_core-4.6.3-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Core common functionality of Jupyter projects"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm64 x86"
+
+RDEPEND="dev-python/traitlets[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		>=dev-python/ipython-4.0.1[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinxcontrib-github-alt
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# rely on imports working without PYTHONPATH
+	sed -e 's:test_not_on_path:_&:' \
+		-e 's:test_path_priority:_&:' \
+		-i jupyter_core/tests/test_command.py || die
+
+	distutils-r1_python_prepare_all
+}