media-gfx/mandelbulber: add 2.28

Closes: https://bugs.gentoo.org/841179
Closes: https://bugs.gentoo.org/834692
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/media-gfx/mandelbulber/Manifest b/media-gfx/mandelbulber/Manifest
index 31dfa04ea113..193b0edba7c3 100644
--- a/media-gfx/mandelbulber/Manifest
+++ b/media-gfx/mandelbulber/Manifest
@@ -1 +1,2 @@
 DIST mandelbulber2-2.26.tar.gz 113563064 BLAKE2B 6fd333a42f5e4b106b950079277ff1bb6cc2395382e12ea37424df137ed11cf5fb103185b325d9615bd890404fe596133644a5cdd3911140eabb2f8c0c1d0e14 SHA512 cc547cab6e2b672a35be5d3d214ad3b292eaf1b3b06daf12cecce0f69e612fcfb4123cd837fd87003eea3103086947639fd04cae4b0ed7cd231d78e5d775e299
+DIST mandelbulber2-2.28.tar.gz 122800825 BLAKE2B a1bc8b3b743687003aeccaea7763b8100736b03dcd5044e43193f07bb519a7e78075c63cd0466373e8240a317fc2bbb6481bc07b51b137241cbb477e679093c3 SHA512 9bb2ecdcc2a2976efb6af930d49f067462713c6fd48f54631477102f3153479df6336b43b160c98c4e01f00d48188b314ccc86a84055a05cac5eb009db4e52e2
diff --git a/media-gfx/mandelbulber/mandelbulber-2.28.ebuild b/media-gfx/mandelbulber/mandelbulber-2.28.ebuild
new file mode 100644
index 000000000000..d943dfa6a263
--- /dev/null
+++ b/media-gfx/mandelbulber/mandelbulber-2.28.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="${PN}2-${PV}"
+inherit desktop qmake-utils toolchain-funcs xdg
+
+DESCRIPTION="Tool to render 3D fractals"
+HOMEPAGE="https://www.mandelbulber.com"
+SRC_URI="https://github.com/buddhi1980/${PN}2/releases/download/${PV}/${MY_P}.tar.gz mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="CC-BY-4.0 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="joystick opencl openexr sndfile tiff"
+
+RDEPEND="
+	dev-libs/lzo
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	media-libs/libpng:=
+	sci-libs/gsl:=
+	joystick? ( dev-qt/qtgamepad:5 )
+	opencl? (
+		dev-libs/clhpp
+		virtual/opencl
+	)
+	openexr? (
+		dev-libs/imath:=
+		media-libs/openexr:=
+	)
+	sndfile? ( media-libs/libsndfile )
+	tiff? ( media-libs/tiff )
+"
+DEPEND="${RDEPEND}
+	dev-qt/designer:5
+"
+BDEPEND="virtual/pkgconfig"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	use joystick || sed -i -e "s/qtHaveModule(gamepad)/false/" makefiles/common.pri || die
+	use openexr || sed -i -e "s/packagesExist(OpenEXR)/false/" makefiles/common.pri || die
+	use sndfile || sed -i -e "s/packagesExist(sndfile)/false/" makefiles/common.pri || die
+	use tiff || sed -i -e "s/packagesExist(libtiff-4)/false/" makefiles/common.pri || die
+}
+
+src_configure() {
+	if use opencl; then
+		eqmake5 makefiles/${PN}-opencl.pro
+	else
+		eqmake5 makefiles/${PN}.pro
+	fi
+}
+
+src_install() {
+	dobin ${PN}2
+
+	dodoc README NEWS usr/share/doc/${PN}2/Mandelbulber_Manual.pdf
+
+	insinto /usr/share/${PN}2
+	doins -r usr/share/${PN}2/*
+
+	domenu ${PN}2.desktop
+
+	newicon -s 256 qt/icons/${PN}.png ${PN}2.png
+}