kde-apps/libkcddb: SLOT 5 shall RDEPEND on *-common too

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/kde-apps/libkcddb/libkcddb-23.08.5-r1.ebuild b/kde-apps/libkcddb/libkcddb-23.08.5-r1.ebuild
new file mode 100644
index 000000000000..d1d02a33c320
--- /dev/null
+++ b/kde-apps/libkcddb/libkcddb-23.08.5-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoff"
+ECM_TEST="true"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE library for CDDB"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="musicbrainz"
+
+# tests require network access and compare static data with online data
+# bug 280996
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	musicbrainz? ( media-libs/musicbrainz:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/libkcddb-common-${PV}
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+# Shipped by kde-apps/libkcddb-common package for shared use w/ SLOT 5
+ECM_REMOVE_FROM_INSTALL=(
+	/usr/share/applications/kcm_cddb.desktop
+	/usr/share/config.kcfg/libkcddb5.kcfg
+)
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	cmake_run_in kcmcddb cmake_comment_add_subdirectory doc
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package musicbrainz MusicBrainz5)
+	)
+	ecm_src_configure
+}