sci-mathematics/lcalc: new revision that doesn't litter libtool files.

Closes: https://bugs.gentoo.org/851183
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/sci-mathematics/lcalc/lcalc-2.0.5-r2.ebuild b/sci-mathematics/lcalc/lcalc-2.0.5-r2.ebuild
new file mode 100644
index 000000000000..640cc2e5b59b
--- /dev/null
+++ b/sci-mathematics/lcalc/lcalc-2.0.5-r2.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Command-line utility and library for L-function computations"
+HOMEPAGE="https://gitlab.com/sagemath/lcalc"
+SRC_URI="https://gitlab.com/sagemath/lcalc/uploads/25f029f3c02fcb6c3174972e0ac0e192/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+# The subslot is the libLfunction soname major version
+SLOT="0/1"
+KEYWORDS="~amd64"
+
+# Omit USE=mpfr for now because it's broken upstream:
+#
+#   https://gitlab.com/sagemath/lcalc/-/issues/7
+#
+IUSE="+double double-double quad-double pari"
+REQUIRED_USE="^^ ( double double-double quad-double )"
+
+BDEPEND="dev-util/gengetopt"
+DEPEND="double-double? ( sci-libs/qd:= )
+	quad-double? ( sci-libs/qd:= )
+	pari? ( sci-mathematics/pari:= )"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	econf $(use_with pari) \
+		  --enable-precision="$(usev double)$(usev double-double)$(usev quad-double)"
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+}