kde-apps/libkcddb: 22.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/kde-apps/libkcddb/libkcddb-22.08.3.ebuild b/kde-apps/libkcddb/libkcddb-22.08.3.ebuild
new file mode 100644
index 000000000000..2a9b9f31801c
--- /dev/null
+++ b/kde-apps/libkcddb/libkcddb-22.08.3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE library for CDDB"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="musicbrainz"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	musicbrainz? ( media-libs/musicbrainz:5 )
+"
+RDEPEND="${DEPEND}"
+
+# tests require network access and compare static data with online data
+# bug 280996
+RESTRICT="test"
+
+src_prepare() {
+	ecm_src_prepare
+	use handbook || cmake_run_in kcmcddb cmake_comment_add_subdirectory doc
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package musicbrainz MusicBrainz5)
+	)
+
+	ecm_src_configure
+}