1 files changed, 98 insertions, 0 deletions
diff --git a/dev-python/python-heatclient/python-heatclient-0.5.0.ebuild b/dev-python/python-heatclient/python-heatclient-0.5.0.ebuild
new file mode 100644
index 000000000000..128799857845
--- /dev/null
+++ b/dev-python/python-heatclient/python-heatclient-0.5.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_3 )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenStack Orchestration API Client Library"
+HOMEPAGE="http://www.openstack.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+CDEPEND="
+	>=dev-python/pbr-0.8[${PYTHON_USEDEP}]
+	<dev-python/pbr-1.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/hacking-0.8.0[${PYTHON_USEDEP}]
+		<dev-python/hacking-0.9[${PYTHON_USEDEP}]
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-0.3.14[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.0[${PYTHON_USEDEP}]
+		>=dev-python/mox3-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.5.1[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-0.9.36[${PYTHON_USEDEP}]
+		!~dev-python/testtools-1.2.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		<dev-python/oslo-sphinx-2.6.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-swiftclient-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.0[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	# BUG: https://bugs.launchpad.net/python-heatclient/+bug/1313257
+	ebegin 'patching heatclient/tests/test_common_http.py'
+	sed \
+		-e '645,/def/ d' \
+		-i heatclient/tests/test_common_http.py
+	STATUS=${?}
+	eend ${STATUS}
+	[[ ${STATUS} -gt 0 ]] && die
+
+	# BUG: https://bugs.launchpad.net/python-heatclient/+bug/1375035
+	ebegin 'patching heatclient/tests/test_shell.py'
+	sed \
+		-e '2116,/def|@/ d' \
+		-i heatclient/tests/test_shell.py
+	STATUS=${?}
+	eend ${STATUS}
+	[[ ${STATUS} -gt 0 ]] && die
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPYTHON}"
+
+	testr init
+	testr run || die "testsuite failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}