1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/trio-websocket/trio-websocket-0.11.1.ebuild b/dev-python/trio-websocket/trio-websocket-0.11.1.ebuild
new file mode 100644
index 000000000000..912e3a9e8237
--- /dev/null
+++ b/dev-python/trio-websocket/trio-websocket-0.11.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="WebSocket client and server implementation for Python Trio"
+HOMEPAGE="
+	https://github.com/python-trio/trio-websocket/
+	https://pypi.org/project/trio-websocket/
+"
+SRC_URI="
+	https://github.com/python-trio/trio-websocket/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+	' 3.10)
+	>=dev-python/trio-0.11[${PYTHON_USEDEP}]
+	>=dev-python/wsproto-0.14[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pytest-trio-0.5.0[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p trio
+}