proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/translate-toolkit/translate-toolkit-1.12.0.ebuild b/dev-python/translate-toolkit/translate-toolkit-1.12.0.ebuild
new file mode 100644
index 000000000000..c35718f7d3b1
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-1.12.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="http://translate.sourceforge.net"
+SRC_URI="mirror://sourceforge/translate/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+IUSE="doc +html +ical +ini +subtitles"
+
+RDEPEND="
+	app-text/iso-codes
+	sys-devel/gettext
+	dev-python/lxml[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.10.2[${PYTHON_USEDEP}]
+	!=dev-python/python-levenshtein-0.11.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/diff-match-patch[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( dev-python/iniparse[${PYTHON_USEDEP}] )"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${RDEPEND}"
+
+python_prepare_all() {
+	# Prevent unwanted d'loading in doc build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${S}"/docs/_build/html/. )
+	distutils-r1_python_install_all
+	rm -Rf docs || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/html2po || die
+		rm "${ED}"/usr/bin/po2html || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/ical2po || die
+		rm "${ED}"/usr/bin/po2ical || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/ini2po || die
+		rm "${ED}"/usr/bin/po2ini || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/sub2po || die
+		rm "${ED}"/usr/bin/po2sub || die
+	fi
+}