sys-kernel/gentoo-kernel-bin: add 5.10.74-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 1fdcf3687068..c41ed49ac016 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -61,6 +61,7 @@ DIST gentoo-kernel-5.10.73-1.amd64.xpak 65497272 BLAKE2B 16901ef5d85cc199bb02d21
 DIST gentoo-kernel-5.10.73-1.arm64.xpak 61223372 BLAKE2B eeb51e422e4d04eed64146b629467dae18c494d93b9b2a0e1965e0e5bd95bb8f343571c51c2736b3adfc57511afb001e9107b0cc6c89d3977a7abd20d0f66c67 SHA512 e13e73769a3a8a9edfa2ccd655d1164a4a74c74c208c5a8980fdd1c6b6e7dbaef7fccd54d57d8a2401bf64e0f1f0f5933962f67430b8c6dbff4fbbb4a75ae432
 DIST gentoo-kernel-5.10.73-1.x86.xpak 57234727 BLAKE2B 028eec3d6f13893ea7e90fc5eeb5efd2a244a59a1a0e18a6d13d2e335bf945439344b8b2124bec0c62c234a160d4b08b661c948453cc9ed4c56acdd70fd1eb16 SHA512 50d414bcc836cb5109088aa265c9b1321c1d0bfa58e978b72e7a2882b6491623ed9ed8fa0693a13420ece3f3057b913c7537cbe275abfbdc0941dca883d22d40
 DIST gentoo-kernel-5.10.74-1.amd64.xpak 65523300 BLAKE2B 3f764dfcef5b0fb8d2f5fc6217b017245689fddd553db237345e534babcc82e6ee928ff15ef29e8cf5e8aa0ef91c683a077a133e40275c0a4b8fa322d1bdf499 SHA512 8cdc9cef68620fe70acb0af49a36df9a12ddb00ec0cce938f40eec9a259270254a29f06dabf0b8ca3b8796c430f4b6088f233815d2a15f14243d4432ecdd489e
+DIST gentoo-kernel-5.10.74-1.arm64.xpak 61290653 BLAKE2B 24778034fd0407e2d33d10de6c69331493cbdb284fb9e1dfc3bd05efe806bd50e1186325a25a0e646e68d2ca57c9ce05460057020fa9f3c7c185918e465ada16 SHA512 45109b2a2257be9be186989aa34b10801434c05c3e4d5325a29d487116502f2a3680764188c14900157ebd60c317d2e025abf08b0c941564e6e5fd6e76d5f23c
 DIST gentoo-kernel-5.10.74-1.x86.xpak 57252997 BLAKE2B 517acc2cb011e325c1ac41f75f8da1fd1187f6b47359b2fd67171ae26e239a40ca26beea926dd490ed116e7b3956bb29d2f8e5a05c95ac3c6d6341751fc6179f SHA512 46b62a7767f056cb530373a090847ef37991b96b1931daa2eeec49c00258d570c9d859477ebc5afa3cfce2cd7245e5df869c41fd4090cbec2008e0dad93e8e16
 DIST gentoo-kernel-5.13.19-1.amd64.xpak 67338326 BLAKE2B d9e718a94bf9a341f5b57063cbde2f3f1f0ea6d03f1805051c084b792388789494a49786d643f1570871ca2b6366a206497aed83f9ed00837c542ac970a71fc6 SHA512 aea74f6f39861752f7a5dae16d955d541f65d3e7b8a0e5fba593011d9ca8583f3dd0964e76aa21daa6583d5d26e3616885aeca8a04dbba222e0aae2a85062b40
 DIST gentoo-kernel-5.13.19-1.arm64.xpak 62747957 BLAKE2B 1981ddb4e35d2210e1c678856ac58e088cd100ecbd70d2b5c88ffe8eb25b56f3f0c90e45d12adb74c7a0fb881dfd36b1d46d6fdfb837dbdff1881ded066b906d SHA512 d8c1e524a3e58def5352b3faae07c42074a2d67015cc62b9601e20bb9b7f29d44d2843e7771e0399e9150be1de2be2b28776f96f7fe75ba7ec4e8f2c31e1f715
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.74-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.74-r1.ebuild
new file mode 100644
index 000000000000..9f8ae493e215
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.74-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}