From f321a80dd21e4b8e0f7fa2e05121e86a907ad210 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Sat, 26 Mar 2016 21:14:12 -0500
Subject: dev-python/python-neutronclient: bup for mitaka

Package-Manager: portage-2.2.26
---
 dev-python/python-neutronclient/Manifest           |  1 +
 .../python-neutronclient-3.1.1.ebuild              |  2 +-
 .../python-neutronclient-4.1.1.ebuild              | 96 ++++++++++++++++++++++
 3 files changed, 98 insertions(+), 1 deletion(-)
 create mode 100644 dev-python/python-neutronclient/python-neutronclient-4.1.1.ebuild

diff --git a/dev-python/python-neutronclient/Manifest b/dev-python/python-neutronclient/Manifest
index e54f1d44d116..55e2201ace3c 100644
--- a/dev-python/python-neutronclient/Manifest
+++ b/dev-python/python-neutronclient/Manifest
@@ -3,3 +3,4 @@ DIST python-neutronclient-2.4.0.tar.gz 137923 SHA256 4c5c3a79216c682926f75ffd8db
 DIST python-neutronclient-2.6.0.tar.gz 141675 SHA256 ce72506c0720825edcb0e93b643340e044f1de9235d398fe1c45d851971020df SHA512 a14503ec5374f0edd647a4da5e75f5d6820388b73792a9c944537815e980e87890fea227b2d21e34207958350f6e08a002e6f09af5567e1b4d709e698ea040cb WHIRLPOOL 7d3e6b0baded7de81f2c010376e8b528a73715382a230ffc6790eaae58b54e9cb5765002d2a508953b22a498d5a60947decd0d2884254cb2cc12f7ae1550596f
 DIST python-neutronclient-3.0.0.tar.gz 147616 SHA256 f6dc2e514e99df4f7eaf9f983a19344a5f38adf323d71f2908c872f8eba88e2f SHA512 f985c054f614d8ec2102d5323e7320c578dd11685f34d5e3f791c0ea3efea3780731da0f777a1544250029cd6dda8484af623c1f4537b45e49386e1ae1e9820b WHIRLPOOL f3323f28c36461b2b64897bd69d9453cf0f91c6497126e3e0d539652711f653e20ca340dfcce429f5342cb9a9397ccd42783a79d1c4baabf108aed569d50b521
 DIST python-neutronclient-3.1.1.tar.gz 148206 SHA256 ac3b695f55e30e17e7f27554780adf413cb7b878be5b922712d7f8357a6dbcc5 SHA512 9b125befd971f3892388d2ded378500889525641918b53588e353503c75f4ef8005c2ece50b2df87c416b258de770b91b73b143f84a4901bdd7d804a07444b08 WHIRLPOOL 0e05430f5d1ddfb0f769624d648f2f6414b141a6d635941b1b416f98d01cbdb18a0d7643196547ae15bcf475ff1c946162ddd3c3547e2a162eef6eadb25a5926
+DIST python-neutronclient-4.1.1.tar.gz 187794 SHA256 4d5c60358272174afb019d68940f67ddad09367b2e6210e3206d19566777c293 SHA512 654a7e8d98b1b6c3fbd1a183196982ea8bb9a0a97707e7a4ddb4cde47a97e93c3356961193c305b3ab33cb8ee2273b1a941c2655e1f56a3e2a8131deaed54922 WHIRLPOOL ead87cb41f57f285a03583ca91e843a0f9c4edaefaa7020d38c949dbd56d46611f44e36c087a9684d2e87c0d236ff8124022b2afacd9b8438b6b8b6716ec9c81
diff --git a/dev-python/python-neutronclient/python-neutronclient-3.1.1.ebuild b/dev-python/python-neutronclient/python-neutronclient-3.1.1.ebuild
index 1c8a6eef87a0..0ba426c30af7 100644
--- a/dev-python/python-neutronclient/python-neutronclient-3.1.1.ebuild
+++ b/dev-python/python-neutronclient/python-neutronclient-3.1.1.ebuild
@@ -13,7 +13,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+KEYWORDS="amd64 ~arm64 x86 ~amd64-linux ~x86-linux"
 IUSE="doc test"
 REQUIRED_USE="test? ( doc )"
 
diff --git a/dev-python/python-neutronclient/python-neutronclient-4.1.1.ebuild b/dev-python/python-neutronclient/python-neutronclient-4.1.1.ebuild
new file mode 100644
index 000000000000..620f66223d35
--- /dev/null
+++ b/dev-python/python-neutronclient/python-neutronclient-4.1.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_3 python3_4 python3_5 )
+
+inherit distutils-r1
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="https://launchpad.net/neutron"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+REQUIRED_USE="test? ( doc )"
+
+CDEPEND=">=dev-python/pbr-1.6[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/mox3-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		!~dev-python/oslo-sphinx-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/reno-0.1.1[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/tempest-lib-0.14.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/cliff-1.15.0[${PYTHON_USEDEP}]
+	!~dev-python/cliff-1.16.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.12[${PYTHON_USEDEP}]
+	!~dev-python/netaddr-0.7.16[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/os-client-config-1.13.1[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
+	!~dev-python/requests-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# built in... 
+	sed -i '/^argparse/d' requirements.txt || die
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && "${PYTHON}" setup.py build_sphinx
+}
+
+python_test() {
+	testr init
+	testr run || die "tests failed under python2.7"
+	flake8 neutronclient/tests || die "run by flake8 over tests folder yielded error"
+}
+
+python_install() {
+	distutils-r1_python_install
+	#stupid stupid
+	local SITEDIR="${D%/}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.egg-info )
+	#[[ -f ${egg[0]} ]] || die "python_quantumclient*.egg-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad