1 files changed, 51 insertions, 0 deletions
diff --git a/dev-python/black/black-23.3.0.ebuild b/dev-python/black/black-23.3.0.ebuild
new file mode 100644
index 000000000000..3bbd465b752b
--- /dev/null
+++ b/dev-python/black/black-23.3.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="The uncompromising Python code formatter"
+HOMEPAGE="
+	https://black.readthedocs.io/en/stable/
+	https://github.com/psf/black/
+	https://pypi.org/project/black/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-3.10.0.0[${PYTHON_USEDEP}]
+	' 3.9)
+"
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/aiohttp-3.7.4[${PYTHON_USEDEP}]
+		dev-python/aiohttp-cors[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature "blackd - HTTP API for black" \
+		"dev-python/aiohttp dev-python/aiohttp-cors"
+}