1 files changed, 59 insertions, 0 deletions
diff --git a/dev-libs/liblinear/liblinear-242.ebuild b/dev-libs/liblinear/liblinear-242.ebuild
new file mode 100644
index 000000000000..a26af094c70c
--- /dev/null
+++ b/dev-libs/liblinear/liblinear-242.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="A Library for Large Linear Classification"
+HOMEPAGE="https://www.csie.ntu.edu.tw/~cjlin/liblinear/ https://github.com/cjlin1/liblinear"
+SRC_URI="https://github.com/cjlin1/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/4"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/^AR/s|=|?=|g' \
+		-e '/^RANLIB/s|=|?=|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		blas/Makefile || die
+	sed -i \
+		-e 's|make|$(MAKE)|g' \
+		-e '/$(LIBS)/s|$(CFLAGS)|& $(LDFLAGS)|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		-e 's|$${SHARED_LIB_FLAG}|& $(LDFLAGS)|g' \
+		Makefile || die
+
+	# fix install_name on Darwin
+	sed -i \
+		-e '/install_name/s:liblinear.so.$(SHVER):'"${EPREFIX}"'/usr/lib/liblinear.$(SHVER).dylib:' \
+		-e '/LDFLAGS/s:liblinear.so.$(SHVER):liblinear'"$(get_libname '$(SHVER)')"':' \
+		Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		CFLAGS="${CFLAGS} -fPIC" \
+		CXXFLAGS="${CXXFLAGS} -fPIC" \
+		AR="$(tc-getAR) rcv" \
+		RANLIB="$(tc-getRANLIB)" \
+		lib all
+}
+
+src_install() {
+	dolib.so ${PN}$(get_libname 4)
+	dosym ${PN}$(get_libname 4) /usr/$(get_libdir)/${PN}$(get_libname)
+
+	newbin predict ${PN}-predict
+	newbin train ${PN}-train
+
+	doheader linear.h
+
+	dodoc README
+}