www-client/opera-developer: Version bump.

Package-Manager: Portage-2.3.6, Repoman-2.3.2

2 files changed, 90 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index e27f819e4c52..6e0e59a53fa8 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1 +1,2 @@
 DIST opera-developer_47.0.2615.0_amd64.deb 49644956 SHA256 c33967558ef500314c66e1f46c0e62f906e9efb110d005c64c09d3c5efe99a2c SHA512 f5fc62c7b7ac786e4d51938121f98df973db21f7a2a8b520791c312b6607f7b5fd1625f078a54657519a586c1b0ef78c39f8b57824d527c6266beb7814f8c482 WHIRLPOOL 76cec9bc69ad63be86e0553d0359542e6f44e7cdf0fdfc61f166402a654678ee99d7f80609d456839a8cb9024da3ca51e6baa8d06907a4c0d01df83eb7ed8854
+DIST opera-developer_47.0.2628.0_amd64.deb 49981666 SHA256 baf2116f7f6cc0e0ff2f814414b2e161a77c4c50910051ba09fe0116d25b7a83 SHA512 023c2739a540b64cc60dbb0bd63c940d5a1122420be417799717023f15a4e07bc2f0ddb1042d41de194557fabece1845f00935a3cd18913928485fd167a44ab1 WHIRLPOOL dd622f5a5d4655efaa9f5d57d907673c6fd736ae3e00a94a3bf479f6683e3194c6308d111d9600d03dfd888170d33f7f706e8fcc2cb9c4e5b64de3637ae6c86a
diff --git a/www-client/opera-developer/opera-developer-47.0.2628.0.ebuild b/www-client/opera-developer/opera-developer-47.0.2628.0.ebuild
new file mode 100644
index 000000000000..75d0b9628bcf
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-47.0.2628.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA he hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="http://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="http://get.geo.opera.com/pub/"
+SRC_URI="
+	amd64?	( "${SRC_URI_BASE}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb" )
+"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}/copyright || die
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}