media-libs/waffle: Revbump for xcb-proto multilib removal

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 69 insertions, 5 deletions

diff --git a/media-libs/waffle/waffle-1.7.0-r2.ebuild b/media-libs/waffle/waffle-1.7.0-r2.ebuild
new file mode 100644
index 000000000000..a4611e934598
--- /dev/null
+++ b/media-libs/waffle/waffle-1.7.0-r2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/${PN}"
+	GIT_ECLASS="git-r3"
+else
+	SRC_URI="https://gitlab.freedesktop.org/mesa/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}"/${PN}-v${PV}
+fi
+inherit meson-multilib multilib ${GIT_ECLASS}
+
+DESCRIPTION="Library that allows selection of GL API and of window system at runtime"
+HOMEPAGE="http://www.waffle-gl.org/ https://gitlab.freedesktop.org/mesa/waffle"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="doc +egl +gbm wayland X"
+RESTRICT="test" # gl_basic tests don't work when run from portage
+
+RDEPEND="
+	>=media-libs/mesa-9.1.6[egl(+)?,gbm(+)?,${MULTILIB_USEDEP}]
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
+	)
+	gbm? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.10[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	X? ( >=x11-base/xcb-proto-1.8-r3 )
+"
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xml-dtd:4.2
+"
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/wflinfo$(get_exeext)
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_feature X glx)
+		$(meson_feature wayland)
+		$(meson_feature X x11_egl)
+		$(meson_feature gbm)
+		$(meson_feature egl surfaceless_egl)
+		$(meson_native_true build-manpages)
+		-Dbuild-tests=false
+	)
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+
+	! use doc && rm -rf \
+		"${D}"/usr/share/doc/waffle1 \
+		"${D}"/usr/share/man/man{3,7}
+}
diff --git a/media-libs/waffle/waffle-9999.ebuild b/media-libs/waffle/waffle-9999.ebuild
index 7b4d01d42f65..a4611e934598 100644
--- a/media-libs/waffle/waffle-9999.ebuild
+++ b/media-libs/waffle/waffle-9999.ebuild
@@ -1,17 +1,17 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 if [[ ${PV} = *9999* ]]; then
 	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/${PN}"
 	GIT_ECLASS="git-r3"
 else
 	SRC_URI="https://gitlab.freedesktop.org/mesa/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
-	KEYWORDS="amd64 arm ~arm64 ~ppc ~ppc64 x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
 	S="${WORKDIR}"/${PN}-v${PV}
 fi
-inherit meson-multilib ${GIT_ECLASS}
+inherit meson-multilib multilib ${GIT_ECLASS}
 
 DESCRIPTION="Library that allows selection of GL API and of window system at runtime"
 HOMEPAGE="http://www.waffle-gl.org/ https://gitlab.freedesktop.org/mesa/waffle"
@@ -31,7 +31,7 @@ RDEPEND="
 	wayland? ( >=dev-libs/wayland-1.10[${MULTILIB_USEDEP}] )
 "
 DEPEND="${RDEPEND}
-	X? ( >=x11-base/xcb-proto-1.8-r3[${MULTILIB_USEDEP}] )
+	X? ( >=x11-base/xcb-proto-1.8-r3 )
 "
 BDEPEND="
 	dev-libs/libxslt