From a7a5c75b606858a1461a801acbaf8697fa17561d Mon Sep 17 00:00:00 2001
From: Sebastian Pipping <sping@gentoo.org>
Date: Mon, 29 Mar 2021 20:14:18 +0200
Subject: app-text/gocr: 0.52

Closes: https://bugs.gentoo.org/688656
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.18, Repoman-3.0.3
---
 app-text/gocr/Manifest         |  1 +
 app-text/gocr/gocr-0.52.ebuild | 53 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)
 create mode 100644 app-text/gocr/gocr-0.52.ebuild

(limited to 'app-text/gocr')

diff --git a/app-text/gocr/Manifest b/app-text/gocr/Manifest
index 0014c37e7f49..12c0bda06be2 100644
--- a/app-text/gocr/Manifest
+++ b/app-text/gocr/Manifest
@@ -1 +1,2 @@
 DIST gocr-0.50.tar.gz 419209 BLAKE2B 232fe240d7a559cdd4408a3dba3768818aefbd8b2718c7ae40829d69ab79dd68293eb6adfc52e661f2f6cf1290ae9656c84d9d7a8fc20229c0942a8e18fb3b68 SHA512 36392516711d43f8561147684b6f4e22a450bc87f1cb30ceaab4a1821ac583ff5a3d25b3bbf1637f01bfb55366b45cc7d5086d1f29f006d615bb658d0e5faab9
+DIST gocr-0.52.tar.gz 445401 BLAKE2B 1f22f5377bb95053e3ab4ede074b3fceca4065f9ca0ede05a8023ebe807f41074f5ead84e133281e98be7f68f13b036dc759cccaf4a5688bf776f62f2de1970a SHA512 e2e6e690e7a32e32237c8b64b1a11719680c560592349df43f4b230f3c92bf324f98e473979b0913c42e33e8abbaf27952b6af173ea06eb5535878a9f608ce6d
diff --git a/app-text/gocr/gocr-0.52.ebuild b/app-text/gocr/gocr-0.52.ebuild
new file mode 100644
index 000000000000..cced5ddc3583
--- /dev/null
+++ b/app-text/gocr/gocr-0.52.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="An OCR (Optical Character Recognition) reader"
+HOMEPAGE="http://jocr.sourceforge.net"
+SRC_URI="http://www-e.uni-magdeburg.de/jschulen/ocr/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc scanner tk"
+
+DEPEND="
+	>=media-libs/netpbm-9.12
+	doc? (
+		>=media-gfx/transfig-3.2
+		app-text/ghostscript-gpl
+	)
+	tk? ( dev-lang/tk )"
+RDEPEND="${DEPEND}
+	tk? (
+		media-gfx/xli
+		scanner? ( media-gfx/xsane )
+	)"
+
+src_compile() {
+	local targets=( src man )
+	use doc && targets+=( doc examples )
+
+	emake "${targets[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" exec_prefix="${EPREFIX}/usr" install
+	einstalldocs
+	dodoc HISTORY REMARK.txt REVIEW
+
+	# remove the tk frontend if tk is not selected
+	if ! use tk; then
+		rm "${ED}"/usr/bin/gocr.tcl || die
+	fi
+
+	# and install the documentation and examples
+	if use doc; then
+		dodoc doc/gocr.html doc/examples.txt doc/unicode.txt
+
+		docinto examples
+		dodoc examples/*.{fig,tex,pcx}
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3-65-gdbad