proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 50 insertions, 0 deletions

diff --git a/sys-apps/usbutils/usbutils-008-r1.ebuild b/sys-apps/usbutils/usbutils-008-r1.ebuild
new file mode 100644
index 000000000000..d76c85534866
--- /dev/null
+++ b/sys-apps/usbutils/usbutils-008-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1
+
+DESCRIPTION="USB enumeration utilities"
+HOMEPAGE="http://linux-usb.sourceforge.net/"
+SRC_URI="mirror://kernel/linux/utils/usb/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+CDEPEND="virtual/libusb:1=
+	virtual/libudev:="
+DEPEND="${CDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	sys-apps/hwids
+	python? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-006-stdint.patch
+	sed -i -e '/^usbids/s:/usr/share:/usr/share/misc:' lsusb.py || die
+	use python && python_fix_shebang lsusb.py
+}
+
+src_configure() {
+	econf \
+		--datarootdir="${EPREFIX}/usr/share" \
+		--datadir="${EPREFIX}/usr/share/misc"
+}
+
+src_install() {
+	default
+	newdoc usbhid-dump/NEWS NEWS.usbhid-dump
+
+	use python || rm -f "${ED}"/usr/bin/lsusb.py
+}