From 676d75b9277896e54cbc8c3cc5632e55842c9413 Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Sat, 2 Jan 2021 11:14:31 +0100
Subject: app-editors/zile: Version bump to 2.4.15
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 app-editors/zile/zile-2.4.15.ebuild | 47 +++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 app-editors/zile/zile-2.4.15.ebuild

(limited to 'app-editors/zile/zile-2.4.15.ebuild')

diff --git a/app-editors/zile/zile-2.4.15.ebuild b/app-editors/zile/zile-2.4.15.ebuild
new file mode 100644
index 000000000000..16a2248ef54d
--- /dev/null
+++ b/app-editors/zile/zile-2.4.15.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Zile is a small Emacs clone"
+HOMEPAGE="https://www.gnu.org/software/zile/"
+SRC_URI="mirror://gnu/zile/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="acl"
+
+RDEPEND=">=dev-libs/boehm-gc-7.2:=
+	sys-libs/ncurses:0=
+	acl? ( virtual/acl )"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="dev-lang/perl
+	sys-apps/help2man
+	virtual/pkgconfig"
+
+# AUTHORS, FAQ, and NEWS are installed by the build system
+DOCS="README THANKS"
+
+QA_AM_MAINTAINER_MODE=".*help2man.*" #450278
+
+src_configure() {
+	econf \
+		$(use_enable acl) \
+		CURSES_LIB="$("$(tc-getPKG_CONFIG)" --libs ncurses)"
+}
+
+src_test() {
+	if tput cup 0 0 >/dev/null || tput cuu1 >/dev/null; then
+		# We have a sane terminal that can move the cursor
+		emake check
+	else
+		ewarn "Terminal type \"${TERM}\" is too stupid to run zile"
+		ewarn "Running the tests with unset TERM instead"
+		( unset TERM; emake check )
+	fi
+}
-- 
cgit v1.2.3-65-gdbad