1 files changed, 36 insertions, 0 deletions
diff --git a/dev-python/backports-csv/backports-csv-1.0.7.ebuild b/dev-python/backports-csv/backports-csv-1.0.7.ebuild
new file mode 100644
index 000000000000..aa307ff49dbd
--- /dev/null
+++ b/dev-python/backports-csv/backports-csv-1.0.7.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Backport of Python 3's 'csv' module"
+HOMEPAGE="https://github.com/ryanhiebert/backports.csv https://pypi.org/project/backports.csv/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/backports[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND} )"
+
+S=${WORKDIR}/${MY_P}
+
+python_test() {
+	"${EPYTHON}" tests.py -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}