dev-python/tox: Bump to 4.14.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 5edc4c3b22d5..84814578ea9f 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,2 +1,3 @@
 DIST tox-4.13.0.tar.gz 177875 BLAKE2B d32d0bbcf04d5aa4eec80907ad0099522aba520617a260d2586856c36f6246bc0ce22ec5eacb4a4f6766802e7529578fd00077eaf13c21e4fb1213278b926d5b SHA512 8fcd69cafd94a6c930769d26a9a8297d6e18e8962a646992330ebea9e49a5fa299915bd6833680c7bb0ed5f84f9be5faa915653c8a03ab0125bc00bd34e9d0e7
 DIST tox-4.14.0.tar.gz 178024 BLAKE2B 06c73240039966037efe46b8e8949dc3690ac96eb431c0890ead84571df2142cf787e9b5063a6e36ee839ae46a879bf1ee8c434c59cc7af52e6d67c36e9a2b0c SHA512 5acec2c30a5f8277bfe9364029d408af9622bfe77a883f9f317d33683758e46811a1702042a2a16f891ff6f9a4ef9e692c8f98eeda49401e814f3f347c2998a0
+DIST tox-4.14.1.tar.gz 178268 BLAKE2B e30e2bfbf3ee70ff217dd482abfddfe271c5158ffda3639ed6cd400e75b2c8bdf494b0ca73039ea1e9eaafa0f8431b98250981c659ae68e92968865d0b2ef8d4 SHA512 6ad0f82fa7c9599ade526179ee6bd417bc2309b1b5cb002dac7f48032b8889eda9164f0d05724c8846ddf887029e55d1dab7ae220722fd02b42f89421bc43c52
diff --git a/dev-python/tox/tox-4.14.1.ebuild b/dev-python/tox/tox-4.14.1.ebuild
new file mode 100644
index 000000000000..e80094cd0dd9
--- /dev/null
+++ b/dev-python/tox/tox-4.14.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}