dev-ruby/net-ssh: add 5.0.2

Thanks to gyakovlel for tracking down the cause of test failures in bug 665220

Drop arm, ppc, ppc64, x86 keywords due to new dependency on ed25519, bug 667070

Closes: https://bugs.gentoo.org/665220
Package-Manager: Portage-2.3.49, Repoman-2.3.10

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-ruby/net-ssh/net-ssh-5.0.2.ebuild b/dev-ruby/net-ssh/net-ssh-5.0.2.ebuild
new file mode 100644
index 000000000000..b2f05b3d0190
--- /dev/null
+++ b/dev-ruby/net-ssh/net-ssh-5.0.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGES.txt README.rdoc THANKS.txt"
+RUBY_FAKEGEM_EXTRAINSTALL="support"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Non-interactive SSH processing in pure Ruby"
+HOMEPAGE="https://github.com/net-ssh/net-ssh"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> net-ssh-git-${PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="ed25519 test"
+
+ruby_add_rdepend "virtual/ruby-ssl ed25519? ( dev-ruby/ed25519 dev-ruby/bcrypt_pbkdf )"
+ruby_add_bdepend "test? ( dev-ruby/test-unit:2 >=dev-ruby/mocha-0.13 )"
+
+all_ruby_prepare() {
+	# Avoid bundler dependency
+	sed -i -e '/\(bundler\|:release\)/ s:^:#:' Rakefile || die
+}
+
+src_test() {
+	# prevent tests from trying to connect to ssh-agent socket and failing
+	unset SSH_AUTH_SOCK
+	if ! use ed25519; then
+		export NET_SSH_NO_ED25519=true
+	fi
+	ruby-ng_src_test
+}